Revision bump <http://my.opera.com/desktopteam/blog/2007/09/21/one-more-snapshot>.

(Portage version: 2.1.3.9)

3 files changed, 204 insertions, 1 deletions

diff --git a/www-client/opera/ChangeLog b/www-client/opera/ChangeLog
index 898da0041c39..9ebab6192676 100644
--- a/www-client/opera/ChangeLog
+++ b/www-client/opera/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for www-client/opera
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/opera/ChangeLog,v 1.138 2007/09/17 00:44:56 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/opera/ChangeLog,v 1.139 2007/09/22 16:13:43 jer Exp $
+
+*opera-9.50_rc1589 (22 Sep 2007)
+
+  22 Sep 2007; Jeroen Roovers <jer@gentoo.org> +opera-9.50_rc1589.ebuild:
+  Revision bump
+  <http://my.opera.com/desktopteam/blog/2007/09/21/one-more-snapshot>.
 
   17 Sep 2007; Jeroen Roovers <jer@gentoo.org> +opera-9.50_alpha1581.ebuild:
   Readd the alpha build with the unchanged RDEPEND for old times´ sake.
diff --git a/www-client/opera/files/digest-opera-9.50_rc1589 b/www-client/opera/files/digest-opera-9.50_rc1589
new file mode 100644
index 000000000000..049170e81513
--- /dev/null
+++ b/www-client/opera/files/digest-opera-9.50_rc1589
@@ -0,0 +1,21 @@
+MD5 129c72946567640f5cee0a5c3f912a60 opera-9.50-20070920.1-static-qt.i386.freebsd-1589.tar.bz2 7478522
+RMD160 6b4aa3f8863878e1fa2ec53d39a91cfc23552d74 opera-9.50-20070920.1-static-qt.i386.freebsd-1589.tar.bz2 7478522
+SHA256 54104e7b71bd73994d6e7cf4a3e01eb5f22b64817d75e6ad3a1b8d09db357f0b opera-9.50-20070920.1-static-qt.i386.freebsd-1589.tar.bz2 7478522
+MD5 bf611c65fdf3342221e48ef690ef13d3 opera-9.50-20070920.1-static-qt.ppc-1589.tar.bz2 7199606
+RMD160 f7db281efbf6476b12a6160009331926f6ee729c opera-9.50-20070920.1-static-qt.ppc-1589.tar.bz2 7199606
+SHA256 d81b0d5813163c36862e83cd7590a1c27ce06f7d18d9da9350603731e1755cc8 opera-9.50-20070920.1-static-qt.ppc-1589.tar.bz2 7199606
+MD5 4fdd6bbb4e9bfd1cc675edc065e134de opera-9.50-20070920.2-shared-qt.x86_64-1589.tar.bz2 5991347
+RMD160 ca0d9b24adc820ded194007e994e91b254c7e2bd opera-9.50-20070920.2-shared-qt.x86_64-1589.tar.bz2 5991347
+SHA256 c9478f6b31c561294d8189c97f1eee5c7319b04fe42e272c24437f9396b9a8ae opera-9.50-20070920.2-shared-qt.x86_64-1589.tar.bz2 5991347
+MD5 ebea2e579e563a90b905cabf952caa69 opera-9.50-20070920.4-shared-qt.i386.freebsd-1589.tar.bz2 5542598
+RMD160 acfeafb5de93bff2b9fc36ed132e511e1739b3f2 opera-9.50-20070920.4-shared-qt.i386.freebsd-1589.tar.bz2 5542598
+SHA256 dc7f39a54f751d9bd3c05c93c1ae7d5296a0702e5362c7649b6f6b0e3b137d6e opera-9.50-20070920.4-shared-qt.i386.freebsd-1589.tar.bz2 5542598
+MD5 93a551da767ca638e2b67cd4cf71eabb opera-9.50-20070920.6-shared-qt.i386-1589.tar.bz2 5501138
+RMD160 f6fa00a28fc45c27c8a511d1076d0b1e09e1e634 opera-9.50-20070920.6-shared-qt.i386-1589.tar.bz2 5501138
+SHA256 d9d9d7e7f3b126c64fc57a21672e8fe61d6ffa9b30403e8e6bf13c967844ad38 opera-9.50-20070920.6-shared-qt.i386-1589.tar.bz2 5501138
+MD5 608f00087461bdad695e48a9be31adae opera-9.50-20070920.6-shared-qt.ppc-1589.tar.bz2 5543254
+RMD160 570689ae74d948dc49dea1f26addb9bd91d79c62 opera-9.50-20070920.6-shared-qt.ppc-1589.tar.bz2 5543254
+SHA256 b37d21c792c8af06851d12f5a48ca31a3dcca9821a459a076d30937014f022f4 opera-9.50-20070920.6-shared-qt.ppc-1589.tar.bz2 5543254
+MD5 872a05bc7e7cf602a91f4829b1aa5e85 opera-9.50-20070920.9-static-qt.i386-1589.tar.bz2 7729686
+RMD160 80b51b02bb2b4141e40814966447f4e2775cfc8b opera-9.50-20070920.9-static-qt.i386-1589.tar.bz2 7729686
+SHA256 0cd9cb4e7e5376d9f475ca6f063b56e9658ca91d8b427c927bbdc01c02918e7a opera-9.50-20070920.9-static-qt.i386-1589.tar.bz2 7729686
diff --git a/www-client/opera/opera-9.50_rc1589.ebuild b/www-client/opera/opera-9.50_rc1589.ebuild
new file mode 100644
index 000000000000..93bae7e82e53
--- /dev/null
+++ b/www-client/opera/opera-9.50_rc1589.ebuild
@@ -0,0 +1,176 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/opera/opera-9.50_rc1589.ebuild,v 1.1 2007/09/22 16:13:43 jer Exp $
+
+GCONF_DEBUG="no"
+
+inherit eutils gnome2
+
+DESCRIPTION="Opera web browser"
+HOMEPAGE="http://www.opera.com/"
+
+SLOT="0"
+LICENSE="OPERA-9.0"
+KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
+
+IUSE="qt-static spell gnome"
+RESTRICT="strip mirror"
+
+O_LNG=""
+O_SUFF="1589"
+O_VER="9.50-20070920"
+
+O_URI="http://snapshot.opera.com/unix/snapshot-${O_SUFF}/"
+SRC_URI="
+	x86? (
+		qt-static? ( ${O_URI}intel-linux/${PN}-${O_VER}.9-static-qt.i386${O_LNG}-${O_SUFF}.tar.bz2 )
+		!qt-static? ( ${O_URI}intel-linux/${PN}-${O_VER}.6-shared-qt.i386${O_LNG}-${O_SUFF}.tar.bz2 ) )
+	amd64? ( !qt-static? ( ${O_URI}x86_64-linux/${PN}-${O_VER}.2-shared-qt.x86_64${O_LNG}-${O_SUFF}.tar.bz2 ) )
+	ppc? (
+		qt-static? ( ${O_URI}ppc-linux/${PN}-${O_VER}.1-static-qt.ppc${O_LNG}-${O_SUFF}.tar.bz2 )
+		!qt-static? ( ${O_URI}ppc-linux/${PN}-${O_VER}.6-shared-qt.ppc${O_LNG}-${O_SUFF}.tar.bz2 ) )
+	x86-fbsd? (
+		qt-static? ( ${O_URI}/intel-freebsd/${PN}-${O_VER}.1-static-qt.i386.freebsd${O_LNG}-${O_SUFF}.tar.bz2 )
+		!qt-static? ( ${O_URI}/intel-freebsd/${PN}-${O_VER}.4-shared-qt.i386.freebsd${O_LNG}-${O_SUFF}.tar.bz2 ) )"
+
+DEPEND=">=sys-apps/sed-4"
+
+RDEPEND=">=media-libs/fontconfig-2.1.94-r1
+		media-libs/jpeg
+		media-libs/libexif
+		x11-libs/libXrandr
+		x11-libs/libXp
+		x11-libs/libXmu
+		x11-libs/libXi
+		x11-libs/libXft
+		x11-libs/libXext
+		x11-libs/libXcursor
+		x11-libs/libX11
+		x11-libs/libSM
+		x11-libs/libICE
+		=virtual/libstdc++-3*
+		!qt-static? ( =x11-libs/qt-3* )
+		spell? ( app-text/aspell )"
+
+S=${WORKDIR}/${A/.tar.bz2/}
+
+src_unpack() {
+	unpack ${A}
+	cd ${S}
+
+	epatch "${FILESDIR}/${PN}-9.00-install.patch"
+	epatch "${FILESDIR}/${PN}-9.50-pluginpath.patch"
+
+	sed -i -e "s:config_dir=\"/etc\":config_dir=\"${D}/etc/\":g" \
+		-e "s:/usr/share/applnk:${D}/usr/share/applnk:g" \
+		-e "s:/usr/share/pixmaps:${D}/usr/share/pixmaps:g" \
+		-e "s:/usr/share/icons:${D}/usr/share/icons:g" \
+		-e "s:/etc/X11:${D}/etc/X11:g" \
+		-e "s:/usr/share/gnome:${D}/usr/share/gnome:g" \
+		-e "s:/opt/gnome/share:${D}/opt/gnome/share:g" \
+		-e 's:#\(OPERA_FORCE_JAVA_ENABLED=\):\1:' \
+		-e 's:#\(export LD_PRELOAD OPERA_FORCE_JAVA_ENABLED\):\1:' \
+		-e 's:read str_answer:return 0:' \
+		-e "s:/opt/kde:${D}/usr/kde:" \
+		-e "s:\(str_localdirplugin=\).*$:\1/opt/opera/lib/opera/plugins:" \
+		install.sh || die "sed failed"
+}
+
+src_compile() {
+	# This workaround is sadly needed because gnome2.eclass doesn't check
+	# whether a configure script or Makefile exists.
+	true
+}
+
+src_install() {
+	local res
+	# Prepare installation directories for Opera's installer script.
+	dodir /etc
+
+	# Opera's native installer.
+	./install.sh --prefix="${D}"/opt/opera || die "install.sh failed"
+
+	einfo "It is safe to ignore warnings about failed checksums"
+	einfo "and about files that would be ignored ..."
+	einfo "Completing the installation where install.sh abandoned us ..."
+
+	# java workaround
+	sed -i -e 's:LD_PRELOAD="${OPERA_JAVA_DIR}/libawt.so":LD_PRELOAD="$LD_PRELOAD"\:"${OPERA_JAVA_DIR}/libawt.so":' ${D}/opt/opera/bin/opera
+
+	dosed /opt/opera/bin/opera
+	dosed /opt/opera/share/opera/java/opera.policy
+
+	# Install the icons
+	insinto /usr/share/pixmaps
+	doins usr/share/pixmaps/opera.xpm
+	for res in 16x16 22x22 32x32 48x48 ; do
+		insinto /usr/share/icons/hicolor/${res}/apps
+		doins usr/share/icons/hicolor/${res}/apps/opera.png
+	done
+
+	# Install the menu entry
+	insinto /usr/share/applications
+	doins ${FILESDIR}/opera.desktop
+
+	# Install a symlink /usr/bin/opera
+	dodir /usr/bin
+	dosym /opt/opera/bin/opera /usr/bin/opera
+
+	# fix plugin path
+	echo "Plugin Path=/opt/opera/lib/opera/plugins" >> ${D}/etc/opera6rc
+
+	# enable spellcheck
+	if use spell; then
+		if use qt-static; then
+			DIR=$O_VER.1
+		else
+			use sparc && DIR=$O_VER.2 || DIR=$O_VER.5
+		fi
+		echo "Spell Check Engine=/opt/opera/lib/opera/${DIR}/spellcheck.so" >> ${D}/opt/opera/share/opera/ini/spellcheck.ini
+	fi
+
+	dodir /etc/revdep-rebuild
+	echo 'SEARCH_DIRS_MASK="/opt/opera/lib/opera/plugins"' > ${D}/etc/revdep-rebuild/90opera
+
+	# Change libz.so.3 to libz.so.1 for gentoo/freebsd
+	if use x86-fbsd; then
+		scanelf -qR -N libz.so.3 -F "#N" "${D}"/opt/${PN}/ | \
+		while read i; do
+			if [[ $(strings "$i" | fgrep -c libz.so.3) -ne 1 ]];
+			then
+				export SANITY_CHECK_LIBZ_FAILED=1
+				break
+			fi
+			sed -i -e 's/libz\.so\.3/libz.so.1/g' "$i"
+		done
+		[[ "$SANITY_CHECK_LIBZ_FAILED" = "1" ]] && die "failed to change libz.so.3 to libz.so.1"
+	fi
+
+	# symlink to libflash-player.so:
+	dosym /opt/netscape/plugins/libflashplayer.so \
+		/opt/opera/lib/opera/plugins/libflashplayer.so
+
+	# Add the Opera man dir to MANPATH:
+	insinto /etc/env.d
+	echo 'MANPATH="/opt/opera/share/man"' >> ${D}/etc/env.d/90opera
+}
+
+pkg_postinst() {
+	use gnome && gnome2_pkg_postinst
+
+	elog "For localized language files take a look at:"
+	elog " http://www.opera.com/download/languagefiles/index.dml"
+	elog
+	elog "To use the spellchecker (USE=spell) for non-English simply do"
+	elog "$ emerge app-dicts/aspell-[your language]."
+
+	if use x86-fbsd; then
+		elog
+		elog "To improve shared memory usage please set:"
+		elog "$ sysctl kern.ipc.shm_allow_removed=1"
+	fi
+}
+
+pkg_postrm() {
+	use gnome && gnome2_pkg_postrm
+}