Version bump, bug 320095. ChangeLog: http://releases.xfce.org/feeds/project/midori

(Portage version: 2.1.8.3/cvs/Linux x86_64)

2 files changed, 85 insertions, 1 deletions

diff --git a/www-client/midori/ChangeLog b/www-client/midori/ChangeLog
index 5918aedfd41e..da242236a5d7 100644
--- a/www-client/midori/ChangeLog
+++ b/www-client/midori/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for www-client/midori
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v 1.28 2010/03/31 15:03:48 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v 1.29 2010/05/18 19:13:53 darkside Exp $
+
+*midori-0.2.5 (18 May 2010)
+
+  18 May 2010; Jeremy Olexa <darkside@gentoo.org> +midori-0.2.5.ebuild:
+  Version bump, bug 320095. ChangeLog:
+  http://releases.xfce.org/feeds/project/midori
 
   31 Mar 2010; Samuli Suominen <ssuominen@gentoo.org> midori-0.2.4.ebuild,
   midori-9999.ebuild:
diff --git a/www-client/midori/midori-0.2.5.ebuild b/www-client/midori/midori-0.2.5.ebuild
new file mode 100644
index 000000000000..13a34fca01e5
--- /dev/null
+++ b/www-client/midori/midori-0.2.5.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/midori/midori-0.2.5.ebuild,v 1.1 2010/05/18 19:13:53 darkside Exp $
+
+EAPI=2
+
+PYTHON_DEPEND="2:2.6"
+
+inherit eutils multilib python xfconf
+
+DESCRIPTION="A lightweight web browser based on WebKitGTK+"
+HOMEPAGE="http://www.twotoasts.de/index.php?/pages/midori_summary.html"
+SRC_URI="mirror://xfce/src/apps/${PN}/0.2/${P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd"
+IUSE="doc gnome html idn libnotify nls +sqlite +unique"
+
+RDEPEND="libnotify? ( x11-libs/libnotify )
+	>=net-libs/libsoup-2.25.2
+	>=net-libs/webkit-gtk-1.1.1
+	dev-libs/libxml2
+	>=x11-libs/gtk+-2.10:2
+	gnome? ( net-libs/libsoup[gnome] )
+	idn? ( net-dns/libidn )
+	sqlite? ( >=dev-db/sqlite-3.0 )
+	unique? ( dev-libs/libunique )"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	dev-util/pkgconfig
+	doc? ( dev-util/gtk-doc )
+	html? ( dev-python/docutils )
+	nls? ( sys-devel/gettext )"
+
+pkg_setup() {
+	python_set_active_version 2
+}
+
+src_prepare() {
+	# moving docs to version-specific directory
+	sed -i -e "s:\${DOCDIR}/${PN}:\${DOCDIR}/${PF}/:g" wscript || die
+	sed -i -e "s:/${PN}/user/midori.html:/${PF}/user/midori.html:g" midori/midori-browser.c || die
+}
+
+src_configure() {
+	strip-linguas -i po
+
+	CCFLAGS="${CFLAGS}" LINKFLAGS="${LDFLAGS}" ./waf \
+		--prefix="/usr/" \
+		--libdir="/usr/$(get_libdir)" \
+		--disable-docs \
+		--enable-addons \
+		$(use_enable doc apidocs) \
+		$(use_enable html userdocs) \
+		$(use_enable idn libidn) \
+		$(use_enable libnotify) \
+		$(use_enable nls nls) \
+		$(use_enable sqlite) \
+		$(use_enable unique) \
+		configure || die "configure failed"
+}
+
+src_compile() {
+	NUMJOBS=$(sed -e 's/.*\(\-j[ 0-9]\+\) .*/\1/; s/--jobs=\?/-j/' <<< ${MAKEOPTS})
+	./waf build ${NUMJOBS} || die "build failed"
+}
+
+src_install() {
+	DESTDIR=${D} ./waf install || die "install failed"
+	dodoc AUTHORS ChangeLog INSTALL TODO || die "dodoc failed"
+}
+
+pkg_postinst() {
+	xfconf_pkg_postinst
+	ewarn "Midori tends to crash due to bugs in WebKit."
+	ewarn "Report bugs at http://www.twotoasts.de/bugs"
+}