Version bump, add explicit choice of crypto provider

(Portage version: 2.2.7/cvs/Linux x86_64, unsigned Manifest commit)

3 files changed, 79 insertions, 2 deletions

diff --git a/x11-plugins/pidgin-sipe/ChangeLog b/x11-plugins/pidgin-sipe/ChangeLog
index 9daffb524f0d..67c60622322a 100644
--- a/x11-plugins/pidgin-sipe/ChangeLog
+++ b/x11-plugins/pidgin-sipe/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for x11-plugins/pidgin-sipe
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-plugins/pidgin-sipe/ChangeLog,v 1.25 2013/12/17 21:49:56 thev00d00 Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-plugins/pidgin-sipe/ChangeLog,v 1.26 2014/01/30 22:09:01 thev00d00 Exp $
+
+*pidgin-sipe-1.18.0 (30 Jan 2014)
+
+  30 Jan 2014; Ian Whyman <thev00d00@gentoo.org> +pidgin-sipe-1.18.0.ebuild,
+  metadata.xml:
+  Version bump, add explicit choice of crypto provider
 
 *pidgin-sipe-1.17.3 (17 Dec 2013)
 
diff --git a/x11-plugins/pidgin-sipe/metadata.xml b/x11-plugins/pidgin-sipe/metadata.xml
index 3406c48190c1..5b18d033d8c9 100644
--- a/x11-plugins/pidgin-sipe/metadata.xml
+++ b/x11-plugins/pidgin-sipe/metadata.xml
@@ -13,5 +13,7 @@ An Open Implementation of SIP/Simple protocol for Live Communications Server 200
   <flag name="ocs2005-message-hack">Disable message timeout for OCS2005 clients which causes "false" not delivered error messages</flag>
   <flag name="telepathy">Support use as a telepathy backend</flag>
   <flag name="voice">Enable experimental voice/video support</flag>
+  <flag name="nss">Enable crypto support via <pkg>dev-libs/nss</pkg></flag>
+  <flag name="openssl">Enable crypto support via <pkg>dev-libs/openssl</pkg></flag>
 </use>
 </pkgmetadata>
diff --git a/x11-plugins/pidgin-sipe/pidgin-sipe-1.18.0.ebuild b/x11-plugins/pidgin-sipe/pidgin-sipe-1.18.0.ebuild
new file mode 100644
index 000000000000..c014f765f5ae
--- /dev/null
+++ b/x11-plugins/pidgin-sipe/pidgin-sipe-1.18.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-plugins/pidgin-sipe/pidgin-sipe-1.18.0.ebuild,v 1.1 2014/01/30 22:09:01 thev00d00 Exp $
+
+EAPI=5
+
+inherit autotools eutils
+
+DESCRIPTION="Pidgin Plug-in SIPE (Sip Exchange Protocol)"
+HOMEPAGE="http://sipe.sourceforge.net/"
+SRC_URI="mirror://sourceforge/sipe/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="debug kerberos nss ocs2005-message-hack openssl telepathy voice"
+REQUIRED_USE="^^ ( openssl nss )"
+
+RDEPEND=">=dev-libs/gmime-2.4.16
+	dev-libs/libxml2
+	nss? ( dev-libs/nss )
+	openssl? ( dev-libs/openssl )
+	kerberos? ( virtual/krb5 )
+	voice? (
+		>=dev-libs/glib-2.28.0
+		>=net-libs/libnice-0.1.0
+		media-libs/gstreamer:0.10
+		>=net-im/pidgin-2.8.0
+	)
+	!voice? (
+		>=dev-libs/glib-2.12.0:2
+		net-im/pidgin
+	)
+	telepathy? (
+		>=sys-apps/dbus-1.1.0
+		>=dev-libs/dbus-glib-0.61
+		>=dev-libs/glib-2.28:2
+		>=net-libs/telepathy-glib-0.18.0
+	)
+"
+
+DEPEND="dev-util/intltool
+	virtual/pkgconfig
+	${RDEPEND}
+"
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-1.13.2-fix-sandbox-r1.patch"
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-purple \
+		--disable-quality-check \
+		$(use_enable telepathy) \
+		$(use_enable debug) \
+		$(use_enable ocs2005-message-hack) \
+		$(use_with kerberos krb5) \
+		$(use_with voice vv) \
+		$(use_enable openssl) \
+		$(use_enable nss)
+}
+
+src_install() {
+	emake install DESTDIR="${D}"
+	dodoc AUTHORS ChangeLog NEWS TODO README
+}