x11-misc/redshift: 1.8 (bug #489182)

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 0x401A1600)

2 files changed, 84 insertions, 1 deletions

diff --git a/x11-misc/redshift/ChangeLog b/x11-misc/redshift/ChangeLog
index 291c9e1d1dc7..5e0b0d90921b 100644
--- a/x11-misc/redshift/ChangeLog
+++ b/x11-misc/redshift/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for x11-misc/redshift
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/redshift/ChangeLog,v 1.19 2013/02/17 22:38:57 sping Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/redshift/ChangeLog,v 1.20 2013/10/23 19:18:10 sping Exp $
+
+*redshift-1.8 (23 Oct 2013)
+
+  23 Oct 2013; Sebastian Pipping <sping@gentoo.org> +redshift-1.8.ebuild:
+  Bump to 1.8 (bug #489182)
 
   17 Feb 2013; Sebastian Pipping <sping@gentoo.org> redshift-1.7-r1.ebuild:
   Migrate to python-r1 (bug #440180). Thanks for the initial patch to Michał
diff --git a/x11-misc/redshift/redshift-1.8.ebuild b/x11-misc/redshift/redshift-1.8.ebuild
new file mode 100644
index 000000000000..695dc0f65888
--- /dev/null
+++ b/x11-misc/redshift/redshift-1.8.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/redshift/redshift-1.8.ebuild,v 1.1 2013/10/23 19:18:10 sping Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit autotools eutils gnome2-utils python-r1
+
+DESCRIPTION="A screen color temperature adjusting software"
+HOMEPAGE="http://jonls.dk/redshift/"
+SRC_URI="https://github.com/jonls/redshift/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="geoclue gnome gtk nls"
+
+COMMON_DEPEND=">=x11-libs/libX11-1.4
+	x11-libs/libXxf86vm
+	x11-libs/libxcb
+	geoclue? ( app-misc/geoclue )
+	gnome? ( dev-libs/glib:2
+		>=gnome-base/gconf-2 )
+	gtk? ( ${PYTHON_DEPS} )"
+RDEPEND="${COMMON_DEPEND}
+	gtk? ( >=dev-python/pygtk-2[${PYTHON_USEDEP}]
+		dev-python/pyxdg[${PYTHON_USEDEP}] )"
+DEPEND="${COMMON_DEPEND}
+	nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	epatch_user
+	eautoreconf
+}
+
+src_configure() {
+	python_export_best
+
+	econf \
+		--disable-silent-rules \
+		$(use_enable nls) \
+		--enable-randr \
+		--enable-vidmode \
+		--disable-wingdi \
+		$(use_enable gnome gnome-clock) \
+		$(use_enable geoclue) \
+		$(use_enable gtk gui) \
+		--disable-ubuntu
+}
+
+_impl_specific_src_install() {
+	emake DESTDIR="${D}" pythondir="$(python_get_sitedir)" \
+			-C src/redshift-gtk install
+}
+
+src_install() {
+	default
+
+	if use gtk; then
+		python_foreach_impl _impl_specific_src_install
+		python_replicate_script "${D}"/usr/bin/redshift-gtk
+	fi
+
+	dosym redshift-gtk /usr/bin/gtk-redshift
+}
+
+pkg_preinst() {
+	use gtk && gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	use gtk && gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	use gtk && gnome2_icon_cache_update
+}