1 files changed, 58 insertions, 0 deletions
diff --git a/app-shells/dash/dash-0.5.4.9.ebuild b/app-shells/dash/dash-0.5.4.9.ebuild
new file mode 100644
index 000000000000..b8174c93fb4e
--- /dev/null
+++ b/app-shells/dash/dash-0.5.4.9.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-shells/dash/dash-0.5.4.9.ebuild,v 1.1 2008/05/31 07:33:11 vapier Exp $
+
+inherit autotools eutils flag-o-matic
+
+DEB_PV=${PV%.*}
+DEB_PATCH=${PV##*.}
+DEB_PF="${PN}_${DEB_PV}-${DEB_PATCH}"
+MY_P="${PN}-${DEB_PV}"
+
+DESCRIPTION="DASH is a direct descendant of the NetBSD version of ash (the Almquist SHell) and is POSIX compliant"
+HOMEPAGE="http://gondor.apana.org.au/~herbert/dash/"
+SRC_URI="http://gondor.apana.org.au/~herbert/dash/files/${PN}-${DEB_PV}.tar.gz
+	mirror://debian/pool/main/d/dash/${DEB_PF}.diff.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="libedit static"
+
+DEPEND="libedit? ( dev-libs/libedit )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_unpack() {
+	unpack ${A}
+
+	epatch "${WORKDIR}"/${DEB_PF}.diff
+	cd "${S}"
+	epatch debian/diff/*
+
+	# Fix the invalid sort
+	sed -i -e 's/LC_COLLATE=C/LC_ALL=C/g' src/mkbuiltins
+
+	# Always statically link libedit in to ensure we always boot if it changes
+	# which it has done in the past.
+	local s="s/-ledit/-Wl,-Bstatic -ledit -Wl,-Bdynamic -lcurses/g"
+	use static && s="s/-ledit/-ledit -lcurses/g"
+	sed -i -e "${s}" configure.ac || die "Failed to sed configure.ac"
+
+	# May as well, as the debian patches force this anyway
+	eautoreconf
+}
+
+src_compile() {
+	use static && append-ldflags -static
+	econf \
+		--bindir=/bin \
+		$(use_with libedit) \
+		|| die "econf failed"
+	emake || die
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die
+	dodoc ChangeLog debian/changelog
+}