Add new legacy release, bug #453538. Add prerelease version, bug #457918. Allow building with hardened-sources, bug #454870. Change SRC_URI for the XVBA SDK, bug #453192. Import of Emil Karlson's ebuild from the x11 overlay.

(Portage version: 2.1.11.50/cvs/Linux x86_64, unsigned Manifest commit)

9 files changed, 784 insertions, 306 deletions

diff --git a/x11-drivers/ati-drivers/ChangeLog b/x11-drivers/ati-drivers/ChangeLog
index 6c560f909cc0..4a03eb35ef5f 100644
--- a/x11-drivers/ati-drivers/ChangeLog
+++ b/x11-drivers/ati-drivers/ChangeLog
@@ -1,6 +1,18 @@
 # ChangeLog for x11-drivers/ati-drivers
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-drivers/ati-drivers/ChangeLog,v 1.316 2013/01/19 02:17:08 zerochaos Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-drivers/ati-drivers/ChangeLog,v 1.317 2013/02/18 21:08:54 chithanh Exp $
+
+*ati-drivers-13.1_pre897 (18 Feb 2013)
+*ati-drivers-13.2_beta3 (18 Feb 2013)
+
+  18 Feb 2013; Chí-Thanh Christopher Nguyễn <chithanh@gentoo.org>
+  +ati-drivers-13.1_pre897.ebuild, +ati-drivers-13.2_beta3.ebuild,
+  +files/const-notifier-block.patch, -ati-drivers-12.4.ebuild,
+  -files/amd-drivers-3.2.7.1.patch, -files/ati-drivers-12.2-redefine-WARN.patch,
+  ati-drivers-12.6_beta_pre897.ebuild, ati-drivers-13.1.ebuild, metadata.xml:
+  Add new legacy release, bug #453538. Add prerelease version, bug #457918.
+  Allow building with hardened-sources, bug #454870. Change SRC_URI for the XVBA
+  SDK, bug #453192. Import of Emil Karlson's ebuild from the x11 overlay.
 
 *ati-drivers-12.8 (19 Jan 2013)
 
diff --git a/x11-drivers/ati-drivers/ati-drivers-12.6_beta_pre897.ebuild b/x11-drivers/ati-drivers/ati-drivers-12.6_beta_pre897.ebuild
index 8d6d181de893..fbcd6aec94d5 100644
--- a/x11-drivers/ati-drivers/ati-drivers-12.6_beta_pre897.ebuild
+++ b/x11-drivers/ati-drivers/ati-drivers-12.6_beta_pre897.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-drivers/ati-drivers/ati-drivers-12.6_beta_pre897.ebuild,v 1.11 2012/12/30 17:05:35 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-drivers/ati-drivers/ati-drivers-12.6_beta_pre897.ebuild,v 1.12 2013/02/18 21:08:54 chithanh Exp $
 
 EAPI=4
 
diff --git a/x11-drivers/ati-drivers/ati-drivers-13.1.ebuild b/x11-drivers/ati-drivers/ati-drivers-13.1.ebuild
index 0a4c4de7fecb..727f004cf9b2 100644
--- a/x11-drivers/ati-drivers/ati-drivers-13.1.ebuild
+++ b/x11-drivers/ati-drivers/ati-drivers-13.1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-drivers/ati-drivers/ati-drivers-13.1.ebuild,v 1.1 2013/01/18 23:13:47 chithanh Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-drivers/ati-drivers/ati-drivers-13.1.ebuild,v 1.2 2013/02/18 21:08:54 chithanh Exp $
 
 EAPI=5
 
@@ -10,17 +10,21 @@ DESCRIPTION="Ati precompiled drivers for Radeon Evergreen (HD5000 Series) and ne
 HOMEPAGE="http://www.amd.com"
 MY_V=( $(get_version_components) )
 #RUN="${WORKDIR}/amd-driver-installer-9.00-x86.x86_64.run"
-DRIVERS_URI="http://www2.ati.com/drivers/linux/amd-driver-installer-catalyst-${PV}-linux-x86.x86_64.zip"
-XVBA_SDK_URI="http://developer.amd.com.php53-23.ord1-1.websitetestlink.com/wordpress/media/2012/10/xvba-sdk-0.74-404001.tar.gz"
+SLOT="1"
+if [[ legacy != ${SLOT} ]]; then
+	DRIVERS_URI="http://www2.ati.com/drivers/linux/amd-driver-installer-catalyst-${PV}-linux-x86.x86_64.zip"
+else
+	DRIVERS_URI="http://www2.ati.com/drivers/legacy/amd-driver-installer-catalyst-$(get_version_component_range 1-2)-legacy-linux-x86.x86_64.zip"
+fi
+XVBA_SDK_URI="http://developer.amd.com/wordpress/media/2012/10/xvba-sdk-0.74-404001.tar.gz"
 SRC_URI="${DRIVERS_URI} ${XVBA_SDK_URI}"
 FOLDER_PREFIX="common/"
-IUSE="debug +modules multilib qt4 static-libs disable-watermark"
+IUSE="debug +modules multilib qt4 static-libs disable-watermark pax_kernel"
 
 LICENSE="AMD GPL-2 QPL-1.0"
 KEYWORDS="-* ~amd64 ~x86"
-SLOT="1"
 
-RESTRICT="bindist"
+RESTRICT="bindist test"
 
 RDEPEND="
 	<=x11-base/xorg-server-1.13.49[-minimal]
@@ -48,6 +52,13 @@ RDEPEND="
 			x11-libs/qt-gui:4[accessibility]
 	)
 "
+if [[ legacy != ${SLOT} ]]; then
+	RDEPEND="${RDEPEND}
+		!x11-drivers/ati-drivers:legacy"
+else
+	RDEPEND="${RDEPEND}
+		!x11-drivers/ati-drivers:1"
+fi
 
 DEPEND="${RDEPEND}
 	x11-proto/inputproto
@@ -133,96 +144,25 @@ QA_DT_HASH="
 	usr/lib\(32\|64\)\?/OpenCL/vendors/amd/libOpenCL.so.1
 "
 
-_check_kernel_config() {
-	local failed=0
-	local error=""
-	if ! kernel_is ge 2 6; then
-		eerror "You need a 2.6 linux kernel to compile against!"
-		die "No 2.6 Kernel found"
-	fi
-
-	if ! linux_chkconfig_present MTRR; then
-		ewarn "You don't have MTRR support enabled in the kernel."
-		ewarn "Direct rendering will not work."
-	fi
-
-	if linux_chkconfig_builtin DRM; then
-		ewarn "You have DRM support built in to the kernel"
-		ewarn "Direct rendering will not work."
-	fi
+CONFIG_CHECK="~MTRR ~!DRM ACPI PCI_MSI !LOCKDEP"
+use amd64 && CONFIG_CHECK="${CONFIG_CHECK} COMPAT"
+ERROR_MTRR="CONFIG_MTRR required for direct rendering."
+ERROR_DRM="CONFIG_DRM must be disabled or compiled as a module for direct
+	rendering."
+ERROR_LOCKDEP="CONFIG_LOCKDEP (lock tracking) exports the symbol lock_acquire
+	as GPL-only. This prevents ${P} from compiling with an error like this:
+	FATAL: modpost: GPL-incompatible module fglrx.ko uses GPL-only symbol 'lock_acquire'"
 
+_check_kernel_config() {
 	if ! linux_chkconfig_present AGP && \
 		! linux_chkconfig_present PCIEPORTBUS; then
 		ewarn "You don't have AGP and/or PCIe support enabled in the kernel"
 		ewarn "Direct rendering will not work."
 	fi
 
-	if ! linux_chkconfig_present ACPI; then
-		eerror "${P} requires the ACPI support in the kernel"
-		eerror "Please enable it:"
-		eerror "    CONFIG_ACPI=y"
-		eerror "in /usr/src/linux/.config or"
-		eerror "    Power management and ACPI options --->"
-		eerror "        [*] Power Management support"
-		eerror "in the 'menuconfig'"
-		error+=" CONFIG_ACPI disabled;"
-		failed=1
-	fi
-
-	if ! linux_chkconfig_present PCI_MSI; then
-		eerror "${P} requires MSI in the kernel."
-		eerror "Please enable it:"
-		eerror "    CONFIG_PCI_MSI=y"
-		eerror "in /usr/src/linux/.config or"
-		eerror "    Bus options (PCI etc.)  --->"
-		eerror "        [*] Message Signaled Interrupts (MSI and MSI-X)"
-		eerror "in the kernel config."
-		error+=" CONFIG_PCI_MSI disabled;"
-		failed=1
-	fi
-
-	if linux_chkconfig_present LOCKDEP; then
-		eerror "You've enabled LOCKDEP -- lock tracking -- in the kernel."
-		eerror "Unfortunately, this option exports the symbol lock_acquire as GPL-only."
-		eerror "This prevents ${P} from compiling with an error like this:"
-		eerror "FATAL: modpost: GPL-incompatible module fglrx.ko uses GPL-only symbol 'lock_acquire'"
-		eerror "Please make sure the following options have been unset:"
-		eerror "    Kernel hacking  --->"
-		eerror "        [ ] Lock debugging: detect incorrect freeing of live locks"
-		eerror "        [ ] Lock debugging: prove locking correctness"
-		eerror "        [ ] Lock usage statistics"
-		eerror "in 'menuconfig'"
-		error+=" LOCKDEP enabled;"
-		failed=1
-	fi
-
-	use amd64 && if ! linux_chkconfig_present COMPAT; then
-		eerror "${P} requires COMPAT."
-		eerror "Please enable the 32 bit emulation:"
-		eerror "Executable file formats / Emulations  --->"
-		eerror "    [*] IA32 Emulation"
-		eerror "in the kernel config."
-		eerror "if this doesn't enable CONFIG_COMPAT add"
-		eerror "    CONFIG_COMPAT=y"
-		eerror "in /usr/src/linux/.config"
-		error+=" COMPAT disabled;"
-		failed=1
-	fi
-
 	kernel_is ge 2 6 37 && kernel_is le 2 6 38 && if ! linux_chkconfig_present BKL ; then
-		eerror "${P} requires BKL."
-		eerror "Please enable the Big Kernel Lock:"
-		eerror "Kernel hacking  --->"
-		eerror "    [*] Big Kernel Lock"
-		eerror "in the kernel config."
-		eerror "or add"
-		eerror "    CONFIG_BKL=y"
-		eerror "in /usr/src/linux/.config"
-		error+=" BKL disabled;"
-		failed=1
+		die "CONFIG_BKL must be enabled for kernels 2.6.37-2.6.38."
 	fi
-
-	[[ ${failed} -ne 0 ]] && die "${error}"
 }
 
 pkg_pretend() {
@@ -264,20 +204,20 @@ pkg_setup() {
 	fi
 
 	elog
-	elog "Please note that this driver supports only graphic cards based on"
+	elog "Please note that this driver only supports graphic cards based on"
 	elog "Evergreen chipset and newer."
-	elog "This represent the AMD Radeon HD 5400+ series at this moment."
+	elog "This includes the AMD Radeon HD 5400+ series at this moment."
 	elog
 	elog "If your card is older then use ${CATEGORY}/xf86-video-ati"
-	elog "For migration informations please reffer to:"
+	elog "For migration informations please refer to:"
 	elog "http://www.gentoo.org/proj/en/desktop/x/x11/ati-migration-guide.xml"
 	einfo
 }
 
 src_unpack() {
 	local DRIVERS_DISTFILE XVBA_SDK_DISTFILE
-	DRIVERS_DISTFILE=${DRIVERS_URI/*\//}
-	XVBA_SDK_DISTFILE=${XVBA_SDK_URI/*\//}
+	DRIVERS_DISTFILE=${DRIVERS_URI##*/}
+	XVBA_SDK_DISTFILE=${XVBA_SDK_URI##*/}
 
 	if [[ ${DRIVERS_DISTFILE} =~ .*\.tar\.gz ]]; then
 		unpack ${DRIVERS_DISTFILE}
@@ -298,10 +238,7 @@ src_unpack() {
 }
 
 src_prepare() {
-	# All kernel options for prepare are ment to be in here
 	if use modules; then
-		# version patches
-		# epatch "${FILESDIR}"/kernel/${PV}-*.patch
 		if use debug; then
 			sed -i '/^#define DRM_DEBUG_CODE/s/0/1/' \
 				"${MODULE_DIR}/firegl_public.c" \
@@ -323,7 +260,7 @@ src_prepare() {
 		-e "s:/var/lib/xdm/authdir/authfiles/:/var/run/xauth/:" \
 		-e "s:/var/lib/gdm/:/var/gdm/:" \
 		"${S}/${FOLDER_PREFIX}etc/ati/authatieventsd.sh" \
-		|| die "sed failed."
+		|| die "ACPI fixups failed."
 
 	# Since "who" is in coreutils, we're using that one instead of "finger".
 	sed -i -e 's:finger:who:' \
@@ -349,6 +286,9 @@ src_prepare() {
 	# see https://bugs.gentoo.org/show_bug.cgi?id=448216
 	epatch "${FILESDIR}/ati-drivers-kernel-3.8-acpihandle.patch"
 
+	# Compile fix, https://bugs.gentoo.org/show_bug.cgi?id=454870
+	use pax_kernel && epatch "${FILESDIR}/const-notifier-block.patch"
+
 	cd "${MODULE_DIR}"
 
 	# bugged fglrx build system, this file should be copied by hand
@@ -366,7 +306,7 @@ src_prepare() {
 		|| die "MODVERSIONS sed failed"
 	cd "${S}"
 
-	mkdir extra || die "mkdir failed"
+	mkdir extra || die "mkdir extra failed"
 	cd extra
 	unpack ./../${FOLDER_PREFIX}usr/src/ati/fglrx_sample_source.tgz
 
@@ -398,8 +338,6 @@ src_compile() {
 	eend $?
 }
 
-src_test() { :; } # no tests present
-
 src_install() {
 	use modules && linux-mod_src_install
 
diff --git a/x11-drivers/ati-drivers/ati-drivers-13.1_pre897.ebuild b/x11-drivers/ati-drivers/ati-drivers-13.1_pre897.ebuild
new file mode 100644
index 000000000000..170b3bd9075b
--- /dev/null
+++ b/x11-drivers/ati-drivers/ati-drivers-13.1_pre897.ebuild
@@ -0,0 +1,596 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-drivers/ati-drivers/ati-drivers-13.1_pre897.ebuild,v 1.1 2013/02/18 21:08:54 chithanh Exp $
+
+EAPI=5
+
+inherit eutils multilib linux-info linux-mod toolchain-funcs versionator
+
+DESCRIPTION="Ati precompiled drivers for Radeon Evergreen (HD5000 Series) and newer chipsets"
+HOMEPAGE="http://www.amd.com"
+MY_V=( $(get_version_components) )
+#RUN="${WORKDIR}/amd-driver-installer-9.00-x86.x86_64.run"
+SLOT="legacy"
+if [[ legacy != ${SLOT} ]]; then
+	DRIVERS_URI="http://www2.ati.com/drivers/linux/amd-driver-installer-catalyst-${PV}-linux-x86.x86_64.zip"
+else
+	DRIVERS_URI="http://www2.ati.com/drivers/legacy/amd-driver-installer-catalyst-$(get_version_component_range 1-2)-legacy-linux-x86.x86_64.zip"
+fi
+XVBA_SDK_URI="http://developer.amd.com/wordpress/media/2012/10/xvba-sdk-0.74-404001.tar.gz"
+SRC_URI="${DRIVERS_URI} ${XVBA_SDK_URI}"
+FOLDER_PREFIX="common/"
+IUSE="debug +modules multilib qt4 static-libs disable-watermark pax_kernel"
+
+LICENSE="AMD GPL-2 QPL-1.0"
+KEYWORDS="-* ~amd64 ~x86"
+
+RESTRICT="bindist test"
+
+RDEPEND="
+	<=x11-base/xorg-server-1.12.49[-minimal]
+	>=app-admin/eselect-opengl-1.0.7
+	app-admin/eselect-opencl
+	sys-power/acpid
+	x11-apps/xauth
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXinerama
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	virtual/glu
+	multilib? (
+			app-emulation/emul-linux-x86-opengl
+			app-emulation/emul-linux-x86-xlibs
+	)
+	qt4? (
+			x11-libs/libICE
+			x11-libs/libSM
+			x11-libs/libXcursor
+			x11-libs/libXfixes
+			x11-libs/libXxf86vm
+			x11-libs/qt-core:4
+			x11-libs/qt-gui:4[accessibility]
+	)
+"
+if [[ legacy != ${SLOT} ]]; then
+	RDEPEND="${RDEPEND}
+		!x11-drivers/ati-drivers:legacy"
+else
+	RDEPEND="${RDEPEND}
+		!x11-drivers/ati-drivers:1"
+fi
+
+DEPEND="${RDEPEND}
+	x11-proto/inputproto
+	x11-proto/xf86miscproto
+	x11-proto/xf86vidmodeproto
+	x11-proto/xineramaproto
+	x11-libs/libXtst
+	sys-apps/findutils
+	app-misc/pax-utils
+	app-arch/unzip
+"
+
+EMULTILIB_PKG="true"
+
+S="${WORKDIR}"
+
+# QA Silencing
+QA_TEXTRELS="
+	usr/lib*/opengl/ati/lib/libGL.so.1.2
+	usr/lib*/libatiadlxx.so
+	usr/lib*/xorg/modules/glesx.so
+	usr/lib*/libaticaldd.so
+	usr/lib*/dri/fglrx_dri.so
+"
+
+QA_EXECSTACK="
+	opt/bin/atiode
+	opt/bin/amdcccle
+	usr/lib*/opengl/ati/lib/libGL.so.1.2
+	usr/lib*/dri/fglrx_dri.so
+"
+
+QA_WX_LOAD="
+	usr/lib*/opengl/ati/lib/libGL.so.1.2
+	usr/lib*/dri/fglrx_dri.so
+"
+
+QA_PRESTRIPPED="
+	usr/lib\(32\|64\)\?/libXvBAW.so.1.0
+	usr/lib\(32\|64\)\?/opengl/ati/lib/libGL.so.1.2
+	usr/lib\(32\|64\)\?/opengl/ati/extensions/libglx.so
+	usr/lib\(32\|64\)\?/xorg/modules/glesx.so
+	usr/lib\(32\|64\)\?/libAMDXvBA.so.1.0
+	usr/lib\(32\|64\)\?/libaticaldd.so
+	usr/lib\(32\|64\)\?/dri/fglrx_dri.so
+"
+
+QA_SONAME="
+	usr/lib\(32\|64\)\?/libatiadlxx.so
+	usr/lib\(32\|64\)\?/libaticalcl.so
+	usr/lib\(32\|64\)\?/libaticaldd.so
+	usr/lib\(32\|64\)\?/libaticalrt.so
+	usr/lib\(32\|64\)\?/libamdocl\(32\|64\)\?.so
+"
+
+QA_DT_HASH="
+	opt/bin/amdcccle
+	opt/bin/aticonfig
+	opt/bin/atiodcli
+	opt/bin/atiode
+	opt/bin/clinfo
+	opt/bin/fglrxinfo
+	opt/sbin/atieventsd
+	opt/sbin/amdnotifyui
+	usr/lib\(32\|64\)\?/libaticalcl.so
+	usr/lib\(32\|64\)\?/libaticalrt.so
+	usr/lib\(32\|64\)\?/libatiuki.so.1.0
+	usr/lib\(32\|64\)\?/libatiadlxx.so
+	usr/lib\(32\|64\)\?/libfglrx_dm.so.1.0
+	usr/lib\(32\|64\)\?/libXvBAW.so.1.0
+	usr/lib\(32\|64\)\?/libAMDXvBA.so.1.0
+	usr/lib\(32\|64\)\?/xorg/modules/amdxmm.so
+	usr/lib\(32\|64\)\?/xorg/modules/glesx.so
+	usr/lib\(32\|64\)\?/xorg/modules/linux/libfglrxdrm.so
+	usr/lib\(32\|64\)\?/xorg/modules/drivers/fglrx_drv.so
+	usr/lib\(32\|64\)\?/libaticaldd.so
+	usr/lib\(32\|64\)\?/dri/fglrx_dri.so
+	usr/lib\(32\|64\)\?/opengl/ati/extensions/libglx.so
+	usr/lib\(32\|64\)\?/opengl/ati/extensions/fglrx-libglx.so
+	usr/lib\(32\|64\)\?/opengl/ati/lib/fglrx-libGL.so.1.2
+	usr/lib\(32\|64\)\?/opengl/ati/lib/libGL.so.1.2
+	usr/lib\(32\|64\)\?/OpenCL/vendors/amd/libamdocl\(32\|64\)\?.so
+	usr/lib\(32\|64\)\?/OpenCL/vendors/amd/libOpenCL.so.1
+"
+
+CONFIG_CHECK="~MTRR ~!DRM ACPI PCI_MSI !LOCKDEP"
+use amd64 && CONFIG_CHECK="${CONFIG_CHECK} COMPAT"
+ERROR_MTRR="CONFIG_MTRR required for direct rendering."
+ERROR_DRM="CONFIG_DRM must be disabled or compiled as a module for direct
+	rendering."
+ERROR_LOCKDEP="CONFIG_LOCKDEP (lock tracking) exports the symbol lock_acquire
+	as GPL-only. This prevents ${P} from compiling with an error like this:
+	FATAL: modpost: GPL-incompatible module fglrx.ko uses GPL-only symbol 'lock_acquire'"
+
+_check_kernel_config() {
+	if ! linux_chkconfig_present AGP && \
+		! linux_chkconfig_present PCIEPORTBUS; then
+		ewarn "You don't have AGP and/or PCIe support enabled in the kernel"
+		ewarn "Direct rendering will not work."
+	fi
+
+	kernel_is ge 2 6 37 && kernel_is le 2 6 38 && if ! linux_chkconfig_present BKL ; then
+		die "CONFIG_BKL must be enabled for kernels 2.6.37-2.6.38."
+	fi
+}
+
+pkg_pretend() {
+	# workaround until bug 365543 is solved
+	if use modules; then
+		linux-info_pkg_setup
+		require_configured_kernel
+		_check_kernel_config
+	fi
+}
+
+pkg_setup() {
+	if use modules; then
+		MODULE_NAMES="fglrx(video:${S}/${FOLDER_PREFIX}/lib/modules/fglrx/build_mod/2.6.x)"
+		BUILD_TARGETS="kmod_build"
+		linux-mod_pkg_setup
+		BUILD_PARAMS="GCC_VER_MAJ=$(gcc-major-version) KVER=${KV_FULL} KDIR=${KV_DIR}"
+		BUILD_PARAMS="${BUILD_PARAMS} CFLAGS_MODULE+=\"-DMODULE -DATI -DFGL\""
+		if grep -q arch_compat_alloc_user_space ${KV_DIR}/arch/x86/include/asm/compat.h ; then
+			BUILD_PARAMS="${BUILD_PARAMS} CFLAGS_MODULE+=-DCOMPAT_ALLOC_USER_SPACE=arch_compat_alloc_user_space"
+		else
+			BUILD_PARAMS="${BUILD_PARAMS} CFLAGS_MODULE+=-DCOMPAT_ALLOC_USER_SPACE=compat_alloc_user_space"
+		fi
+	fi
+	# Define module dir.
+	MODULE_DIR="${S}/${FOLDER_PREFIX}/lib/modules/fglrx/build_mod"
+	# get the xorg-server version and set BASE_DIR for that
+	BASE_DIR="${S}/xpic"
+
+	# amd64/x86
+	if use amd64 ; then
+		MY_BASE_DIR="${BASE_DIR}_64a"
+		PKG_LIBDIR=lib64
+		ARCH_DIR="${S}/arch/x86_64"
+	else
+		MY_BASE_DIR="${BASE_DIR}"
+		PKG_LIBDIR=lib
+		ARCH_DIR="${S}/arch/x86"
+	fi
+
+	elog
+	elog "Please note that this driver only supports graphic cards based on"
+	elog "Evergreen chipset and newer."
+	elog "This includes the AMD Radeon HD 5400+ series at this moment."
+	elog
+	elog "If your card is older then use ${CATEGORY}/xf86-video-ati"
+	elog "For migration informations please refer to:"
+	elog "http://www.gentoo.org/proj/en/desktop/x/x11/ati-migration-guide.xml"
+	einfo
+}
+
+src_unpack() {
+	local DRIVERS_DISTFILE XVBA_SDK_DISTFILE
+	DRIVERS_DISTFILE=${DRIVERS_URI##*/}
+	XVBA_SDK_DISTFILE=${XVBA_SDK_URI##*/}
+
+	if [[ ${DRIVERS_DISTFILE} =~ .*\.tar\.gz ]]; then
+		unpack ${DRIVERS_DISTFILE}
+	else
+		#please note, RUN may be insanely assigned at top near SRC_URI
+		if [[ ${DRIVERS_DISTFILE} =~ .*\.zip ]]; then
+			unpack ${DRIVERS_DISTFILE}
+			[[ -z "$RUN" ]] && RUN="${S}/${DRIVERS_DISTFILE/%.zip/.run}"
+		else
+			RUN="${DISTDIR}/${DRIVERS_DISTFILE}"
+		fi
+		sh ${RUN} --extract "${S}" 2>&1 > /dev/null || die
+	fi
+
+	mkdir xvba_sdk
+	cd xvba_sdk
+	unpack ${XVBA_SDK_DISTFILE}
+}
+
+src_prepare() {
+	if use modules; then
+		if use debug; then
+			sed -i '/^#define DRM_DEBUG_CODE/s/0/1/' \
+				"${MODULE_DIR}/firegl_public.c" \
+				|| die "Failed to enable debug output."
+		fi
+	fi
+
+	# These are the userspace utilities that we also have source for.
+	# We rebuild these later.
+	rm \
+		"${ARCH_DIR}"/usr/X11R6/bin/fgl_glxgears \
+		|| die "bin rm failed"
+
+	# in this version amdcccle isn't static, thus we depend on qt4
+	use qt4 || rm "${ARCH_DIR}"/usr/X11R6/bin/amdcccle
+
+	# ACPI fixups
+	sed -i \
+		-e "s:/var/lib/xdm/authdir/authfiles/:/var/run/xauth/:" \
+		-e "s:/var/lib/gdm/:/var/gdm/:" \
+		"${S}/${FOLDER_PREFIX}etc/ati/authatieventsd.sh" \
+		|| die "ACPI fixups failed."
+
+	# Since "who" is in coreutils, we're using that one instead of "finger".
+	sed -i -e 's:finger:who:' \
+		"${S}/${FOLDER_PREFIX}usr/share/doc/fglrx/examples/etc/acpi/ati-powermode.sh" \
+		|| die "Replacing 'finger' with 'who' failed."
+	# Adjust paths in the script from /usr/X11R6/bin/ to /opt/bin/ and
+	# add function to detect default state.
+	epatch "${FILESDIR}"/ati-powermode-opt-path-3.patch
+
+	# see http://ati.cchtml.com/show_bug.cgi?id=495
+	#epatch "${FILESDIR}"/ati-drivers-old_rsp.patch
+	# first hunk applied upstream second (x32 related) was not
+	epatch "${FILESDIR}"/ati-drivers-x32_something_something.patch
+
+	#fixes bug #420751
+	epatch "${FILESDIR}"/ati-drivers-do_mmap.patch
+
+	# compile fix for linux-3.7
+	# https://bugs.gentoo.org/show_bug.cgi?id=438516
+	epatch "${FILESDIR}/ati-drivers-vm-reserverd.patch"
+
+	# compile fix for AGP-less kernel, bug #435322
+	epatch "${FILESDIR}"/ati-drivers-12.9-KCL_AGP_FindCapsRegisters-stub.patch
+
+	# Use ACPI_DEVICE_HANDLE wrapper to make driver build on linux-3.8
+	# see https://bugs.gentoo.org/show_bug.cgi?id=448216
+	epatch "${FILESDIR}/ati-drivers-kernel-3.8-acpihandle.patch"
+
+	# Compile fix, https://bugs.gentoo.org/show_bug.cgi?id=454870
+	use pax_kernel && epatch "${FILESDIR}/const-notifier-block.patch"
+
+	cd "${MODULE_DIR}"
+
+	# bugged fglrx build system, this file should be copied by hand
+	cp ${ARCH_DIR}/lib/modules/fglrx/build_mod/libfglrx_ip.a 2.6.x
+
+	convert_to_m 2.6.x/Makefile || die "convert_to_m failed"
+
+	# When built with ati's make.sh it defines a bunch of macros if
+	# certain .config values are set, falling back to less reliable
+	# detection methods if linux/autoconf.h is not available. We
+	# simply use the linux/autoconf.h settings directly, bypassing the
+	# detection script.
+	sed -i -e 's/__SMP__/CONFIG_SMP/' *.c *h || die "SMP sed failed"
+	sed -i -e 's/ifdef MODVERSIONS/ifdef CONFIG_MODVERSIONS/' *.c *.h \
+		|| die "MODVERSIONS sed failed"
+	cd "${S}"
+
+	mkdir extra || die "mkdir extra failed"
+	cd extra
+	unpack ./../${FOLDER_PREFIX}usr/src/ati/fglrx_sample_source.tgz
+
+	# Get rid of watermark. Oldest known reference:
+	# http://phoronix.com/forums/showthread.php?19875-Unsupported-Hardware-watermark
+	if use disable-watermark; then
+		ebegin "Disabling watermark"
+		driver="${MY_BASE_DIR}"/usr/X11R6/${PKG_LIBDIR}/modules/drivers/fglrx_drv.so
+		for x in $(objdump -d ${driver}|awk '/call/&&/EnableLogo/{print "\\x"$2"\\x"$3"\\x"$4"\\x"$5"\\x"$6}'); do
+		sed -i "s/${x/x5b/\x5b}/\x90\x90\x90\x90\x90/g" ${driver} || break 1
+		done
+		eend $? || die "Disabling watermark failed"
+	fi
+}
+
+src_compile() {
+	use modules && linux-mod_src_compile
+
+	ebegin "Building fgl_glxgears"
+	cd "${S}"/extra/fgl_glxgears
+	# These extra libs/utils either have an Imakefile that does not
+	# work very well without tweaking or a Makefile ignoring CFLAGS
+	# and the like. We bypass those.
+	# The -DUSE_GLU is needed to compile using nvidia headers
+	# according to a comment in ati-drivers-extra-8.33.6.ebuild.
+	"$(tc-getCC)" -o fgl_glxgears ${CFLAGS} ${LDFLAGS} -DUSE_GLU \
+		-I"${S}"/${FOLDER_PREFIX}usr/include fgl_glxgears.c \
+		-lGL -lGLU -lX11 -lm || die "fgl_glxgears build failed"
+	eend $?
+}
+
+src_install() {
+	use modules && linux-mod_src_install
+
+	# We can do two things here, and neither of them is very nice.
+
+	# For direct rendering libGL has to be able to load one or more
+	# dri modules (files ending in _dri.so, like fglrx_dri.so).
+	# Gentoo's mesa looks for these files in the location specified by
+	# LIBGL_DRIVERS_PATH or LIBGL_DRIVERS_DIR, then in the hardcoded
+	# location /usr/$(get_libdir)/dri. Ati's libGL does the same
+	# thing, but the hardcoded location is /usr/X11R6/lib/modules/dri
+	# on x86 and amd64 32bit, /usr/X11R6/lib64/modules/dri on amd64
+	# 64bit. So we can either put the .so files in that (unusual,
+	# compared to "normal" mesa libGL) location or set
+	# LIBGL_DRIVERS_PATH. We currently do the latter. See also bug
+	# 101539.
+
+	# The problem with this approach is that LIBGL_DRIVERS_PATH
+	# *overrides* the default hardcoded location, it does not extend
+	# it. So if ati-drivers is merged but a non-ati libGL is selected
+	# and its hardcoded path does not match our LIBGL_DRIVERS_PATH
+	# (because it changed in a newer mesa or because it was compiled
+	# for a different set of multilib abis than we are) stuff breaks.
+
+	# We create one file per ABI to work with "native" multilib, see
+	# below.
+
+	echo "COLON_SEPARATED=LIBGL_DRIVERS_PATH" > "${T}/03ati-colon-sep"
+	doenvd "${T}/03ati-colon-sep" || die
+
+	# All libraries that we have a 32 bit and 64 bit version of on
+	# amd64 are installed in src_install-libs. Everything else
+	# (including libraries only available in native 64bit on amd64)
+	# goes in here.
+
+	# There used to be some code here that tried to detect running
+	# under a "native multilib" portage ((precursor of)
+	# http://dev.gentoo.org/~kanaka/auto-multilib/). I removed that, it
+	# should just work (only doing some duplicate work). --marienz
+	if has_multilib_profile; then
+		local OABI=${ABI}
+		for ABI in $(get_install_abis); do
+			src_install-libs
+		done
+		ABI=${OABI}
+		unset OABI
+	else
+		src_install-libs
+	fi
+
+	# This is sorted by the order the files occur in the source tree.
+
+	# X modules.
+	exeinto /usr/$(get_libdir)/xorg/modules/drivers
+	doexe "${MY_BASE_DIR}"/usr/X11R6/${PKG_LIBDIR}/modules/drivers/fglrx_drv.so
+	exeinto /usr/$(get_libdir)/xorg/modules/linux
+	doexe "${MY_BASE_DIR}"/usr/X11R6/${PKG_LIBDIR}/modules/linux/libfglrxdrm.so
+	exeinto /usr/$(get_libdir)/xorg/modules
+	doexe "${MY_BASE_DIR}"/usr/X11R6/${PKG_LIBDIR}/modules/{glesx.so,amdxmm.so}
+
+	# Arch-specific files.
+	# (s)bin.
+	into /opt
+	dosbin "${ARCH_DIR}"/usr/sbin/atieventsd
+	use qt4 && dosbin "${ARCH_DIR}"/usr/sbin/amdnotifyui
+	dobin "${ARCH_DIR}"/usr/bin/clinfo
+	# We cleaned out the compilable stuff in src_unpack
+	dobin "${ARCH_DIR}"/usr/X11R6/bin/*
+
+	# Common files.
+	# etc.
+	insinto /etc/ati
+	exeinto /etc/ati
+	# Everything except for the authatieventsd.sh script.
+	doins ${FOLDER_PREFIX}etc/ati/{logo*,control,atiogl.xml,signature,amdpcsdb.default}
+	doexe ${FOLDER_PREFIX}etc/ati/authatieventsd.sh
+
+	# include.
+	insinto /usr
+	doins -r ${FOLDER_PREFIX}usr/include
+	insinto /usr/include/X11/extensions
+
+	# Just the atigetsysteminfo.sh script.
+	into /usr
+	dosbin ${FOLDER_PREFIX}usr/sbin/*
+
+	# data files for the control panel.
+	if use qt4 ; then
+		insinto /usr/share
+		doins -r ${FOLDER_PREFIX}usr/share/ati
+		insinto /usr/share/pixmaps
+		doins ${FOLDER_PREFIX}usr/share/icons/ccc_large.xpm
+		make_desktop_entry amdcccle 'AMD Catalyst Control Center' \
+			ccc_large System
+	fi
+
+	# doc.
+	dohtml -r ${FOLDER_PREFIX}usr/share/doc/fglrx
+
+	doman ${FOLDER_PREFIX}usr/share/man/man8/atieventsd.8
+
+	pushd ${FOLDER_PREFIX}usr/share/doc/fglrx/examples/etc/acpi > /dev/null
+
+	exeinto /etc/acpi
+	doexe ati-powermode.sh
+	insinto /etc/acpi/events
+	doins events/*
+
+	popd > /dev/null
+
+	# Done with the "source" tree. Install tools we rebuilt:
+	dobin extra/fgl_glxgears/fgl_glxgears
+	newdoc extra/fgl_glxgears/README README.fgl_glxgears
+
+	# Gentoo-specific stuff:
+	newinitd "${FILESDIR}"/atieventsd.init atieventsd
+	echo 'ATIEVENTSDOPTS=""' > "${T}"/atieventsd.conf
+	newconfd "${T}"/atieventsd.conf atieventsd
+
+	# PowerXpress stuff
+	exeinto /usr/$(get_libdir)/fglrx
+	doexe "${FILESDIR}"/switchlibGL || die "doexe switchlibGL failed"
+	cp "${FILESDIR}"/switchlibGL "${T}"/switchlibglx
+	doexe "${T}"/switchlibglx || die "doexe switchlibglx failed"
+}
+
+src_install-libs() {
+	if [[ "${ABI}" == "amd64" ]]; then
+		local EX_BASE_DIR="${BASE_DIR}_64a"
+		local pkglibdir=lib64
+		local MY_ARCH_DIR="${S}/arch/x86_64"
+		local oclsuffix=64
+	else
+		local EX_BASE_DIR="${BASE_DIR}"
+		local pkglibdir=lib
+		local MY_ARCH_DIR="${S}/arch/x86"
+		local oclsuffix=32
+	fi
+	einfo "ati tree '${pkglibdir}' -> '$(get_libdir)' on system"
+
+	local ATI_ROOT=/usr/$(get_libdir)/opengl/ati
+	# To make sure we do not miss a spot when these change.
+	local libmajor=1 libminor=2
+	local libver=${libmajor}.${libminor}
+
+	# The GLX libraries
+	# (yes, this really is "lib" even on amd64/multilib --marienz)
+	exeinto ${ATI_ROOT}/lib
+	newexe "${MY_ARCH_DIR}"/usr/X11R6/${pkglibdir}/fglrx/fglrx-libGL.so.${libver} \
+		libGL.so.${libver}
+	dosym libGL.so.${libver} ${ATI_ROOT}/lib/libGL.so.${libmajor}
+	dosym libGL.so.${libver} ${ATI_ROOT}/lib/libGL.so
+
+	exeinto ${ATI_ROOT}/extensions
+	doexe "${EX_BASE_DIR}"/usr/X11R6/${pkglibdir}/modules/extensions/fglrx/fglrx-libglx.so
+	mv "${D}"/${ATI_ROOT}/extensions/{fglrx-,}libglx.so
+
+	# other libs
+	exeinto /usr/$(get_libdir)
+	# Everything except for the libGL.so installed some row above
+	doexe $(find "${MY_ARCH_DIR}"/usr/X11R6/${pkglibdir} \
+		-maxdepth 1 -type f -name '*.so*' -not -name '*libGL.so*')
+	insinto /usr/$(get_libdir)
+	doins $(find "${MY_ARCH_DIR}"/usr/X11R6/${pkglibdir} \
+		-maxdepth 1 -type f -not -name '*.so*')
+
+	# DRI modules, installed into the path used by recent versions of mesa.
+	exeinto /usr/$(get_libdir)/dri
+	doexe "${MY_ARCH_DIR}"/usr/X11R6/${pkglibdir}/modules/dri/fglrx_dri.so
+
+	# AMD Cal and OpenCL libraries
+	exeinto /usr/$(get_libdir)/OpenCL/vendors/amd
+	doexe "${MY_ARCH_DIR}"/usr/${pkglibdir}/libamdocl*.so*
+	doexe "${MY_ARCH_DIR}"/usr/${pkglibdir}/libOpenCL*.so*
+	dosym libOpenCL.so.${libmajor} /usr/$(get_libdir)/OpenCL/vendors/amd/libOpenCL.so
+	exeinto /usr/$(get_libdir)
+	doexe "${MY_ARCH_DIR}"/usr/${pkglibdir}/libati*.so*
+
+	# OpenCL vendor files
+	insinto /etc/OpenCL/vendors/
+	cat > "${T}"/amdocl${oclsuffix}.icd <<-EOF
+		/usr/$(get_libdir)/OpenCL/vendors/amd/libamdocl${oclsuffix}.so
+	EOF
+	doins "${T}"/amdocl${oclsuffix}.icd
+
+	local envname="${T}"/04ati-dri-path
+	if [[ -n ${ABI} ]]; then
+		envname="${envname}-${ABI}"
+	fi
+	echo "LIBGL_DRIVERS_PATH=/usr/$(get_libdir)/dri" > "${envname}"
+	doenvd "${envname}"
+
+	# Silence the QA notice by creating missing soname symlinks
+	for so in $(find "${D}"/usr/$(get_libdir) -maxdepth 1 -name *.so.[0-9].[0-9])
+	do
+		local soname=${so##*/}
+		local soname_one=${soname%.[0-9]}
+		local soname_zero=${soname_one%.[0-9]}
+		dosym ${soname} /usr/$(get_libdir)/${soname_one}
+		dosym ${soname_one} /usr/$(get_libdir)/${soname_zero}
+	done
+
+	# See https://bugs.gentoo.org/show_bug.cgi?id=443466
+	dodir /etc/revdep-rebuild/
+	echo "SEARCH_DIRS_MASK=\"/opt/bin/clinfo\"" > "${ED}/etc/revdep-rebuild/62-ati-drivers"
+
+	#remove static libs if not wanted
+	use static-libs || rm -rf "${D}"/usr/$(get_libdir)/libfglrx_dm.a
+
+	#install xvba sdk headers
+	doheader xvba_sdk/include/amdxvba.h
+}
+
+pkg_postinst() {
+	elog "To switch to AMD OpenGL, run \"eselect opengl set ati\""
+	elog "To change your xorg.conf you can use the bundled \"aticonfig\""
+	elog
+	elog "If you experience unexplained segmentation faults and kernel crashes"
+	elog "with this driver and multi-threaded applications such as wine,"
+	elog "set UseFastTLS in xorg.conf to either 0 or 1, but not 2."
+	elog
+	elog "Fully rebooting the system after an ${PN} update is recommended"
+	elog "Stopping Xorg, reloading fglrx kernel module and restart Xorg"
+	elog "might not work"
+	elog
+	elog "Some cards need acpid running to handle events"
+	elog "Please add it to boot runlevel with rc-update add acpid boot"
+	elog
+
+	use modules && linux-mod_pkg_postinst
+	"${ROOT}"/usr/bin/eselect opengl set --use-old ati
+	"${ROOT}"/usr/bin/eselect opencl set --use-old amd
+
+	if has_version ">=x11-drivers/xf86-video-intel-2.20.3"; then
+		ewarn "It is reported that xf86-video-intel-2.20.3 and later cause the X server"
+		ewarn "to crash on systems that use hybrid AMD/Intel graphics. If you experience"
+		ewarn "this crash, downgrade to xf86-video-intel-2.20.2 or earlier."
+		ewarn "For details, see https://bugs.gentoo.org/show_bug.cgi?id=430000"
+	fi
+}
+
+pkg_preinst() {
+	use modules && linux-mod_pkg_preinst
+}
+
+pkg_prerm() {
+	"${ROOT}"/usr/bin/eselect opengl set --use-old xorg-x11
+}
+
+pkg_postrm() {
+	use modules && linux-mod_pkg_postrm
+	"${ROOT}"/usr/bin/eselect opengl set --use-old xorg-x11
+}
diff --git a/x11-drivers/ati-drivers/ati-drivers-12.4.ebuild b/x11-drivers/ati-drivers/ati-drivers-13.2_beta3.ebuild
index 743303cc6084..41f5192cfb1e 100644
--- a/x11-drivers/ati-drivers/ati-drivers-12.4.ebuild
+++ b/x11-drivers/ati-drivers/ati-drivers-13.2_beta3.ebuild
@@ -1,30 +1,34 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-drivers/ati-drivers/ati-drivers-12.4.ebuild,v 1.9 2012/11/27 02:15:54 zerochaos Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-drivers/ati-drivers/ati-drivers-13.2_beta3.ebuild,v 1.1 2013/02/18 21:08:54 chithanh Exp $
 
-EAPI=4
+EAPI=5
 
 inherit eutils multilib linux-info linux-mod toolchain-funcs versionator
 
-DESCRIPTION="Ati precompiled drivers for radeon r600 (HD Series) and newer chipsets"
+DESCRIPTION="Ati precompiled drivers for Radeon Evergreen (HD5000 Series) and newer chipsets"
 HOMEPAGE="http://www.amd.com"
-# 8.ble will be used for beta releases.
-if [[ $(get_major_version) -gt 8 ]]; then
-	ATI_URL="http://www2.ati.com/drivers/linux/"
-	SRC_URI="${ATI_URL}/amd-driver-installer-${PV/./-}-x86.x86_64.run"
-	FOLDER_PREFIX="common/"
+MY_V=( $(get_version_components) )
+#RUN="${WORKDIR}/amd-driver-installer-9.00-x86.x86_64.run"
+SLOT="1"
+[[ "${MY_V[2]}" =~  beta.* ]] && BETADIR="beta/"
+if [[ legacy != ${SLOT} ]]; then
+	DRIVERS_URI="http://www2.ati.com/drivers/${BETADIR}amd-driver-installer-catalyst-${PV/_beta/-beta}-linux-x86.x86_64.zip"
 else
-	SRC_URI="https://launchpad.net/ubuntu/natty/+source/fglrx-installer/2:${PV}-0ubuntu1/+files/fglrx-installer_${PV}.orig.tar.gz"
-	FOLDER_PREFIX=""
+	DRIVERS_URI="http://www2.ati.com/drivers/legacy/amd-driver-installer-catalyst-$(get_version_component_range 1-2)-$(get_version_component_range 3)-legacy-linux-x86.x86_64.zip"
 fi
-IUSE="debug +modules multilib pax_kernel qt4 static-libs"
+XVBA_SDK_URI="http://developer.amd.com/wordpress/media/2012/10/xvba-sdk-0.74-404001.tar.gz"
+SRC_URI="${DRIVERS_URI} ${XVBA_SDK_URI}"
+FOLDER_PREFIX="common/"
+IUSE="debug +modules multilib qt4 static-libs disable-watermark pax_kernel"
 
-LICENSE="AMD GPL-2 QPL-1.0 as-is"
-KEYWORDS="amd64 x86"
-SLOT="1"
+LICENSE="AMD GPL-2 QPL-1.0"
+KEYWORDS="-* ~amd64 ~x86"
+
+RESTRICT="bindist test"
 
 RDEPEND="
-	<=x11-base/xorg-server-1.11.49[-minimal]
+	<=x11-base/xorg-server-1.13.49[-minimal]
 	>=app-admin/eselect-opengl-1.0.7
 	app-admin/eselect-opencl
 	sys-power/acpid
@@ -34,6 +38,7 @@ RDEPEND="
 	x11-libs/libXinerama
 	x11-libs/libXrandr
 	x11-libs/libXrender
+	virtual/glu
 	multilib? (
 			app-emulation/emul-linux-x86-opengl
 			app-emulation/emul-linux-x86-xlibs
@@ -45,9 +50,16 @@ RDEPEND="
 			x11-libs/libXfixes
 			x11-libs/libXxf86vm
 			x11-libs/qt-core:4
-			x11-libs/qt-gui:4
+			x11-libs/qt-gui:4[accessibility]
 	)
 "
+if [[ legacy != ${SLOT} ]]; then
+	RDEPEND="${RDEPEND}
+		!x11-drivers/ati-drivers:legacy"
+else
+	RDEPEND="${RDEPEND}
+		!x11-drivers/ati-drivers:1"
+fi
 
 DEPEND="${RDEPEND}
 	x11-proto/inputproto
@@ -57,6 +69,7 @@ DEPEND="${RDEPEND}
 	x11-libs/libXtst
 	sys-apps/findutils
 	app-misc/pax-utils
+	app-arch/unzip
 "
 
 EMULTILIB_PKG="true"
@@ -102,7 +115,7 @@ QA_SONAME="
 	usr/lib\(32\|64\)\?/libamdocl\(32\|64\)\?.so
 "
 
-QA_FLAGS_IGNORED="
+QA_DT_HASH="
 	opt/bin/amdcccle
 	opt/bin/aticonfig
 	opt/bin/atiodcli
@@ -132,111 +145,33 @@ QA_FLAGS_IGNORED="
 	usr/lib\(32\|64\)\?/OpenCL/vendors/amd/libOpenCL.so.1
 "
 
-_check_kernel_config() {
-	local failed=0
-	local error=""
-	if ! kernel_is ge 2 6; then
-		eerror "You need a 2.6 linux kernel to compile against!"
-		die "No 2.6 Kernel found"
-	fi
-
-	if kernel_is ge 3 5; then
-		eerror "${P} is not compatible with this kernel version!"
-		eerror "Use ati-drivers-12.6_beta_pre897 for legacy cards."
-		die "Kernel too new"
-	fi
-
-	if ! linux_chkconfig_present MTRR; then
-		ewarn "You don't have MTRR support enabled in the kernel."
-		ewarn "Direct rendering will not work."
-	fi
-
-	if linux_chkconfig_builtin DRM; then
-		ewarn "You have DRM support built in to the kernel"
-		ewarn "Direct rendering will not work."
-	fi
+CONFIG_CHECK="~MTRR ~!DRM ACPI PCI_MSI !LOCKDEP"
+use amd64 && CONFIG_CHECK="${CONFIG_CHECK} COMPAT"
+ERROR_MTRR="CONFIG_MTRR required for direct rendering."
+ERROR_DRM="CONFIG_DRM must be disabled or compiled as a module for direct
+	rendering."
+ERROR_LOCKDEP="CONFIG_LOCKDEP (lock tracking) exports the symbol lock_acquire
+	as GPL-only. This prevents ${P} from compiling with an error like this:
+	FATAL: modpost: GPL-incompatible module fglrx.ko uses GPL-only symbol 'lock_acquire'"
 
+_check_kernel_config() {
 	if ! linux_chkconfig_present AGP && \
 		! linux_chkconfig_present PCIEPORTBUS; then
 		ewarn "You don't have AGP and/or PCIe support enabled in the kernel"
 		ewarn "Direct rendering will not work."
 	fi
 
-	if ! linux_chkconfig_present ACPI; then
-		eerror "${P} requires the ACPI support in the kernel"
-		eerror "Please enable it:"
-		eerror "    CONFIG_ACPI=y"
-		eerror "in /usr/src/linux/.config or"
-		eerror "    Power management and ACPI options --->"
-		eerror "        [*] Power Management support"
-		eerror "in the 'menuconfig'"
-		error+=" CONFIG_ACPI disabled;"
-		failed=1
-	fi
-
-	if ! linux_chkconfig_present PCI_MSI; then
-		eerror "${P} requires MSI in the kernel."
-		eerror "Please enable it:"
-		eerror "    CONFIG_PCI_MSI=y"
-		eerror "in /usr/src/linux/.config or"
-		eerror "    Bus options (PCI etc.)  --->"
-		eerror "        [*] Message Signaled Interrupts (MSI and MSI-X)"
-		eerror "in the kernel config."
-		error+=" CONFIG_PCI_MSI disabled;"
-		failed=1
-	fi
-
-	if linux_chkconfig_present LOCKDEP; then
-		eerror "You've enabled LOCKDEP -- lock tracking -- in the kernel."
-		eerror "Unfortunately, this option exports the symbol lock_acquire as GPL-only."
-		eerror "This prevents ${P} from compiling with an error like this:"
-		eerror "FATAL: modpost: GPL-incompatible module fglrx.ko uses GPL-only symbol 'lock_acquire'"
-		eerror "Please make sure the following options have been unset:"
-		eerror "    Kernel hacking  --->"
-		eerror "        [ ] Lock debugging: detect incorrect freeing of live locks"
-		eerror "        [ ] Lock debugging: prove locking correctness"
-		eerror "        [ ] Lock usage statistics"
-		eerror "in 'menuconfig'"
-		error+=" LOCKDEP enabled;"
-		failed=1
-	fi
-
-	use amd64 && if ! linux_chkconfig_present COMPAT; then
-		eerror "${P} requires COMPAT."
-		eerror "Please enable the 32 bit emulation:"
-		eerror "Executable file formats / Emulations  --->"
-		eerror "    [*] IA32 Emulation"
-		eerror "in the kernel config."
-		eerror "if this doesn't enable CONFIG_COMPAT add"
-		eerror "    CONFIG_COMPAT=y"
-		eerror "in /usr/src/linux/.config"
-		error+=" COMPAT disabled;"
-		failed=1
-	fi
-
 	kernel_is ge 2 6 37 && kernel_is le 2 6 38 && if ! linux_chkconfig_present BKL ; then
-		eerror "${P} requires BKL."
-		eerror "Please enable the Big Kernel Lock:"
-		eerror "Kernel hacking  --->"
-		eerror "    [*] Big Kernel Lock"
-		eerror "in the kernel config."
-		eerror "or add"
-		eerror "    CONFIG_BKL=y"
-		eerror "in /usr/src/linux/.config"
-		error+=" BKL disabled;"
-		failed=1
+		die "CONFIG_BKL must be enabled for kernels 2.6.37-2.6.38."
 	fi
-
-	[[ ${failed} -ne 0 ]] && die "${error}"
 }
 
 pkg_pretend() {
 	# workaround until bug 365543 is solved
 	if use modules; then
 		linux-info_pkg_setup
-		if linux_config_exists; then
-			_check_kernel_config
-		fi
+		require_configured_kernel
+		_check_kernel_config
 	fi
 }
 
@@ -270,32 +205,41 @@ pkg_setup() {
 	fi
 
 	elog
-	elog "Please note that this driver supports only graphic cards based on"
-	elog "r600 chipset and newer."
-	elog "This represent the AMD Radeon HD series at this moment."
+	elog "Please note that this driver only supports graphic cards based on"
+	elog "Evergreen chipset and newer."
+	elog "This includes the AMD Radeon HD 5400+ series at this moment."
 	elog
 	elog "If your card is older then use ${CATEGORY}/xf86-video-ati"
-	elog "For migration informations please reffer to:"
+	elog "For migration informations please refer to:"
 	elog "http://www.gentoo.org/proj/en/desktop/x/x11/ati-migration-guide.xml"
 	einfo
 }
 
 src_unpack() {
-	if [[ $(get_major_version) -gt 8 ]]; then
-		# Switching to a standard way to extract the files since otherwise no signature file
-		# would be created
-		local src="${DISTDIR}/${A}"
-		sh "${src}" --extract "${S}"  2&>1 /dev/null
+	local DRIVERS_DISTFILE XVBA_SDK_DISTFILE
+	DRIVERS_DISTFILE=${DRIVERS_URI##*/}
+	XVBA_SDK_DISTFILE=${XVBA_SDK_URI##*/}
+
+	if [[ ${DRIVERS_DISTFILE} =~ .*\.tar\.gz ]]; then
+		unpack ${DRIVERS_DISTFILE}
 	else
-		unpack ${A}
+		#please note, RUN may be insanely assigned at top near SRC_URI
+		if [[ ${DRIVERS_DISTFILE} =~ .*\.zip ]]; then
+			unpack ${DRIVERS_DISTFILE}
+			[[ -z "$RUN" ]] && RUN="${S}/${DRIVERS_DISTFILE/%.zip/.run}"
+		else
+			RUN="${DISTDIR}/${DRIVERS_DISTFILE}"
+		fi
+		sh ${RUN} --extract "${S}" 2>&1 > /dev/null || die
 	fi
+
+	mkdir xvba_sdk
+	cd xvba_sdk
+	unpack ${XVBA_SDK_DISTFILE}
 }
 
 src_prepare() {
-	# All kernel options for prepare are ment to be in here
 	if use modules; then
-		# version patches
-		# epatch "${FILESDIR}"/kernel/${PV}-*.patch
 		if use debug; then
 			sed -i '/^#define DRM_DEBUG_CODE/s/0/1/' \
 				"${MODULE_DIR}/firegl_public.c" \
@@ -317,7 +261,7 @@ src_prepare() {
 		-e "s:/var/lib/xdm/authdir/authfiles/:/var/run/xauth/:" \
 		-e "s:/var/lib/gdm/:/var/gdm/:" \
 		"${S}/${FOLDER_PREFIX}etc/ati/authatieventsd.sh" \
-		|| die "sed failed."
+		|| die "ACPI fixups failed."
 
 	# Since "who" is in coreutils, we're using that one instead of "finger".
 	sed -i -e 's:finger:who:' \
@@ -325,20 +269,26 @@ src_prepare() {
 		|| die "Replacing 'finger' with 'who' failed."
 	# Adjust paths in the script from /usr/X11R6/bin/ to /opt/bin/ and
 	# add function to detect default state.
-	epatch "${FILESDIR}"/ati-powermode-opt-path-2.patch
+	epatch "${FILESDIR}"/ati-powermode-opt-path-3.patch
+
+	# see http://ati.cchtml.com/show_bug.cgi?id=495
+	#epatch "${FILESDIR}"/ati-drivers-old_rsp.patch
+	# first hunk applied upstream second (x32 related) was not
+	epatch "${FILESDIR}"/ati-drivers-x32_something_something.patch
 
-	# fix needed for at least hardened-sources, see bug #392753
-	use pax_kernel && epatch "${FILESDIR}"/ati-drivers-12.2-redefine-WARN.patch
+	# compile fix for linux-3.7
+	# https://bugs.gentoo.org/show_bug.cgi?id=438516
+	epatch "${FILESDIR}/ati-drivers-vm-reserverd.patch"
 
-	# fixed fgrlx compilation error on 32-bit x86 arch with kernel 3.3-rc4 due to commit:
-	# https://github.com/torvalds/linux/commit/f94edacf998516ac9d849f7bc6949a703977a7f3
-	# later modified (in 3.3-rc5) by commit:
-	# https://github.com/torvalds/linux/commit/7e16838d94b566a17b65231073d179bc04d590c8#diff-1
-	# and finally backported to kernel 3.2.8.
-	epatch "${FILESDIR}"/amd-drivers-3.2.7.1.patch
+	# compile fix for AGP-less kernel, bug #435322
+	epatch "${FILESDIR}"/ati-drivers-12.9-KCL_AGP_FindCapsRegisters-stub.patch
 
-	# see http://ati.cchtml.com/show_bug.cgi?id=495
-	epatch "${FILESDIR}"/ati-drivers-old_rsp.patch
+	# Use ACPI_DEVICE_HANDLE wrapper to make driver build on linux-3.8
+	# see https://bugs.gentoo.org/show_bug.cgi?id=448216
+	epatch "${FILESDIR}/ati-drivers-kernel-3.8-acpihandle.patch"
+
+	# Compile fix, https://bugs.gentoo.org/show_bug.cgi?id=454870
+	use pax_kernel && epatch "${FILESDIR}/const-notifier-block.patch"
 
 	cd "${MODULE_DIR}"
 
@@ -357,9 +307,20 @@ src_prepare() {
 		|| die "MODVERSIONS sed failed"
 	cd "${S}"
 
-	mkdir extra || die "mkdir failed"
+	mkdir extra || die "mkdir extra failed"
 	cd extra
 	unpack ./../${FOLDER_PREFIX}usr/src/ati/fglrx_sample_source.tgz
+
+	# Get rid of watermark. Oldest known reference:
+	# http://phoronix.com/forums/showthread.php?19875-Unsupported-Hardware-watermark
+	if use disable-watermark; then
+		ebegin "Disabling watermark"
+		driver="${MY_BASE_DIR}"/usr/X11R6/${PKG_LIBDIR}/modules/drivers/fglrx_drv.so
+		for x in $(objdump -d ${driver}|awk '/call/&&/EnableLogo/{print "\\x"$2"\\x"$3"\\x"$4"\\x"$5"\\x"$6}'); do
+		sed -i "s/${x/x5b/\x5b}/\x90\x90\x90\x90\x90/g" ${driver} || break 1
+		done
+		eend $? || die "Disabling watermark failed"
+	fi
 }
 
 src_compile() {
@@ -378,8 +339,6 @@ src_compile() {
 	eend $?
 }
 
-src_test() { :; } # no tests present
-
 src_install() {
 	use modules && linux-mod_src_install
 
@@ -576,9 +535,10 @@ src_install-libs() {
 	for so in $(find "${D}"/usr/$(get_libdir) -maxdepth 1 -name *.so.[0-9].[0-9])
 	do
 		local soname=${so##*/}
-		## let's keep also this alternative way ;)
-		#dosym ${soname} /usr/$(get_libdir)/${soname%.[0-9]}
-		dosym ${soname} /usr/$(get_libdir)/$(scanelf -qF "#f%S" ${so})
+		local soname_one=${soname%.[0-9]}
+		local soname_zero=${soname_one%.[0-9]}
+		dosym ${soname} /usr/$(get_libdir)/${soname_one}
+		dosym ${soname_one} /usr/$(get_libdir)/${soname_zero}
 	done
 
 	# See https://bugs.gentoo.org/show_bug.cgi?id=443466
@@ -587,6 +547,9 @@ src_install-libs() {
 
 	#remove static libs if not wanted
 	use static-libs || rm -rf "${D}"/usr/$(get_libdir)/libfglrx_dm.a
+
+	#install xvba sdk headers
+	doheader xvba_sdk/include/amdxvba.h
 }
 
 pkg_postinst() {
@@ -608,6 +571,13 @@ pkg_postinst() {
 	use modules && linux-mod_pkg_postinst
 	"${ROOT}"/usr/bin/eselect opengl set --use-old ati
 	"${ROOT}"/usr/bin/eselect opencl set --use-old amd
+
+	if has_version ">=x11-drivers/xf86-video-intel-2.20.3"; then
+		ewarn "It is reported that xf86-video-intel-2.20.3 and later cause the X server"
+		ewarn "to crash on systems that use hybrid AMD/Intel graphics. If you experience"
+		ewarn "this crash, downgrade to xf86-video-intel-2.20.2 or earlier."
+		ewarn "For details, see https://bugs.gentoo.org/show_bug.cgi?id=430000"
+	fi
 }
 
 pkg_preinst() {
diff --git a/x11-drivers/ati-drivers/files/amd-drivers-3.2.7.1.patch b/x11-drivers/ati-drivers/files/amd-drivers-3.2.7.1.patch
deleted file mode 100644
index 104c878884a3..000000000000
--- a/x11-drivers/ati-drivers/files/amd-drivers-3.2.7.1.patch
+++ /dev/null
@@ -1,19 +0,0 @@
---- a/common/lib/modules/fglrx/build_mod/firegl_public.c
-+++ b/common/lib/modules/fglrx/build_mod/firegl_public.c
-@@ -5797,10 +5797,16 @@ void ATI_API_CALL KCL_fpu_begin(void)
- #ifdef CONFIG_X86_64
-     kernel_fpu_begin();
- #else
-+#ifndef TS_USEDFPU
-+    preempt_disable();
-+    if (__thread_has_fpu(current))
-+        __save_init_fpu(current);
-+#else
-     struct thread_info *cur_task = current_thread_info();
-     preempt_disable();
-     if (cur_task->status & TS_USEDFPU)
-         __save_init_fpu(cur_task->task);
-+#endif
-     else
-         clts();
- #endif
diff --git a/x11-drivers/ati-drivers/files/ati-drivers-12.2-redefine-WARN.patch b/x11-drivers/ati-drivers/files/ati-drivers-12.2-redefine-WARN.patch
deleted file mode 100644
index f4fab432686e..000000000000
--- a/x11-drivers/ati-drivers/files/ati-drivers-12.2-redefine-WARN.patch
+++ /dev/null
@@ -1,42 +0,0 @@
---- common/lib/modules/fglrx/build_mod/kcl_debug.h.orig	2012-03-08 19:30:38.195025328 +0100
-+++ common/lib/modules/fglrx/build_mod/kcl_debug.h	2012-03-08 19:31:24.976024507 +0100
-@@ -85,8 +85,8 @@
- #ifdef ERROR
- #undef ERROR
- #endif
--#ifdef WARN
--#undef WARN
-+#ifdef AMD_WARN
-+#undef AMD_WARN
- #endif
- #ifdef INFO
- #undef INFO
-@@ -122,7 +122,7 @@
- {
-     SPECIAL = 0,
-     ERROR  ,
--    WARN  ,
-+    AMD_WARN  ,
-     INFO ,
-     INFOEX,
-     TRACE,
-@@ -160,7 +160,7 @@
- }log_map;
- 
- 
--#define DEFAULT_LOG_LEVEL ((U08)(___BIT(INFO) | ___BIT(INFOEX) |___BIT(ERROR) |___BIT(WARN) | ___BIT(TRACE)| ___BIT(SPECIAL)  ))
-+#define DEFAULT_LOG_LEVEL ((U08)(___BIT(INFO) | ___BIT(INFOEX) |___BIT(ERROR) |___BIT(AMD_WARN) | ___BIT(TRACE)| ___BIT(SPECIAL)  ))
- #define INFO_LOG_LEVEL ((U08)(___BIT(INFO) | ___BIT(INFOEX)))
- extern const log_map module_log_map[];
- extern const module_map module_type_map[];
---- common/lib/modules/fglrx/build_mod/kcl_debug.c.orig	2012-03-08 19:36:18.244019310 +0100
-+++ common/lib/modules/fglrx/build_mod/kcl_debug.c	2012-03-08 19:36:36.197018973 +0100
-@@ -69,7 +69,7 @@
- {
-     {SPECIAL        ,   'S'},
-     {ERROR          ,   'E'},
--    {WARN           ,   'W'},
-+    {AMD_WARN           ,   'W'},
-     {INFO           ,   'I'},
-     {INFOEX         ,   'X'},
-     {TRACE          ,   'T'},
diff --git a/x11-drivers/ati-drivers/files/const-notifier-block.patch b/x11-drivers/ati-drivers/files/const-notifier-block.patch
new file mode 100644
index 000000000000..ba1fdb2b7402
--- /dev/null
+++ b/x11-drivers/ati-drivers/files/const-notifier-block.patch
@@ -0,0 +1,25 @@
+diff -Nur common/lib/modules/fglrx/build_mod/kcl_acpi.c common-r1/lib/modules/fglrx/build_mod/kcl_acpi.c
+--- common/lib/modules/fglrx/build_mod/kcl_acpi.c	2013-01-29 17:03:51.000000000 +0200
++++ common-r1/lib/modules/fglrx/build_mod/kcl_acpi.c	2013-02-15 20:33:10.611838616 +0200
+@@ -15,6 +15,9 @@
+  ****************************************************************************/
+ 
+ #include <linux/version.h>
++#if LINUX_VERSION_CODE >= KERNEL_VERSION(3,7,0)
++#include <linux/notifier.h>
++#endif
+ #if LINUX_VERSION_CODE >= KERNEL_VERSION(2,6,33)
+ #include <generated/autoconf.h>
+ #else
+@@ -145,7 +148,11 @@
+     return NOTIFY_OK;
+ }
+ 
++#if LINUX_VERSION_CODE >= KERNEL_VERSION(3,7,0)
++static notifier_block_no_const firegl_acpi_lid_notifier = {
++#else
+ static struct notifier_block firegl_acpi_lid_notifier = {
++#endif
+         .notifier_call = firegl_acpi_lid_event,
+ };
+ #endif
diff --git a/x11-drivers/ati-drivers/metadata.xml b/x11-drivers/ati-drivers/metadata.xml
index 9e60972c81c2..57810eb2d66e 100644
--- a/x11-drivers/ati-drivers/metadata.xml
+++ b/x11-drivers/ati-drivers/metadata.xml
@@ -15,11 +15,9 @@
 		<flag name='modules'>Build the kernel modules</flag>
 	</use>
 	<use>
-		<flag name='pax_kernel'>
-			Enable if the user plans to run the package under a pax enabled hardened kernel
-		</flag>
+		<flag name='disable-watermark'>Do a potentially dangerous binary search and replace to disable watermark</flag>
 	</use>
 	<use>
-		<flag name='disable-watermark'>Do a potentially dangerous binary search and replace to disable watermark</flag>
+		<flag name='pax_kernel'>Enable pax kernel specific patches</flag>
 	</use>
 </pkgmetadata>