Revision bump to keep .la files around per bug #336671. Fix configure phase per bug #336329, thanks to Erik Zeek for patch.

(Portage version: 2.2_rc78/cvs/Linux x86_64)

4 files changed, 29 insertions, 151 deletions

diff --git a/x11-libs/cairo/ChangeLog b/x11-libs/cairo/ChangeLog
index 56a815008337..307fc4108e9d 100644
--- a/x11-libs/cairo/ChangeLog
+++ b/x11-libs/cairo/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for x11-libs/cairo
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/ChangeLog,v 1.260 2010/09/10 09:47:45 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/ChangeLog,v 1.261 2010/09/10 10:30:53 scarabeus Exp $
+
+*cairo-1.10.0-r3 (10 Sep 2010)
+
+  10 Sep 2010; Tomáš Chvátal <scarabeus@gentoo.org>
+  -cairo-1.10.0-r1.ebuild, -cairo-1.10.0-r2.ebuild, +cairo-1.10.0-r3.ebuild,
+  +files/cairo-1.10.0-install-sh.patch:
+  Revision bump to keep .la files around per bug #336671. Fix configure
+  phase per bug #336329, thanks to Erik Zeek for patch.
 
 *cairo-1.10.0-r2 (10 Sep 2010)
 
diff --git a/x11-libs/cairo/cairo-1.10.0-r2.ebuild b/x11-libs/cairo/cairo-1.10.0-r2.ebuild
deleted file mode 100644
index 912b9b857915..000000000000
--- a/x11-libs/cairo/cairo-1.10.0-r2.ebuild
+++ /dev/null
@@ -1,147 +0,0 @@
-# Copyright 1999-2010 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-1.10.0-r2.ebuild,v 1.1 2010/09/10 09:47:45 ssuominen Exp $
-
-EAPI=3
-
-EGIT_REPO_URI="git://anongit.freedesktop.org/git/cairo"
-[[ ${PV} == *9999 ]] && GIT_ECLASS="git"
-
-inherit eutils flag-o-matic autotools ${GIT_ECLASS}
-
-DESCRIPTION="A vector graphics library with cross-device output support"
-HOMEPAGE="http://cairographics.org/"
-[[ ${PV} == *9999 ]] || SRC_URI="http://cairographics.org/releases/${P}.tar.gz"
-
-LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
-IUSE="X aqua debug directfb doc drm gallium opengl openvg qt4 static-libs +svg xcb"
-
-# Test causes a circular depend on gtk+... since gtk+ needs cairo but test needs gtk+ so we need to block it
-RESTRICT="test"
-
-RDEPEND="media-libs/fontconfig
-	media-libs/freetype:2
-	media-libs/libpng:0
-	sys-libs/zlib
-	>=x11-libs/pixman-0.18.4
-	directfb? ( dev-libs/DirectFB )
-	opengl? ( virtual/opengl )
-	qt4? ( >=x11-libs/qt-gui-4.4:4 )
-	svg? ( dev-libs/libxml2 )
-	X? (
-		>=x11-libs/libXrender-0.6
-		x11-libs/libXext
-		x11-libs/libX11
-		x11-libs/libXft
-		drm? (
-			>=sys-fs/udev-136
-			gallium? ( media-libs/mesa[gallium] )
-		)
-	)
-	xcb? (
-		x11-libs/libxcb
-		x11-libs/xcb-util
-	)"
-DEPEND="${RDEPEND}
-	dev-util/pkgconfig
-	>=sys-devel/libtool-2
-	doc? (
-		>=dev-util/gtk-doc-1.6
-		~app-text/docbook-xml-dtd-4.2
-	)
-	X? (
-		x11-proto/renderproto
-		drm? (
-			x11-proto/xproto
-			>=x11-proto/xextproto-7.1
-		)
-	)"
-
-src_prepare() {
-	epatch "${FILESDIR}"/${PN}-1.8.8-interix.patch
-	epatch "${FILESDIR}"/${PN}-1.10.0-buggy_gradients.patch #336696
-
-	# Slightly messed build system YAY
-	if [[ ${PV} == *9999* ]]; then
-		touch boilerplate/Makefile.am.features
-		touch src/Makefile.am.features
-		touch ChangeLog
-	fi
-
-	# We need to run elibtoolize to ensure correct so versioning on FreeBSD
-	# upgraded to an eautoreconf for the above interix patch.
-	eautoreconf
-}
-
-src_configure() {
-	local myopts
-
-	[[ ${CHOST} == *-interix* ]] && append-flags -D_REENTRANT
-	# http://bugs.freedesktop.org/show_bug.cgi?id=15463
-	[[ ${CHOST} == *-solaris* ]] && append-flags -D_POSIX_PTHREAD_SEMANTICS
-
-	#gets rid of fbmmx.c inlining warnings
-	append-flags -finline-limit=1200
-
-	if use X; then
-		myopts+="
-			$(use_enable drm)
-		"
-
-		if use drm; then
-			myopts+="
-				$(use_enable gallium)
-				$(use_enable xcb xcb-drm)
-			"
-		else
-			use gallium && ewarn "Gallium use requires drm use enabled. So disabling for now."
-			myopts+="
-				--disable-gallium
-				--disable-xcb-drm
-			"
-		fi
-	else
-		use drm && ewarn "drm use requires X use enabled. So disabling for now."
-		myopts+="
-			--disable-drm
-			--disable-gallium
-			--disable-xcb-drm
-		"
-	fi
-
-	# --disable-xcb-lib:
-	#	do not override good xlib backed by hardforcing rendering over xcb
-	econf \
-		--disable-dependency-tracking \
-		$(use_with X x) \
-		$(use_enable X xlib) \
-		$(use_enable X xlib-xrender) \
-		$(use_enable aqua quartz) \
-		$(use_enable aqua quartz-image) \
-		$(use_enable debug test-surfaces) \
-		$(use_enable directfb) \
-		$(use_enable doc gtk-doc) \
-		$(use_enable openvg vg) \
-		$(use_enable opengl gl) \
-		$(use_enable qt4 qt) \
-		$(use_enable static-libs static) \
-		$(use_enable svg) \
-		$(use_enable xcb) \
-		$(use_enable xcb xcb-shm) \
-		--enable-ft \
-		--enable-pdf \
-		--enable-png \
-		--enable-ps \
-		--disable-xlib-xcb \
-		${myopts}
-}
-
-src_install() {
-	# parallel make install fails
-	emake -j1 DESTDIR="${D}" install || die "Installation failed"
-	dodoc AUTHORS ChangeLog NEWS README || die
-
-	use static-libs || find "${D}" -type f -name '*.la' -exec rm -f '{}' \;
-}
diff --git a/x11-libs/cairo/cairo-1.10.0-r1.ebuild b/x11-libs/cairo/cairo-1.10.0-r3.ebuild
index d1a298f02169..430a88a16ab0 100644
--- a/x11-libs/cairo/cairo-1.10.0-r1.ebuild
+++ b/x11-libs/cairo/cairo-1.10.0-r3.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-1.10.0-r1.ebuild,v 1.4 2010/09/09 19:37:28 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-1.10.0-r3.ebuild,v 1.1 2010/09/10 10:30:53 scarabeus Exp $
 
 EAPI=3
 
@@ -61,6 +61,8 @@ DEPEND="${RDEPEND}
 
 src_prepare() {
 	epatch "${FILESDIR}"/${PN}-1.8.8-interix.patch
+	epatch "${FILESDIR}"/${P}-buggy_gradients.patch #336696
+	epatch "${FILESDIR}"/${P}-install-sh.patch #336329
 
 	# Slightly messed build system YAY
 	if [[ ${PV} == *9999* ]]; then
@@ -141,6 +143,4 @@ src_install() {
 	# parallel make install fails
 	emake -j1 DESTDIR="${D}" install || die "Installation failed"
 	dodoc AUTHORS ChangeLog NEWS README || die
-
-	use static-libs || find "${D}" -type f -name '*.la' -exec rm -f '{}' \;
 }
diff --git a/x11-libs/cairo/files/cairo-1.10.0-install-sh.patch b/x11-libs/cairo/files/cairo-1.10.0-install-sh.patch
new file mode 100644
index 000000000000..b654fd10eede
--- /dev/null
+++ b/x11-libs/cairo/files/cairo-1.10.0-install-sh.patch
@@ -0,0 +1,17 @@
+--- configure.ac.orig	2010-09-09 11:23:11.298237207 -0600
++++ configure.ac	2010-09-09 11:21:38.149557655 -0600
+@@ -3,12 +3,12 @@
+ AC_INIT([cairo],
+ 	[cairo_version_major.cairo_version_minor.cairo_version_micro],
+ 	[http://bugs.freedesktop.org/enter_bug.cgi?product=cairo])
++AC_CONFIG_AUX_DIR(build)
++AC_CONFIG_MACRO_DIR(build)
+ AC_GNU_SOURCE
+ AC_USE_SYSTEM_EXTENSIONS
+ AC_CONFIG_SRCDIR(src/cairo.h)
+ AC_CONFIG_HEADERS(config.h)
+-AC_CONFIG_AUX_DIR(build)
+-AC_CONFIG_MACRO_DIR(build)
+ AM_INIT_AUTOMAKE([1.9.6 gnu -Wall no-define])
+ m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
+ AC_LIBTOOL_WIN32_DLL dnl Must be called before AC_PROG_LIBTOOL