1 files changed, 52 insertions, 0 deletions
diff --git a/app-emacs/ess/ess-5.3.11.ebuild b/app-emacs/ess/ess-5.3.11.ebuild
new file mode 100644
index 000000000000..cede94103f5f
--- /dev/null
+++ b/app-emacs/ess/ess-5.3.11.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emacs/ess/ess-5.3.11.ebuild,v 1.1 2009/01/29 01:44:03 fauli Exp $
+
+inherit elisp
+
+DESCRIPTION="Emacs Speaks Statistics"
+HOMEPAGE="http://ess.r-project.org/"
+SRC_URI="http://ess.r-project.org/downloads/ess/${P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
+IUSE=""
+
+DEPEND="app-text/texi2html
+	virtual/latex-base"
+RDEPEND=""
+
+SITEFILE="50${PN}-gentoo.el"
+
+src_compile() {
+	emake || die "emake failed"
+}
+
+src_install() {
+	# Install all elisp sources; the Makefile installs only part of them.
+	# This has to go before emake install, see bug 205156 comment 3.
+	elisp-install ${PN} lisp/ess*.el || die
+
+	# make install fails to create some directories
+	dodir /usr/share/doc/${PF}/{html,refcard}
+
+	emake PREFIX="${D}/usr" \
+		INFODIR="${D}/usr/share/info" \
+		LISPDIR="${D}${SITELISP}/ess" \
+		DOCDIR="${D}/usr/share/doc/${PF}" \
+		install || die "emake install failed"
+
+	elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
+
+	# Most documentation is installed by the package's build system
+	dodoc ChangeLog doc/{NEWS,TODO,ess-intro.pdf} || die "dodoc failed"
+	newdoc lisp/ChangeLog ChangeLog-lisp || die "newdoc failed"
+	prepalldocs
+}
+
+pkg_postinst() {
+	elisp-site-regen
+	elog "Please see /usr/share/doc/${PF} for the complete documentation."
+	elog "Usage hints are in ${SITELISP}/${PN}/ess-site.el ."
+}