Version bump for Gnome 3.8

(Portage version: 2.1.11.58/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

3 files changed, 70 insertions, 1 deletions

diff --git a/x11-terms/gnome-terminal/ChangeLog b/x11-terms/gnome-terminal/ChangeLog
index 6cbe1159394d..61f384c572b6 100644
--- a/x11-terms/gnome-terminal/ChangeLog
+++ b/x11-terms/gnome-terminal/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for x11-terms/gnome-terminal
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-terms/gnome-terminal/ChangeLog,v 1.262 2013/03/28 16:05:25 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-terms/gnome-terminal/ChangeLog,v 1.263 2013/03/28 22:26:30 pacho Exp $
+
+*gnome-terminal-3.8.0 (28 Mar 2013)
+
+  28 Mar 2013; Pacho Ramos <pacho@gentoo.org> +gnome-terminal-3.8.0.ebuild,
+  metadata.xml:
+  Version bump for Gnome 3.8
 
   28 Mar 2013; Agostino Sarubbo <ago@gentoo.org>
   gnome-terminal-2.32.1-r1.ebuild:
diff --git a/x11-terms/gnome-terminal/gnome-terminal-3.8.0.ebuild b/x11-terms/gnome-terminal/gnome-terminal-3.8.0.ebuild
new file mode 100644
index 000000000000..8c24f551f752
--- /dev/null
+++ b/x11-terms/gnome-terminal/gnome-terminal-3.8.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-terms/gnome-terminal/gnome-terminal-3.8.0.ebuild,v 1.1 2013/03/28 22:26:30 pacho Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2
+
+DESCRIPTION="The Gnome Terminal"
+HOMEPAGE="http://www.gnome.org/"
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="+nautilus"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux"
+
+# FIXME: automagic dependency on gtk+[X]
+RDEPEND="
+	>=dev-libs/glib-2.33.2:2
+	>=x11-libs/gtk+-3.6:3[X]
+	>=x11-libs/vte-0.34.0:2.90
+	>=gnome-base/gconf-2.31.3
+	>=gnome-base/dconf-0.12
+	>=gnome-base/gsettings-desktop-schemas-0.1.0
+	x11-libs/libSM
+	x11-libs/libICE
+	nautilus? ( >=gnome-base/nautilus-3 )
+"
+# gtk+:2 needed for gtk-builder-convert, bug 356239
+DEPEND="${RDEPEND}
+	|| ( dev-util/gtk-builder-convert <=x11-libs/gtk+-2.24.10:2 )
+	app-text/yelp-tools
+	>=dev-util/intltool-0.40
+	>=gnome-base/dconf-0.14.0
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	DOCS="AUTHORS ChangeLog HACKING NEWS"
+	# FIXME: leave smclient configure unset until it accepts values from the
+	# switch and not from GDK_TARGET, bug #363033
+	G2CONF="${G2CONF}
+		--enable-migration
+		$(use_with nautilus nautilus-extension)"
+
+	gnome2_src_configure
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	if [[ ${REPLACING_VERSIONS} < 3.6.1-r1 && ${REPLACING_VERSIONS} != 2.32.1-r1 &&
+		  ${REPLACING_VERSIONS} != 3.4.1.1-r1 ]]; then
+		elog "Gnome Terminal no longer uses login shell by default, switching"
+		elog "to upstream default. Because of this, if you have some command you"
+		elog "want to be run, be sure to have it placed in your ~/.bashrc file."
+	fi
+}
diff --git a/x11-terms/gnome-terminal/metadata.xml b/x11-terms/gnome-terminal/metadata.xml
index da6fd63d0085..6b23610944af 100644
--- a/x11-terms/gnome-terminal/metadata.xml
+++ b/x11-terms/gnome-terminal/metadata.xml
@@ -2,4 +2,7 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 <herd>gnome</herd>
+<use>
+<flag name="nautilus">Build gnome-base/nautilus extension</flag>
+</use>
 </pkgmetadata>