Version bump

(Portage version: 2.2_rc61/cvs/Linux x86_64)

2 files changed, 86 insertions, 1 deletions

diff --git a/x11-libs/qscintilla/ChangeLog b/x11-libs/qscintilla/ChangeLog
index 152d56a2095a..621646964102 100644
--- a/x11-libs/qscintilla/ChangeLog
+++ b/x11-libs/qscintilla/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for x11-libs/qscintilla
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/qscintilla/ChangeLog,v 1.39 2010/01/06 21:10:25 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/qscintilla/ChangeLog,v 1.40 2010/01/15 16:23:07 yngwin Exp $
+
+*qscintilla-2.4.1 (15 Jan 2010)
+
+  15 Jan 2010; Ben de Groot <yngwin@gentoo.org> +qscintilla-2.4.1.ebuild:
+  Version bump
 
   06 Jan 2010; Brent Baude <ranger@gentoo.org> qscintilla-2.4.ebuild:
   Marking qscintilla-2.4 ppc64 for bug 284707
diff --git a/x11-libs/qscintilla/qscintilla-2.4.1.ebuild b/x11-libs/qscintilla/qscintilla-2.4.1.ebuild
new file mode 100644
index 000000000000..e31d38ee2c59
--- /dev/null
+++ b/x11-libs/qscintilla/qscintilla-2.4.1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/qscintilla/qscintilla-2.4.1.ebuild,v 1.1 2010/01/15 16:23:07 yngwin Exp $
+
+EAPI="2"
+
+inherit qt4-r2
+
+MY_P="QScintilla-gpl-${PV/_pre/-snapshot-}"
+
+DESCRIPTION="A Qt port of Neil Hodgson's Scintilla C++ editor class"
+HOMEPAGE="http://www.riverbankcomputing.co.uk/software/qscintilla/intro"
+SRC_URI="http://www.riverbankcomputing.co.uk/static/Downloads/QScintilla2/${MY_P}.tar.gz"
+
+LICENSE="|| ( GPL-2 GPL-3 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="doc python"
+
+DEPEND="x11-libs/qt-gui:4"
+RDEPEND="${DEPEND}"
+PDEPEND="python? ( ~dev-python/qscintilla-python-${PV} )"
+
+S="${WORKDIR}"/${MY_P}
+
+PATCHES=( "${FILESDIR}/${PN}-2.4-designer.patch" )
+
+src_configure() {
+	cd "${S}"/Qt4
+	eqmake4 qscintilla.pro
+
+	cd "${S}"/designer-Qt4
+	eqmake4 designer.pro
+}
+
+src_compile() {
+	cd "${S}"/Qt4
+	emake all staticlib || die "emake failed"
+
+	cd "${S}"/designer-Qt4
+	emake || die "failed to build designer plugin"
+}
+
+src_install() {
+	cd "${S}"/Qt4
+
+	# header files
+	insinto /usr/include/Qsci
+	doins Qsci/*.h || die
+
+	# libraries
+	dolib.so libqscintilla2.so* || die
+	dolib.a libqscintilla2.a || die
+
+	# translations
+	insinto /usr/share/${PN}/translations
+	for trans in qscintilla_*.qm; do
+		doins ${trans} || die
+		dosym /usr/share/${PN}/translations/${trans} \
+			/usr/share/qt4/translations/${trans} || die
+	done
+
+	# designer plugin
+	cd "${S}"/designer-Qt4
+	emake INSTALL_ROOT="${D}" install || die "designer plugin installation failed"
+
+	# documentation
+	cd "${S}"
+	dodoc ChangeLog NEWS
+	if use doc; then
+		dohtml doc/html-Qt4/* || die
+		insinto /usr/share/doc/${PF}/Scintilla
+		doins doc/Scintilla/* || die
+	fi
+}
+
+pkg_postinst() {
+	ewarn "Please remerge dev-python/PyQt4 if you have problems with eric or other"
+	ewarn "qscintilla related packages before submitting bug reports."
+}