Hack USE=xft onto imake build (bug #514110).

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A792A613)

3 files changed, 79 insertions, 48 deletions

diff --git a/x11-misc/dclock/ChangeLog b/x11-misc/dclock/ChangeLog
index 762fc4bd67c8..3c5ec58652bb 100644
--- a/x11-misc/dclock/ChangeLog
+++ b/x11-misc/dclock/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for x11-misc/dclock
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/dclock/ChangeLog,v 1.19 2012/05/22 20:59:25 ranger Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/dclock/ChangeLog,v 1.20 2014/07/02 00:46:39 jer Exp $
+
+*dclock-2.2.2_p4-r1 (02 Jul 2014)
+
+  02 Jul 2014; Jeroen Roovers <jer@gentoo.org> -dclock-2.1.2_p8.ebuild,
+  +dclock-2.2.2_p4-r1.ebuild:
+  Hack USE=xft onto imake build (bug #514110).
 
   22 May 2012; Brent Baude <ranger@gentoo.org> dclock-2.2.2_p4.ebuild:
   Marking dclock-2.2.2_p4 ppc for bug 416087
diff --git a/x11-misc/dclock/dclock-2.1.2_p8.ebuild b/x11-misc/dclock/dclock-2.1.2_p8.ebuild
deleted file mode 100644
index 60b7ed2b9a5a..000000000000
--- a/x11-misc/dclock/dclock-2.1.2_p8.ebuild
+++ /dev/null
@@ -1,46 +0,0 @@
-# Copyright 1999-2010 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/dclock/dclock-2.1.2_p8.ebuild,v 1.4 2010/07/21 14:39:02 ssuominen Exp $
-
-inherit eutils
-
-DESCRIPTION="Digital clock for the X window system."
-HOMEPAGE="ftp://ftp.ac-grenoble.fr/ge/Xutils/"
-SRC_URI="mirror://debian/pool/main/d/${PN}/${PN}_${PV/_p*/}.orig.tar.gz
-		mirror://debian/pool/main/d/${PN}/${PN}_${PV/_p/-}.diff.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="amd64 ppc x86"
-IUSE=""
-
-RDEPEND="x11-libs/libX11
-	x11-libs/libXt
-	x11-libs/libXext
-	app-text/rman"
-DEPEND="${RDEPEND}
-	x11-misc/imake"
-
-S=${WORKDIR}/${PN}
-
-src_unpack() {
-	unpack ${A}
-	cd "${S}"
-	epatch ../${PN}_${PV/_p/-}.diff
-	ln -sf dclock.1 dclock.man # needed to fix xmkmf breakage
-}
-
-src_compile() {
-	xmkmf || die
-	emake CFLAGS="${CFLAGS}" || die
-}
-
-src_install() {
-	emake DESTDIR="${D}" install || die
-	emake DESTDIR="${D}" install.man || die
-	insinto /usr/share/sounds
-	doins sounds/* || die
-	insinto /usr/share/X11/app-defaults
-	newins Dclock.ad DClock || die
-	dodoc README TODO
-}
diff --git a/x11-misc/dclock/dclock-2.2.2_p4-r1.ebuild b/x11-misc/dclock/dclock-2.2.2_p4-r1.ebuild
new file mode 100644
index 000000000000..daef377449ef
--- /dev/null
+++ b/x11-misc/dclock/dclock-2.2.2_p4-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/dclock/dclock-2.2.2_p4-r1.ebuild,v 1.1 2014/07/02 00:46:39 jer Exp $
+
+EAPI=4
+inherit eutils flag-o-matic toolchain-funcs
+
+DESCRIPTION="Digital clock for the X window system."
+HOMEPAGE="http://packages.qa.debian.org/d/dclock.html"
+SRC_URI="mirror://debian/pool/main/d/${PN}/${PN}_${PV/_p*/}.orig.tar.gz
+		mirror://debian/pool/main/d/${PN}/${PN}_${PV/_p/-}.debian.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="xft"
+
+RDEPEND="
+	xft? (
+		media-libs/freetype
+		x11-libs/libXft
+	)
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXt
+"
+DEPEND="
+	${RDEPEND}
+	app-text/rman
+	x11-misc/imake
+	xft? ( virtual/pkgconfig )
+"
+
+S=${WORKDIR}/${P/_p*/}
+
+src_prepare() {
+	EPATCH_FORCE=yes EPATCH_SUFFIX=diff epatch "${WORKDIR}"/debian/patches
+	epatch "${FILESDIR}"/${P}-include.patch
+}
+
+src_configure() {
+	if use xft; then
+		append-cppflags \
+			-DXFT_SUPPORT \
+			$( $(tc-getPKG_CONFIG) --cflags freetype2)
+	else
+		append-cppflags -UXFT_SUPPORT
+		sed -i -e '/EXTRA_LIBRARIES/s|^|#|g' Imakefile || die
+	fi
+
+	xmkmf || die
+}
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		CFLAGS="${CFLAGS}" \
+		EXTRA_LDOPTIONS="${LDFLAGS}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install{,.man}
+
+	insinto /usr/share/sounds
+	doins sounds/*
+
+	insinto /usr/share/X11/app-defaults
+	newins Dclock.ad DClock
+
+	dodoc README TODO
+}