Remove apparmor profiles per #494426. Thanks to Balazs Nemeth <jobbara.artalmatlan@gmail.com>

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key C2BA7F3C!)

3 files changed, 125 insertions, 2 deletions

diff --git a/x11-misc/lightdm/ChangeLog b/x11-misc/lightdm/ChangeLog
index 72cd15537e49..d99ba4d25558 100644
--- a/x11-misc/lightdm/ChangeLog
+++ b/x11-misc/lightdm/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for x11-misc/lightdm
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/ChangeLog,v 1.78 2013/12/11 21:43:49 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/ChangeLog,v 1.79 2013/12/22 13:35:38 hwoarang Exp $
+
+*lightdm-1.8.5-r1 (22 Dec 2013)
+
+  22 Dec 2013; Markos Chandras <hwoarang@gentoo.org> +lightdm-1.8.5-r1.ebuild,
+  lightdm-1.9.5.ebuild:
+  Remove apparmor profiles per #494426. Thanks to Balazs Nemeth
+  <jobbara.artalmatlan@gmail.com>
 
   11 Dec 2013; Pacho Ramos <pacho@gentoo.org> lightdm-1.8.5.ebuild:
   amd64/x86 stable, bug #492796
diff --git a/x11-misc/lightdm/lightdm-1.8.5-r1.ebuild b/x11-misc/lightdm/lightdm-1.8.5-r1.ebuild
new file mode 100644
index 000000000000..15e267384034
--- /dev/null
+++ b/x11-misc/lightdm/lightdm-1.8.5-r1.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/lightdm-1.8.5-r1.ebuild,v 1.1 2013/12/22 13:35:38 hwoarang Exp $
+
+EAPI=5
+inherit autotools eutils pam readme.gentoo systemd
+
+TRUNK_VERSION="1.8"
+DESCRIPTION="A lightweight display manager"
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/LightDM"
+SRC_URI="http://launchpad.net/${PN}/${TRUNK_VERSION}/${PV}/+download/${P}.tar.xz
+	mirror://gentoo/introspection-20110205.m4.tar.bz2"
+
+LICENSE="GPL-3 LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+IUSE="+gtk +introspection kde qt4 razor"
+REQUIRED_USE="|| ( gtk kde razor )"
+
+COMMON_DEPEND=">=dev-libs/glib-2.32.3:2
+	dev-libs/libxml2
+	sys-apps/accountsservice
+	virtual/pam
+	x11-libs/libX11
+	>=x11-libs/libxklavier-5
+	introspection? ( >=dev-libs/gobject-introspection-1 )
+	qt4? (
+		dev-qt/qtcore:4
+		dev-qt/qtdbus:4
+		dev-qt/qtgui:4
+		)"
+RDEPEND="${COMMON_DEPEND}
+	>=sys-auth/pambase-20101024-r2"
+DEPEND="${COMMON_DEPEND}
+	dev-util/gtk-doc-am
+	dev-util/intltool
+	gnome-base/gnome-common
+	sys-devel/gettext
+	virtual/pkgconfig"
+PDEPEND="gtk? ( x11-misc/lightdm-gtk-greeter )
+	kde? ( x11-misc/lightdm-kde )
+	razor? ( razorqt-base/razorqt-lightdm-greeter )"
+
+RESTRICT="test"
+DOCS=( NEWS )
+
+src_prepare() {
+	sed -i -e 's:getgroups:lightdm_&:' tests/src/libsystem.c || die #412369
+	sed -i -e '/minimum-uid/s:500:1000:' data/users.conf || die
+
+	epatch "${FILESDIR}"/${PN}-1.7.7-session-wrapper.patch
+	epatch_user
+
+	# Remove bogus Makefile statement. This needs to go upstream
+	sed -i /"@YELP_HELP_RULES@"/d help/Makefile.am || die
+	if has_version dev-libs/gobject-introspection; then
+		eautoreconf
+	else
+		AT_M4DIR=${WORKDIR} eautoreconf
+	fi
+}
+
+src_configure() {
+	# Set default values if global vars unset
+	local _greeter _session _user
+	_greeter=${LIGHTDM_GREETER:=lightdm-gtk-greeter}
+	_session=${LIGHTDM_SESSION:=gnome}
+	_user=${LIGHTDM_USER:=root}
+	# Let user know how lightdm is configured
+	einfo "Gentoo configuration"
+	einfo "Default greeter: ${_greeter}"
+	einfo "Default session: ${_session}"
+	einfo "Greeter user: ${_user}"
+
+	econf \
+		--localstatedir=/var \
+		--disable-static \
+		$(use_enable introspection) \
+		$(use_enable qt4 liblightdm-qt) \
+		--with-user-session=${_session} \
+		--with-greeter-session=${_greeter} \
+		--with-greeter-user=${_user} \
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
+}
+
+src_install() {
+	default
+
+	# Delete apparmor profiles because they only work with Ubuntu's
+	# apparmor package. Bug #494426
+	if [[ -d ${D}/etc/apparmor.d ]]; then
+		rm -r "${D}/etc/apparmor.d" || die \
+			"Failed to remove apparmor profiles"
+	fi
+	insinto /etc/${PN}
+	doins data/{${PN},keys}.conf
+	doins "${FILESDIR}"/Xsession
+	fperms +x /etc/${PN}/Xsession
+
+	prune_libtool_files --all
+	rm -rf "${ED}"/etc/init
+
+	pamd_mimic system-local-login ${PN} auth account session #372229
+	dopamd "${FILESDIR}"/${PN}-autologin #390863, #423163
+
+	readme.gentoo_create_doc
+
+	systemd_dounit "${FILESDIR}/${PN}.service"
+}
diff --git a/x11-misc/lightdm/lightdm-1.9.5.ebuild b/x11-misc/lightdm/lightdm-1.9.5.ebuild
index 9a75d8c6cb6e..0ef5718fcb58 100644
--- a/x11-misc/lightdm/lightdm-1.9.5.ebuild
+++ b/x11-misc/lightdm/lightdm-1.9.5.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/lightdm-1.9.5.ebuild,v 1.2 2013/12/11 21:28:26 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/lightdm-1.9.5.ebuild,v 1.3 2013/12/22 13:35:38 hwoarang Exp $
 
 EAPI=5
 inherit autotools eutils pam readme.gentoo systemd
@@ -86,6 +86,13 @@ src_configure() {
 src_install() {
 	default
 
+	# Delete apparmor profiles because they only work with Ubuntu's
+	# apparmor package. Bug #494426
+	if [[ -d ${D}/etc/apparmor.d ]]; then
+		rm -r "${D}/etc/apparmor.d" || die \
+			"Failed to remove apparmor profiles"
+	fi
+
 	insinto /etc/${PN}
 	doins data/{${PN},keys}.conf
 	doins "${FILESDIR}"/Xsession