1 files changed, 44 insertions, 0 deletions
diff --git a/app-emacs/gnuserv-programs/gnuserv-programs-3.12.8-r1.ebuild b/app-emacs/gnuserv-programs/gnuserv-programs-3.12.8-r1.ebuild
new file mode 100644
index 000000000000..da88acfbd7b2
--- /dev/null
+++ b/app-emacs/gnuserv-programs/gnuserv-programs-3.12.8-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emacs/gnuserv-programs/gnuserv-programs-3.12.8-r1.ebuild,v 1.1 2010/04/30 14:13:10 grobian Exp $
+
+EAPI="3"
+
+inherit multilib
+
+DESCRIPTION="Binary programs for app-emacs/gnuserv"
+HOMEPAGE="http://meltin.net/hacks/emacs/"
+SRC_URI="http://meltin.net/hacks/emacs/src/gnuserv-${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~x86-linux ~ppc-macos"
+IUSE="X"
+
+DEPEND="!app-editors/xemacs
+	!<=app-emacs/gnuserv-3.12.7
+	X? ( x11-libs/libXau )"
+RDEPEND="${DEPEND}"
+PDEPEND="~app-emacs/gnuserv-${PV}"
+
+S="${WORKDIR}/gnuserv-${PV}"
+
+src_configure() {
+	# bug #83112
+	unset LDFLAGS
+
+	econf $(use_enable X xauth) \
+		--x-includes="${EPREFIX}"/usr/include \
+		--x-libraries="${EPREFIX}"/usr/$(get_libdir)
+}
+
+src_compile() {
+	emake ELC="" || die "emake failed"
+}
+
+src_install() {
+	emake -j1 ELC="" \
+		prefix="${ED}"/usr \
+		man1dir="${ED}"/usr/share/man/man1 \
+		install || die "emake install failed"
+}