1 files changed, 49 insertions, 0 deletions
diff --git a/app-crypt/ccid/ccid-1.4.8.ebuild b/app-crypt/ccid/ccid-1.4.8.ebuild
new file mode 100644
index 000000000000..d2114b988f2e
--- /dev/null
+++ b/app-crypt/ccid/ccid-1.4.8.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/ccid/ccid-1.4.8.ebuild,v 1.1 2012/10/07 19:13:56 flameeyes Exp $
+
+EAPI="4"
+
+STUPID_NUM="3768"
+
+inherit eutils toolchain-funcs
+
+DESCRIPTION="CCID free software driver"
+HOMEPAGE="http://pcsclite.alioth.debian.org/ccid.html"
+SRC_URI="http://alioth.debian.org/download.php/${STUPID_NUM}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86"
+IUSE="twinserial +usb"
+
+RDEPEND=">=sys-apps/pcsc-lite-1.8.3
+	usb? ( virtual/libusb:1 )"
+DEPEND="${RDEPEND}
+	kernel_linux? ( virtual/pkgconfig )"
+
+DOCS=( README AUTHORS )
+
+src_prepare() {
+	sed -i -e 's:GROUP="pcscd":ENV{PCSCD}="1":' \
+		src/92_pcscd_ccid.rules || die
+}
+
+src_configure() {
+	econf \
+		LEX=: \
+		--docdir="/usr/share/doc/${PF}" \
+		$(use_enable twinserial) \
+		$(use_enable usb libusb)
+}
+
+src_install() {
+	default
+
+	if use kernel_linux; then
+		local udevdir=/lib/udev
+		has_version sys-fs/udev && udevdir="$($(tc-getPKG_CONFIG) --variable=udevdir udev)"
+		insinto "${udevdir}"/rules.d
+		newins src/92_pcscd_ccid.rules 92-pcsc-ccid.rules
+	fi
+}