Initial import wrt bug 336304. Ebuild written by Samuli Suominen <ssuominen@gentoo.org>.

(Portage version: 2.1.9/cvs/Linux x86_64)

3 files changed, 82 insertions, 0 deletions

diff --git a/x11-misc/lightdm/ChangeLog b/x11-misc/lightdm/ChangeLog
new file mode 100644
index 000000000000..629e82f0c9f0
--- /dev/null
+++ b/x11-misc/lightdm/ChangeLog
@@ -0,0 +1,11 @@
+# ChangeLog for x11-misc/lightdm
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/ChangeLog,v 1.1 2010/09/07 18:35:47 xarthisius Exp $
+
+*lightdm-0.1.1 (07 Sep 2010)
+
+  07 Sep 2010; Kacper Kowalik <xarthisius@gentoo.org> +lightdm-0.1.1.ebuild,
+  +metadata.xml:
+  Initial import wrt bug 336304. Ebuild written by Samuli Suominen
+  <ssuominen@gentoo.org>.
+
diff --git a/x11-misc/lightdm/lightdm-0.1.1.ebuild b/x11-misc/lightdm/lightdm-0.1.1.ebuild
new file mode 100644
index 000000000000..29e2cb9d2d09
--- /dev/null
+++ b/x11-misc/lightdm/lightdm-0.1.1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/lightdm-0.1.1.ebuild,v 1.1 2010/09/07 18:35:47 xarthisius Exp $
+
+EAPI=2
+
+inherit eutils pam
+
+DESCRIPTION="A lightweight display manager"
+HOMEPAGE="http://launchpad.net/lightdm"
+SRC_URI="http://people.ubuntu.com/~robert-ancell/${PN}/releases/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="consolekit nls"
+
+RDEPEND="dev-libs/glib:2
+	dev-libs/dbus-glib
+	net-libs/webkit-gtk
+	x11-libs/gtk+:2
+	x11-libs/libxcb
+	x11-libs/libXdmcp
+	x11-libs/libxklavier
+	consolekit? ( sys-auth/consolekit )
+	virtual/pam"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	nls? ( dev-util/intltool )"
+
+src_prepare() {
+	# hardcoded service name to start PAM session
+	sed -e "s/check_pass/${PN}/" -i src/pam-session.c || die #report me upstream
+	# Fix ubuntu way of launching WM
+	sed -e "s:/etc/X11/Xsession::" -i src/display.c || die #report me upstream
+}
+
+src_configure() {
+	econf \
+		--disable-static \
+		--disable-dependency-tracking \
+		--disable-introspection \
+		$(use_enable consolekit console-kit) \
+		--disable-scrollkeeper \
+		$(use_enable nls) \
+		--with-html-dir=/usr/share/doc/${PF}/html \
+		--localstatedir=/var  #overcoming econf default (fix me?)
+
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	pamd_mimic_system lightdm auth account password session
+	dodoc ChangeLog NEWS || die
+	find "${D}" -name '*.la' -exec rm -f '{}' +
+}
diff --git a/x11-misc/lightdm/metadata.xml b/x11-misc/lightdm/metadata.xml
new file mode 100644
index 000000000000..22158347ab8e
--- /dev/null
+++ b/x11-misc/lightdm/metadata.xml
@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<herd>desktop-misc</herd>
+	<longdescription>An X display manager that:
+	 * Has a lightweight codebase
+	 * Is standards compliant (PAM, ConsoleKit, etc)
+	 * Has a well defined interface between the server and user interface
+	 * Fully themeable (easiest with the webkit interface)
+	 * Cross-desktop (greeters can be written in any toolkit)
+	</longdescription>
+	<use>
+	  <flag name="consolekit">Enables support for authorization using consolekit</flag>
+    </use>
+</pkgmetadata>