Version bump with missing dev-lang/vala depend wrt #336643 by Agostino Sarubbo and pax-mark -m for hardened wrt #338561 by René Neumann.

(Portage version: 2.2_rc87/cvs/Linux x86_64)

3 files changed, 108 insertions, 9 deletions

diff --git a/www-client/midori/ChangeLog b/www-client/midori/ChangeLog
index 6f784c844c45..566a2383a5dc 100644
--- a/www-client/midori/ChangeLog
+++ b/www-client/midori/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for www-client/midori
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v 1.36 2010/09/06 21:07:20 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v 1.37 2010/09/29 02:40:29 ssuominen Exp $
+
+*midori-0.2.8 (29 Sep 2010)
+
+  29 Sep 2010; Samuli Suominen <ssuominen@gentoo.org> +midori-0.2.8.ebuild,
+  midori-9999.ebuild:
+  Version bump with missing dev-lang/vala depend wrt #336643 by Agostino
+  Sarubbo and pax-mark -m for hardened wrt #338561 by René Neumann.
 
   06 Sep 2010; Samuli Suominen <ssuominen@gentoo.org> midori-0.2.7.ebuild,
   midori-9999.ebuild:
diff --git a/www-client/midori/midori-0.2.8.ebuild b/www-client/midori/midori-0.2.8.ebuild
new file mode 100644
index 000000000000..65b5bdbedb81
--- /dev/null
+++ b/www-client/midori/midori-0.2.8.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/midori/midori-0.2.8.ebuild,v 1.1 2010/09/29 02:40:29 ssuominen Exp $
+
+EAPI=2
+
+PYTHON_DEPEND="2:2.6"
+
+inherit pax-utils eutils multilib python xfconf
+
+DESCRIPTION="A lightweight web browser based on WebKitGTK+"
+HOMEPAGE="http://www.twotoasts.de/index.php?/pages/midori_summary.html"
+SRC_URI="mirror://xfce/src/apps/${PN}/0.2/${P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd"
+IUSE="doc gnome +html idn libnotify nls +unique vala"
+
+RDEPEND="libnotify? ( x11-libs/libnotify )
+	>=net-libs/libsoup-2.25.2
+	>=net-libs/webkit-gtk-1.1.1
+	>=dev-db/sqlite-3.0
+	dev-libs/libxml2
+	>=x11-libs/gtk+-2.10:2
+	gnome? ( net-libs/libsoup[gnome] )
+	idn? ( net-dns/libidn )
+	unique? ( dev-libs/libunique )
+	vala? ( dev-lang/vala:0 )"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	dev-util/pkgconfig
+	doc? ( dev-util/gtk-doc )
+	html? ( dev-python/docutils )
+	nls? ( sys-devel/gettext )"
+
+pkg_setup() {
+	python_set_active_version 2
+}
+
+src_prepare() {
+	# moving docs to version-specific directory
+	sed -i -e "s:\${DOCDIR}/${PN}:\${DOCDIR}/${PF}/:g" wscript || die
+	sed -i -e "s:/${PN}/user/midori.html:/${PF}/user/midori.html:g" midori/midori-browser.c || die
+}
+
+src_configure() {
+	strip-linguas -i po
+
+	CCFLAGS="${CFLAGS}" LINKFLAGS="${LDFLAGS}" ./waf \
+		--prefix="/usr/" \
+		--libdir="/usr/$(get_libdir)" \
+		--disable-docs \
+		--enable-addons \
+		$(use_enable doc apidocs) \
+		$(use_enable html userdocs) \
+		$(use_enable idn libidn) \
+		$(use_enable libnotify) \
+		$(use_enable nls) \
+		$(use_enable unique) \
+		$(use_enable vala) \
+		configure || die
+}
+
+src_compile() {
+	# This is from dev-libs/boost, keep it synced
+	jobs=$( echo " ${MAKEOPTS} " | \
+		sed -e 's/ --jobs[= ]/ -j /g' \
+		-e 's/ -j \([1-9][0-9]*\)/ -j\1/g' \
+		-e 's/ -j\>/ -j1/g' | \
+		( while read -d ' ' j ; do if [[ "${j#-j}" = "$j" ]]; then continue; fi;
+		jobs="${j#-j}"; done; echo ${jobs} ) )
+	if [[ "${jobs}" != "" ]]; then NUMJOBS="-j"${jobs}; fi;
+
+	./waf build ${NUMJOBS} || die
+}
+
+src_install() {
+	DESTDIR=${D} ./waf install || die
+	dodoc AUTHORS ChangeLog INSTALL TODO || die
+
+	pax-mark -m "${D}"/usr/bin/midori #338561
+}
+
+pkg_postinst() {
+	xfconf_pkg_postinst
+	ewarn "Midori tends to crash due to bugs in WebKit."
+	ewarn "Report bugs at http://www.twotoasts.de/bugs"
+}
diff --git a/www-client/midori/midori-9999.ebuild b/www-client/midori/midori-9999.ebuild
index ebd48811470d..a709b263d5ba 100644
--- a/www-client/midori/midori-9999.ebuild
+++ b/www-client/midori/midori-9999.ebuild
@@ -1,12 +1,12 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/midori/midori-9999.ebuild,v 1.18 2010/09/06 21:07:20 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/midori/midori-9999.ebuild,v 1.19 2010/09/29 02:40:29 ssuominen Exp $
 
 EAPI=2
 
 PYTHON_DEPEND="2:2.6"
 
-inherit eutils multilib python xfconf git
+inherit pax-utils eutils multilib python xfconf git
 
 DESCRIPTION="A lightweight web browser based on WebKitGTK+"
 HOMEPAGE="http://www.twotoasts.de/index.php?/pages/midori_summary.html"
@@ -27,7 +27,8 @@ RDEPEND="libnotify? ( x11-libs/libnotify )
 	>=x11-libs/gtk+-2.10:2
 	gnome? ( net-libs/libsoup[gnome] )
 	idn? ( net-dns/libidn )
-	unique? ( dev-libs/libunique )"
+	unique? ( dev-libs/libunique )
+	vala? ( dev-lang/vala:0 )"
 DEPEND="${RDEPEND}
 	dev-util/intltool
 	dev-util/pkgconfig
@@ -57,10 +58,10 @@ src_configure() {
 		$(use_enable html userdocs) \
 		$(use_enable idn libidn) \
 		$(use_enable libnotify) \
-		$(use_enable nls nls) \
+		$(use_enable nls) \
 		$(use_enable unique) \
 		$(use_enable vala) \
-		configure || die "configure failed"
+		configure || die
 }
 
 src_compile() {
@@ -73,12 +74,14 @@ src_compile() {
 		jobs="${j#-j}"; done; echo ${jobs} ) )
 	if [[ "${jobs}" != "" ]]; then NUMJOBS="-j"${jobs}; fi;
 
-	./waf build ${NUMJOBS} || die "build failed"
+	./waf build ${NUMJOBS} || die
 }
 
 src_install() {
-	DESTDIR=${D} ./waf install || die "install failed"
-	dodoc AUTHORS ChangeLog INSTALL TODO || die "dodoc failed"
+	DESTDIR=${D} ./waf install || die
+	dodoc AUTHORS ChangeLog INSTALL TODO || die
+
+	pax-mark -m "${D}"/usr/bin/midori #338561
 }
 
 pkg_postinst() {