1 files changed, 42 insertions, 0 deletions
diff --git a/dev-libs/libebml/libebml-1.0.0.ebuild b/dev-libs/libebml/libebml-1.0.0.ebuild
new file mode 100644
index 000000000000..c62d5a436e4b
--- /dev/null
+++ b/dev-libs/libebml/libebml-1.0.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libebml/libebml-1.0.0.ebuild,v 1.1 2010/06/05 15:37:14 beandog Exp $
+
+EAPI=2
+
+inherit eutils multilib toolchain-funcs
+
+DESCRIPTION="Extensible binary format library (kinda like XML)"
+HOMEPAGE="http://www.matroska.org/"
+SRC_URI="http://www.bunkus.org/videotools/mkvtoolnix/sources/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE=""
+
+S="${S}/make/linux"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-makefile-fixup.patch
+}
+
+src_compile() {
+	# keep the prefix in here to make sure the binary is built with a correct
+	# install_name on Darwin
+	emake \
+		prefix="${EPREFIX}/usr" \
+		CC="$(tc-getCC)" \
+		CXX="$(tc-getCXX)" \
+		|| die "emake failed"
+}
+
+src_install() {
+	emake \
+		DESTDIR="${D}" \
+		prefix="${EPREFIX}/usr" \
+		libdir="${EPREFIX}/usr/$(get_libdir)" \
+		install || die "emake install failed"
+
+	dodoc "${WORKDIR}/${P}/ChangeLog"
+}