4 files changed, 85 insertions, 0 deletions
diff --git a/app-editors/beaver/ChangeLog b/app-editors/beaver/ChangeLog
new file mode 100644
index 000000000000..1462ca56b70a
--- /dev/null
+++ b/app-editors/beaver/ChangeLog
@@ -0,0 +1,10 @@
+# ChangeLog for app-editors/beaver
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-editors/beaver/ChangeLog,v 1.18 2010/10/15 17:01:42 ssuominen Exp $
+
+*beaver-0.4.1 (15 Oct 2010)
+
+  15 Oct 2010; Samuli Suominen <ssuominen@gentoo.org> +beaver-0.4.1.ebuild,
+  +files/beaver-0.4.1-desktop-file-validate.patch:
+  Initial commit wrt #231532 by Mirko Briemle.
+
diff --git a/app-editors/beaver/beaver-0.4.1.ebuild b/app-editors/beaver/beaver-0.4.1.ebuild
new file mode 100644
index 000000000000..b18055bebae1
--- /dev/null
+++ b/app-editors/beaver/beaver-0.4.1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-editors/beaver/beaver-0.4.1.ebuild,v 1.1 2010/10/15 17:01:42 ssuominen Exp $
+
+EAPI=2
+inherit eutils gnome2-utils
+
+DESCRIPTION="Beaver is an Early AdVanced EditoR"
+HOMEPAGE="http://beaver-editor.sourceforge.net/"
+SRC_URI="mirror://sourceforge/beaver-editor/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc"
+
+RDEPEND=">=dev-libs/glib-2.14:2
+	>=x11-libs/gtk+-2.10:2"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	dev-util/pkgconfig
+	dev-util/intltool
+	sys-devel/gettext"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-0.4.1-desktop-file-validate.patch
+}
+
+src_configure() {
+	econf \
+		--disable-dependency-tracking \
+		$(use_enable doc doxygen-doc) \
+		$(use_enable debug)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	dodoc AUTHORS ChangeLog NEWS README THANKS TODO
+	find "${D}" -name '*.la' -exec rm -f '{}' +
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
diff --git a/app-editors/beaver/files/beaver-0.4.1-desktop-file-validate.patch b/app-editors/beaver/files/beaver-0.4.1-desktop-file-validate.patch
new file mode 100644
index 000000000000..6d58c6ff9425
--- /dev/null
+++ b/app-editors/beaver/files/beaver-0.4.1-desktop-file-validate.patch
@@ -0,0 +1,14 @@
+--- data/beaver.desktop.orig	2010-10-15 20:00:44.000000000 +0300
++++ data/beaver.desktop	2010-10-15 20:01:15.000000000 +0300
+@@ -1,5 +1,4 @@
+ [Desktop Entry]
+-Encoding=UTF-8
+ Name=Beaver
+ GenericName=Programmer's Text Editor
+ Comment=Beaver's an Early AdVanced EditoR
+@@ -9,4 +8,4 @@
+ MimeType=text/plain;application/x-shellscript;text/x-c;text/x-c++;text/x-c++hdr;text/x-c++src;text/x-chdr;text/x-csrc;text/x-java;text/x-makefile;text/x-moc;text/x-pascal;text/x-tcl;text/x-tex;
+ StartupNotify=false
+ Type=Application
+-Categories=Application;Development;TextEditor;GTK;
++Categories=Development;Utility;TextEditor;GTK;
diff --git a/app-editors/beaver/metadata.xml b/app-editors/beaver/metadata.xml
new file mode 100644
index 000000000000..7cc5007c5d79
--- /dev/null
+++ b/app-editors/beaver/metadata.xml
@@ -0,0 +1,9 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <herd>no-herd</herd>
+  <maintainer>
+    <email>ssuominen@gentoo.org</email>
+    <name>Samuli Suominen</name>
+  </maintainer>
+</pkgmetadata>