Version bump.

(Portage version: 2.2.0_alpha174/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

2 files changed, 68 insertions, 1 deletions

diff --git a/xfce-base/xfce4-session/ChangeLog b/xfce-base/xfce4-session/ChangeLog
index 36933d11e967..2a7a9ddf2e37 100644
--- a/xfce-base/xfce4-session/ChangeLog
+++ b/xfce-base/xfce4-session/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for xfce-base/xfce4-session
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-session/ChangeLog,v 1.180 2013/04/13 07:20:53 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-session/ChangeLog,v 1.181 2013/05/05 16:55:45 ssuominen Exp $
+
+*xfce4-session-4.10.1 (05 May 2013)
+
+  05 May 2013; Samuli Suominen <ssuominen@gentoo.org>
+  +xfce4-session-4.10.1.ebuild:
+  Version bump.
 
   13 Apr 2013; Agostino Sarubbo <ago@gentoo.org> xfce4-session-4.10.0-r1.ebuild:
   Stable for sparc, wrt bug #465286
diff --git a/xfce-base/xfce4-session/xfce4-session-4.10.1.ebuild b/xfce-base/xfce4-session/xfce4-session-4.10.1.ebuild
new file mode 100644
index 000000000000..00fe12e037cd
--- /dev/null
+++ b/xfce-base/xfce4-session/xfce4-session-4.10.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-session/xfce4-session-4.10.1.ebuild,v 1.1 2013/05/05 16:55:45 ssuominen Exp $
+
+EAPI=5
+inherit xfconf
+
+DESCRIPTION="A session manager for the Xfce desktop environment"
+HOMEPAGE="http://docs.xfce.org/xfce/xfce4-session/start"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="debug policykit udev +xscreensaver"
+
+COMMON_DEPEND=">=dev-libs/dbus-glib-0.100
+	x11-apps/iceauth
+	x11-libs/libSM
+	>=x11-libs/libwnck-2.30:1
+	x11-libs/libX11
+	>=xfce-base/libxfce4util-4.10.1
+	>=xfce-base/libxfce4ui-4.10
+	>=xfce-base/xfconf-4.10
+	!xfce-base/xfce-utils
+	policykit? ( >=sys-auth/polkit-0.100 )"
+RDEPEND="${COMMON_DEPEND}
+	x11-apps/xrdb
+	x11-misc/xdg-user-dirs
+	udev? ( >=sys-power/upower-0.9.20 )
+	xscreensaver? ( || (
+		>=x11-misc/xscreensaver-5.15
+		gnome-extra/gnome-screensaver
+		>=x11-misc/xlockmore-5.38
+		>=x11-misc/slock-1
+		) )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+pkg_setup() {
+	XFCONF=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		$(use_enable policykit systemd)
+		--with-xsession-prefix="${EPREFIX}"/usr
+		$(xfconf_use_debug)
+		)
+
+	DOCS=( AUTHORS BUGS ChangeLog NEWS README TODO )
+}
+
+src_install() {
+	xfconf_src_install
+
+	local sessiondir=/etc/X11/Sessions
+	echo startxfce4 > "${T}"/Xfce4
+	exeinto ${sessiondir}
+	doexe "${T}"/Xfce4
+	dosym Xfce4 ${sessiondir}/Xfce
+}