Version bump. Many bug fixes and performance enhancements. http://releases.xfce.org/feeds/project/midori

(Portage version: 2.1.7.4/cvs/Linux x86_64)

2 files changed, 75 insertions, 1 deletions

diff --git a/www-client/midori/ChangeLog b/www-client/midori/ChangeLog
index 2b399ccb2874..770c0a07cd22 100644
--- a/www-client/midori/ChangeLog
+++ b/www-client/midori/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for www-client/midori
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v 1.21 2009/11/07 19:15:28 volkmar Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v 1.22 2009/11/16 15:37:53 darkside Exp $
+
+*midori-0.2.1 (16 Nov 2009)
+
+  16 Nov 2009; Jeremy Olexa <darkside@gentoo.org> +midori-0.2.1.ebuild:
+  Version bump. Many bug fixes and performance enhancements.
+  http://releases.xfce.org/feeds/project/midori
 
   07 Nov 2009; Mounir Lamouri <volkmar@gentoo.org> midori-0.1.10.ebuild,
   midori-0.2.0.ebuild:
diff --git a/www-client/midori/midori-0.2.1.ebuild b/www-client/midori/midori-0.2.1.ebuild
new file mode 100644
index 000000000000..e254fcde8533
--- /dev/null
+++ b/www-client/midori/midori-0.2.1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/midori/midori-0.2.1.ebuild,v 1.1 2009/11/16 15:37:53 darkside Exp $
+
+EAPI=2
+inherit xfconf multilib
+
+DESCRIPTION="A lightweight web browser based on WebKitGTK+"
+HOMEPAGE="http://www.twotoasts.de/index.php?/pages/midori_summary.html"
+SRC_URI="mirror://xfce/src/apps/${PN}/0.2/${P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
+IUSE="doc gnome html idn libnotify nls +sqlite +unique"
+
+RDEPEND="libnotify? ( x11-libs/libnotify )
+	>=net-libs/libsoup-2.25.2
+	>=net-libs/webkit-gtk-1.1.1
+	dev-libs/libxml2
+	>=x11-libs/gtk+-2.10:2
+	gnome? ( net-libs/libsoup[gnome] )
+	idn? ( net-dns/libidn )
+	sqlite? ( >=dev-db/sqlite-3.0 )
+	unique? ( dev-libs/libunique )"
+
+DEPEND="${RDEPEND}
+	dev-lang/python
+	dev-util/pkgconfig
+	doc? ( dev-util/gtk-doc )
+	html? ( dev-python/docutils )
+	nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	# moving docs to version-specific directory
+	sed -i -e "s:\${DOCDIR}/${PN}:\${DOCDIR}/${PF}/:g" wscript || die
+	sed -i -e "s:/${PN}/user/midori.html:/${PF}/user/midori.html:g" midori/midori-browser.c || die
+}
+
+src_configure() {
+	CCFLAGS="${CFLAGS}" LINKFLAGS="${LDFLAGS}" ./waf \
+		--prefix="/usr/" \
+		--libdir="/usr/$(get_libdir)" \
+		--disable-docs \
+		$(use_enable doc apidocs) \
+		$(use_enable html userdocs) \
+		$(use_enable idn libidn) \
+		$(use_enable nls nls) \
+		$(use_enable sqlite) \
+		$(use_enable unique) \
+		configure || die "configure failed"
+}
+
+src_compile() {
+	NUMJOBS=$(sed -e 's/.*\(\-j[ 0-9]\+\) .*/\1/; s/--jobs=\?/-j/' <<< ${MAKEOPTS})
+	./waf build ${NUMJOBS} || die "build failed"
+}
+
+src_install() {
+	DESTDIR=${D} ./waf install || die "install failed"
+	dodoc AUTHORS ChangeLog INSTALL TODO || die "dodoc failed"
+}
+
+pkg_postinst() {
+	xfconf_pkg_postinst
+	ewarn "Midori tends to crash due to bugs in WebKit."
+	ewarn "Report bugs at http://www.twotoasts.de/bugs"
+}