add a live ebuild for the fdo version; so that people that want to play with it can, we need a few patches to be merged still

(Portage version: 2.2.0_alpha38/cvs/Linux x86_64)

2 files changed, 75 insertions, 1 deletions

diff --git a/x11-libs/libva/ChangeLog b/x11-libs/libva/ChangeLog
index 02cb19ec84c1..d360c10d0399 100644
--- a/x11-libs/libva/ChangeLog
+++ b/x11-libs/libva/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for x11-libs/libva
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/libva/ChangeLog,v 1.18 2011/04/26 11:34:30 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libva/ChangeLog,v 1.19 2011/06/07 17:00:06 aballier Exp $
+
+*libva-9999 (07 Jun 2011)
+
+  07 Jun 2011; Alexis Ballier <aballier@gentoo.org> +libva-9999.ebuild:
+  add a live ebuild for the fdo version; so that people that want to play with
+  it can, we need a few patches to be merged still
 
   26 Apr 2011; Tomáš Chvátal <scarabeus@gentoo.org> libva-0.32.0_p2.ebuild:
   Pdepend on xvba-video. Per bug #325033.
diff --git a/x11-libs/libva/libva-9999.ebuild b/x11-libs/libva/libva-9999.ebuild
new file mode 100644
index 000000000000..42b138ab6c03
--- /dev/null
+++ b/x11-libs/libva/libva-9999.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libva/libva-9999.ebuild,v 1.1 2011/06/07 17:00:06 aballier Exp $
+
+EAPI="2"
+
+SCM=""
+if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
+	SCM=git-2
+	EGIT_BRANCH=master
+	EGIT_REPO_URI="git://anongit.freedesktop.org/git/libva"
+fi
+
+inherit autotools ${SCM} multilib
+
+DESCRIPTION="Video Acceleration (VA) API for Linux"
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/vaapi"
+if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
+	SRC_URI=""
+	S="${WORKDIR}/${PN}"
+else
+	SRC_URI="http://cgit.freedesktop.org/libva/snapshot/${P}.tar.bz2"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+if [ "${PV%9999}" = "${PV}" ] ; then
+	KEYWORDS="~amd64 ~x86 ~amd64-linux"
+else
+	KEYWORDS=""
+fi
+IUSE="opengl"
+
+VIDEO_CARDS="dummy nvidia intel fglrx"
+for x in ${VIDEO_CARDS}; do
+	IUSE+=" video_cards_${x}"
+done
+
+RDEPEND=">=x11-libs/libdrm-2.4
+	video_cards_intel? ( >=x11-libs/libdrm-2.4.23[video_cards_intel] )
+	video_cards_dummy? ( sys-fs/udev )
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXfixes
+	opengl? ( virtual/opengl )"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+PDEPEND="video_cards_nvidia? ( x11-libs/vdpau-video )
+	video_cards_fglrx? ( x11-libs/xvba-video )"
+
+src_prepare() {
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-drivers-path=/usr/$(get_libdir)/va/drivers \
+		$(use_enable video_cards_dummy dummy-driver) \
+		$(use_enable video_cards_dummy dummy-backend) \
+		$(use_enable video_cards_intel i965-driver) \
+		$(use_enable opengl glx)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "make install failed"
+	find "${D}" -name '*.la' -delete
+}