Version bump thanks to Dennis Nezic (bug #303825).

(Portage version: 2.2_rc62/cvs/Linux i686)

2 files changed, 91 insertions, 1 deletions

diff --git a/x11-libs/fltk/ChangeLog b/x11-libs/fltk/ChangeLog
index 07cb41305246..2adba5632a82 100644
--- a/x11-libs/fltk/ChangeLog
+++ b/x11-libs/fltk/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for x11-libs/fltk
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/fltk/ChangeLog,v 1.148 2010/02/08 20:29:12 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/fltk/ChangeLog,v 1.149 2010/02/09 18:15:51 jer Exp $
+
+*fltk-2.0_pre6970 (09 Feb 2010)
+
+  09 Feb 2010; Jeroen Roovers <jer@gentoo.org> +fltk-2.0_pre6970.ebuild:
+  Version bump thanks to Dennis Nezic (bug #303825).
 
 *fltk-2.0_pre6786-r2 (08 Feb 2010)
 
diff --git a/x11-libs/fltk/fltk-2.0_pre6970.ebuild b/x11-libs/fltk/fltk-2.0_pre6970.ebuild
new file mode 100644
index 000000000000..7032d023a0ae
--- /dev/null
+++ b/x11-libs/fltk/fltk-2.0_pre6970.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/fltk/fltk-2.0_pre6970.ebuild,v 1.1 2010/02/09 18:15:51 jer Exp $
+
+EAPI="2"
+inherit multilib autotools flag-o-matic
+
+MY_P=${P/_pre/.x-r}
+DESCRIPTION="C++ user interface toolkit for X and OpenGL"
+HOMEPAGE="http://www.fltk.org/"
+SRC_URI="mirror://easysw/fltk/snapshots/${MY_P}.tar.bz2"
+
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+LICENSE="FLTK LGPL-2"
+SLOT="2"
+IUSE="cairo debug doc +jpeg +png opengl +xft xinerama zlib"
+
+RDEPEND="x11-libs/libXext
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libXt
+	xft? ( x11-libs/libXft )
+	png? ( media-libs/libpng )
+	jpeg? ( media-libs/jpeg )
+	opengl? ( virtual/opengl )
+	cairo? ( x11-libs/cairo )
+	xinerama? ( x11-libs/libXinerama )
+	zlib? ( sys-libs/zlib )
+	>=sys-libs/glibc-2.10"   # glibc-2.10 patch breaks with 2.9, bug 276695
+DEPEND="${RDEPEND}
+	x11-proto/xextproto
+	x11-libs/libXi
+	xinerama? ( x11-proto/xineramaproto )
+	cairo? ( dev-util/pkgconfig )
+	doc? ( app-doc/doxygen )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	epatch "${FILESDIR}"/fltk2-asneeded.patch  # bug 255494
+	epatch "${FILESDIR}"/fltk2-gcc43.patch
+	epatch "${FILESDIR}"/fltk2-ldflags.patch  # bug 251233
+	epatch "${FILESDIR}"/fltk2-fluid2.patch  # bug 282472
+	sed -i "/STRIP/d" fluid/Makefile  # don't pre-strip, bug 246694
+	use opengl || epatch "${FILESDIR}"/fltk2-nogl.patch
+	eautoreconf
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+
+	CPPFLAGS="${CPPFLAGS} -DFLTK_DOCDIR=\"/usr/share/doc/${PF}\"" \
+	econf --enable-shared --enable-threads \
+		$(use_enable debug) \
+		$(use_enable xft) \
+		$(use_enable opengl gl) \
+		$(use_enable cairo) \
+		$(use_enable jpeg) \
+		$(use_enable png) \
+		$(use_enable xinerama) \
+		$(use_enable zlib)
+}
+
+src_compile() {
+	emake || die "make failed"
+
+	if use doc; then
+		make -C documentation || die "make documentation failed"
+	fi
+}
+
+src_install() {
+	einstall includedir="${D}/usr/include" libdir="${D}/usr/$(get_libdir)/fltk"
+
+	if use doc; then
+		emake -C documentation install || die "install documentation failed"
+		dohtml -r documentation/html/* || die "install html documentation failed"
+	fi
+	dodoc CHANGES CREDITS README* TODO
+
+	echo "LDPATH=/usr/$(get_libdir)/fltk" > 99fltk-${SLOT}
+	echo "FLTK_DOCDIR=/usr/share/doc/${PF}/html" >> 99fltk-${SLOT}
+
+	doenvd 99fltk-${SLOT} || die "installing env.d file failed"
+}