Revision bump: migrate to distutils-r1 eclass. Drop old revision

(Portage version: 2.2.0_alpha173/cvs/Linux x86_64, signed Manifest commit with key 0x1F357D42)

3 files changed, 45 insertions, 45 deletions

diff --git a/x11-apps/ccsm/ChangeLog b/x11-apps/ccsm/ChangeLog
index 280782053016..06d98f9d0055 100644
--- a/x11-apps/ccsm/ChangeLog
+++ b/x11-apps/ccsm/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for x11-apps/ccsm
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-apps/ccsm/ChangeLog,v 1.26 2012/08/30 17:41:06 pinkbyte Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-apps/ccsm/ChangeLog,v 1.27 2013/05/07 15:13:32 pinkbyte Exp $
+
+*ccsm-0.8.4-r3 (07 May 2013)
+
+  07 May 2013; Sergey Popov <pinkbyte@gentoo.org> -ccsm-0.8.4-r1.ebuild,
+  +ccsm-0.8.4-r3.ebuild:
+  Revision bump: migrate to distutils-r1 eclass. Drop old revision
 
   30 Aug 2012; Sergey Popov <pinkbyte@gentoo.org> metadata.xml:
   Remove myself and proxy maintainer from maintainers
diff --git a/x11-apps/ccsm/ccsm-0.8.4-r1.ebuild b/x11-apps/ccsm/ccsm-0.8.4-r1.ebuild
deleted file mode 100644
index ec6e45ce35f4..000000000000
--- a/x11-apps/ccsm/ccsm-0.8.4-r1.ebuild
+++ /dev/null
@@ -1,43 +0,0 @@
-# Copyright 1999-2012 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-apps/ccsm/ccsm-0.8.4-r1.ebuild,v 1.5 2012/08/29 10:14:37 naota Exp $
-
-EAPI="3"
-PYTHON_DEPEND="2"
-
-inherit distutils
-
-DESCRIPTION="Compizconfig Settings Manager"
-HOMEPAGE="http://www.compiz.org/"
-SRC_URI="http://releases.compiz.org/${PV}/${P}.tar.bz2"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
-IUSE=""
-
-DEPEND="
-	>=dev-python/compizconfig-python-${PV}
-	>=dev-python/pygtk-2.12:2
-	gnome-base/librsvg
-"
-RDEPEND="${DEPEND}
-	x11-themes/hicolor-icon-theme"
-DEPEND="${DEPEND}
-	dev-util/intltool"
-
-DOCS="AUTHORS"
-PYTHON_MODNAME="ccm"
-
-pkg_setup() {
-	python_set_active_version 2
-	python_pkg_setup
-}
-
-src_compile() {
-	distutils_src_compile --prefix=/usr
-}
-
-src_install() {
-	distutils_src_install --prefix=/usr
-}
diff --git a/x11-apps/ccsm/ccsm-0.8.4-r3.ebuild b/x11-apps/ccsm/ccsm-0.8.4-r3.ebuild
new file mode 100644
index 000000000000..cc4c793752c6
--- /dev/null
+++ b/x11-apps/ccsm/ccsm-0.8.4-r3.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-apps/ccsm/ccsm-0.8.4-r3.ebuild,v 1.1 2013/05/07 15:13:32 pinkbyte Exp $
+
+EAPI="5"
+
+PYTHON_COMPAT=( python2_{6,7} )
+DISTUTILS_IN_SOURCE_BUILD=1
+inherit distutils-r1
+
+DESCRIPTION="Compizconfig Settings Manager"
+HOMEPAGE="http://www.compiz.org/"
+SRC_URI="http://releases.compiz.org/${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+
+RDEPEND="
+	>=dev-python/compizconfig-python-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/pygtk-2.12:2[${PYTHON_USEDEP}]
+	gnome-base/librsvg
+"
+
+DOCS=( AUTHORS )
+
+python_prepare_all() {
+	# return error if wrong arguments passed to setup.py
+	sed -i -e 's/raise SystemExit/\0(1)/' setup.py || die 'sed on setup.py failed'
+	# fix desktop file
+	sed -i \
+		-e '/Categories/s/Compiz/X-\0/' \
+		-e '/Encoding/d' \
+		ccsm.desktop.in || die 'sed on ccsm.desktop.in failed'
+
+	distutils-r1_python_prepare_all
+}