Migrate to distutils-r1.

(Portage version: 2.2.0_alpha161/cvs/Linux x86_64, signed Manifest commit with key 42B9401D)

2 files changed, 48 insertions, 2 deletions

diff --git a/www-servers/tornado/ChangeLog b/www-servers/tornado/ChangeLog
index 2d2aa64bf478..eae9930e781c 100644
--- a/www-servers/tornado/ChangeLog
+++ b/www-servers/tornado/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for www-servers/tornado
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-servers/tornado/ChangeLog,v 1.30 2012/12/31 22:45:30 ago Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/www-servers/tornado/ChangeLog,v 1.31 2013/02/05 23:14:49 mgorny Exp $
+
+*tornado-2.4-r1 (05 Feb 2013)
+
+  05 Feb 2013; Michał Górny <mgorny@gentoo.org> +tornado-2.4-r1.ebuild:
+  Migrate to distutils-r1.
 
   31 Dec 2012; Agostino Sarubbo <ago@gentoo.org> tornado-2.4.ebuild:
   Stable for x86, wrt bug #449428
diff --git a/www-servers/tornado/tornado-2.4-r1.ebuild b/www-servers/tornado/tornado-2.4-r1.ebuild
new file mode 100644
index 000000000000..67431e6ed779
--- /dev/null
+++ b/www-servers/tornado/tornado-2.4-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-servers/tornado/tornado-2.4-r1.ebuild,v 1.1 2013/02/05 23:14:49 mgorny Exp $
+
+EAPI=5
+
+# 
+PYTHON_COMPAT=( python{2_5,2_6,2_7,3_2} pypy{1_9,2_0} )
+
+inherit distutils-r1
+
+DESCRIPTION="Scalable, non-blocking web server and tools"
+HOMEPAGE="http://www.tornadoweb.org/ http://pypi.python.org/pypi/tornado"
+SRC_URI="http://github.com/downloads/facebook/tornado/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
+IUSE="curl"
+
+RDEPEND="curl? ( dev-python/pycurl[$(python_gen_usedep python2*)] )
+	python_targets_python2_5? (
+		dev-python/simplejson[python_targets_python2_5] )"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+
+REQUIRED_USE="curl? ( $(python_gen_useflags python2*) )"
+
+src_test() {
+	# The test server tries to bind at an unused port but suffers
+	# a race condition in it. Seems to be fixed already.
+	# https://github.com/facebook/tornado/blob/master/tornado/test/process_test.py#L64
+	local DISTUTILS_NO_PARALLEL_BUILD=1
+
+	distutils-r1_src_test
+}
+
+python_test() {
+	cd "${TMPDIR}" || die
+	"${PYTHON}" -m tornado.test.runtests || die "Tests fail with ${EPYTHON}"
+}