1 files changed, 64 insertions, 0 deletions
diff --git a/app-i18n/ibus-pinyin/ibus-pinyin-1.1.0.20090303.ebuild b/app-i18n/ibus-pinyin/ibus-pinyin-1.1.0.20090303.ebuild
new file mode 100644
index 000000000000..280e19249f22
--- /dev/null
+++ b/app-i18n/ibus-pinyin/ibus-pinyin-1.1.0.20090303.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus-pinyin/ibus-pinyin-1.1.0.20090303.ebuild,v 1.1 2009/03/03 14:51:04 matsuu Exp $
+
+inherit eutils python
+
+PYDB_TAR="pinyin-database-0.1.10.6.tar.bz2"
+DESCRIPTION="Chinese PinYin IMEngine for IBus Framework"
+HOMEPAGE="http://code.google.com/p/ibus/"
+SRC_URI="http://ibus.googlecode.com/files/${P}.tar.gz
+	http://ibus.googlecode.com/files/${PYDB_TAR}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls"
+
+RDEPEND=">=app-i18n/ibus-1.1.0
+	>=dev-lang/python-2.5
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	nls? ( >=sys-devel/gettext-0.16.1 )"
+
+pkg_setup() {
+	if ! built_with_use '>=dev-lang/python-2.5' sqlite; then
+		eerror "To use ibus-pinyin you have to build dev-lang/python with \"sqlite\" USE flag!"
+		die "To use ibus-pinyin you have to build dev-lang/python
+		with \"sqlite\" USE flag!"
+	fi
+}
+
+src_unpack() {
+	unpack ${P}.tar.gz
+	cd "${S}"
+	mv py-compile py-compile.orig || die
+	ln -s "$(type -P true)" py-compile || die
+	cp "${DISTDIR}/${PYDB_TAR}" "${S}"/engine
+}
+
+src_compile() {
+	econf $(use_enable nls) || die
+	emake || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	dodoc AUTHORS ChangeLog NEWS README
+}
+
+pkg_postinst() {
+	ewarn "This package is very experimental, please report your bugs to"
+	ewarn "http://ibus.googlecode.com/issues/list"
+	elog
+	elog "You should run ibus-setup and enable IM Engines you want to use!"
+	elog
+
+	python_mod_optimize /usr/share/${PN}
+}
+
+pkg_postrm() {
+	python_mod_cleanup /usr/share/${PN}
+}