Version bump.

(Portage version: 2.2.0_alpha177/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

3 files changed, 121 insertions, 2 deletions

diff --git a/www-client/midori/ChangeLog b/www-client/midori/ChangeLog
index 0085900f6bae..fbc6bb1a3bb3 100644
--- a/www-client/midori/ChangeLog
+++ b/www-client/midori/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for www-client/midori
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v 1.110 2013/04/09 15:56:57 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v 1.111 2013/06/01 14:27:45 ssuominen Exp $
+
+*midori-0.5.2 (01 Jun 2013)
+
+  01 Jun 2013; Samuli Suominen <ssuominen@gentoo.org> +midori-0.5.2.ebuild,
+  midori-9999.ebuild:
+  Version bump.
 
   09 Apr 2013; Samuli Suominen <ssuominen@gentoo.org> -midori-0.4.8.ebuild,
   -files/midori-0.4.8-desktop_file_validation.patch, -midori-0.4.9.ebuild:
diff --git a/www-client/midori/midori-0.5.2.ebuild b/www-client/midori/midori-0.5.2.ebuild
new file mode 100644
index 000000000000..7f84591892c2
--- /dev/null
+++ b/www-client/midori/midori-0.5.2.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/midori/midori-0.5.2.ebuild,v 1.1 2013/06/01 14:27:45 ssuominen Exp $
+
+EAPI=5
+VALA_MIN_API_VERSION=0.14
+
+PYTHON_COMPAT=( python2_7 )
+
+unset _live_inherits
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="git://git.xfce.org/apps/${PN}"
+	_live_inherits=git-2
+else
+	KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd"
+	SRC_URI="mirror://xfce/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
+fi
+
+inherit eutils fdo-mime gnome2-utils python-any-r1 waf-utils vala ${_live_inherits}
+
+DESCRIPTION="A lightweight web browser based on WebKitGTK+"
+HOMEPAGE="http://twotoasts.de/index.php/midori/"
+
+LICENSE="LGPL-2.1 MIT"
+SLOT="0"
+IUSE="+deprecated doc gnome libnotify nls +unique webkit2 zeitgeist"
+
+RDEPEND=">=dev-db/sqlite-3.6.19:3
+	>=dev-libs/glib-2.22
+	dev-libs/libxml2
+	>=net-libs/libsoup-2.34:2.4
+	x11-libs/libXScrnSaver
+	deprecated? (
+		net-libs/webkit-gtk:2
+		x11-libs/gtk+:2
+		unique? ( dev-libs/libunique:1 )
+		)
+	!deprecated? (
+		>=app-crypt/gcr-3
+		>=net-libs/webkit-gtk-1.10.2:3
+		x11-libs/gtk+:3
+		unique? ( dev-libs/libunique:3 )
+		webkit2? ( >=net-libs/webkit-gtk-2 )
+		)
+	gnome? ( || ( >=net-libs/libsoup-2.42:2.4 >=net-libs/libsoup-gnome-2.34:2.4 ) )
+	libnotify? ( >=x11-libs/libnotify-0.7 )
+	zeitgeist? ( >=dev-libs/libzeitgeist-0.3.14 )"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	$(vala_depend)
+	dev-util/intltool
+	gnome-base/librsvg
+	doc? ( dev-util/gtk-doc )
+	nls? ( sys-devel/gettext )"
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+
+	DOCS=( AUTHORS ChangeLog HACKING INSTALL TODO TRANSLATE )
+	HTML_DOCS=( data/faq.html data/faq.css )
+}
+
+src_unpack() {
+	if [[ ${PV} == *9999* ]]; then
+		git-2_src_unpack
+	else
+		default
+	fi
+}
+
+src_prepare() {
+	# Force disabled because we don't have this custom renamed in Portage
+	sed -i -e 's:gcr-3-gtk2:&dIsAbLe:' wscript || die
+
+	vala_src_prepare
+}
+
+src_configure() {
+	strip-linguas -i po
+
+	local myconf
+	use deprecated || myconf="$(use_enable webkit2)"
+
+	waf-utils_src_configure \
+		--disable-docs \
+		$(use_enable doc apidocs) \
+		$(use_enable unique) \
+		$(use_enable libnotify) \
+		--disable-granite \
+		--enable-addons \
+		$(use_enable nls) \
+		$(use_enable !deprecated gtk3) \
+		$(use_enable zeitgeist) \
+		${myconf}
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+}
diff --git a/www-client/midori/midori-9999.ebuild b/www-client/midori/midori-9999.ebuild
index bcb9a2a80237..d833dff4d599 100644
--- a/www-client/midori/midori-9999.ebuild
+++ b/www-client/midori/midori-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/midori/midori-9999.ebuild,v 1.48 2013/03/31 19:10:56 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/midori/midori-9999.ebuild,v 1.49 2013/06/01 14:27:45 ssuominen Exp $
 
 EAPI=5
 VALA_MIN_API_VERSION=0.14
@@ -41,6 +41,7 @@ RDEPEND=">=dev-db/sqlite-3.6.19:3
 		>=net-libs/webkit-gtk-1.10.2:3
 		x11-libs/gtk+:3
 		unique? ( dev-libs/libunique:3 )
+		webkit2? ( >=net-libs/webkit-gtk-2 )
 		)
 	gnome? ( || ( >=net-libs/libsoup-2.42:2.4 >=net-libs/libsoup-gnome-2.34:2.4 ) )
 	libnotify? ( >=x11-libs/libnotify-0.7 )