Bump to 0.28.0, add both gtk2 and gtk3 versions

(Portage version: 2.1.9.46/cvs/Linux x86_64)

3 files changed, 121 insertions, 1 deletions

diff --git a/x11-libs/vte/ChangeLog b/x11-libs/vte/ChangeLog
index 3704e6b1bfcf..7562fa32301e 100644
--- a/x11-libs/vte/ChangeLog
+++ b/x11-libs/vte/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for x11-libs/vte
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/vte/ChangeLog,v 1.274 2011/04/10 09:07:41 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/vte/ChangeLog,v 1.275 2011/04/30 10:16:48 nirbheek Exp $
+
+*vte-0.28.0-r300 (30 Apr 2011)
+*vte-0.28.0-r200 (30 Apr 2011)
+
+  30 Apr 2011; Nirbheek Chauhan <nirbheek@gentoo.org>
+  +vte-0.28.0-r200.ebuild, +vte-0.28.0-r300.ebuild:
+  Bump to 0.28.0, add both gtk2 and gtk3 versions
 
   10 Apr 2011; Samuli Suominen <ssuominen@gentoo.org> vte-0.26.2.ebuild:
   Punt useless libtool file.
diff --git a/x11-libs/vte/vte-0.28.0-r200.ebuild b/x11-libs/vte/vte-0.28.0-r200.ebuild
new file mode 100644
index 000000000000..26214c07ef4f
--- /dev/null
+++ b/x11-libs/vte/vte-0.28.0-r200.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/vte/vte-0.28.0-r200.ebuild,v 1.1 2011/04/30 10:16:48 nirbheek Exp $
+
+EAPI="3"
+GCONF_DEBUG="yes"
+GNOME2_LA_PUNT="yes"
+PYTHON_DEPEND="python? 2:2.4"
+
+inherit gnome2 python
+
+DESCRIPTION="GNOME terminal widget"
+HOMEPAGE="http://git.gnome.org/browse/vte"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="debug doc glade +introspection python"
+
+PDEPEND="x11-libs/gnome-pty-helper"
+RDEPEND=">=dev-libs/glib-2.26:2
+	>=x11-libs/gtk+-2.20:2[introspection?]
+	>=x11-libs/pango-1.22.0
+
+	sys-libs/ncurses
+	x11-libs/libX11
+	x11-libs/libXft
+
+	glade? ( <dev-util/glade-3.9:3 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.0 )
+	python? ( >=dev-python/pygtk-2.4:2 )"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.35
+	>=dev-util/pkgconfig-0.9
+	sys-devel/gettext
+	doc? ( >=dev-util/gtk-doc-1.13 )"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--disable-gnome-pty-helper
+		--disable-deprecation
+		--disable-maintainer-mode
+		--disable-static
+		$(use_enable debug)
+		$(use_enable glade glade-catalogue)
+		$(use_enable introspection)
+		$(use_enable python)
+		--with-gtk=2.0"
+	DOCS="AUTHORS ChangeLog HACKING NEWS README"
+	use python && python_set_active_version 2
+}
+
+src_install() {
+	gnome2_src_install
+	use python && python_clean_installation_image
+}
diff --git a/x11-libs/vte/vte-0.28.0-r300.ebuild b/x11-libs/vte/vte-0.28.0-r300.ebuild
new file mode 100644
index 000000000000..98ddf2649fd5
--- /dev/null
+++ b/x11-libs/vte/vte-0.28.0-r300.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/vte/vte-0.28.0-r300.ebuild,v 1.1 2011/04/30 10:16:49 nirbheek Exp $
+
+EAPI="3"
+GCONF_DEBUG="yes"
+GNOME2_LA_PUNT="yes"
+
+inherit autotools eutils gnome2
+
+DESCRIPTION="GNOME terminal widget"
+HOMEPAGE="http://git.gnome.org/browse/vte"
+
+LICENSE="LGPL-2"
+SLOT="2.90"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="debug doc glade +introspection"
+
+PDEPEND="x11-libs/gnome-pty-helper"
+RDEPEND=">=dev-libs/glib-2.26:2
+	>=x11-libs/gtk+-3.0:3[introspection?]
+	>=x11-libs/pango-1.22.0
+
+	sys-libs/ncurses
+	x11-libs/libX11
+	x11-libs/libXft
+
+	glade? ( >=dev-util/glade-3.9:3 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.0 )"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.35
+	>=dev-util/pkgconfig-0.9
+	sys-devel/gettext
+	doc? ( >=dev-util/gtk-doc-1.13 )"
+
+pkg_setup() {
+	# Python bindings are via gobject-introspection
+	# Ex: from gi.repository import Vte
+	G2CONF="${G2CONF}
+		--disable-gnome-pty-helper
+		--disable-deprecation
+		--disable-maintainer-mode
+		--disable-static
+		$(use_enable debug)
+		$(use_enable glade glade-catalogue)
+		$(use_enable introspection)
+		--with-gtk=3.0"
+	DOCS="AUTHORS ChangeLog HACKING NEWS README"
+}
+
+src_prepare() {
+	epatch "${FILESDIR}/${P}-fix-gdk-targets.patch"
+
+	eautoreconf
+
+	gnome2_src_prepare
+}