Version bump <http://my.opera.com/desktopteam/blog/2007/11/16/even-more-work>.

(Portage version: 2.1.3.19)

3 files changed, 208 insertions, 1 deletions

diff --git a/www-client/opera/ChangeLog b/www-client/opera/ChangeLog
index 3a91cf0b07ca..b17dc4793fbd 100644
--- a/www-client/opera/ChangeLog
+++ b/www-client/opera/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for www-client/opera
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/opera/ChangeLog,v 1.172 2007/11/09 17:29:45 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/opera/ChangeLog,v 1.173 2007/11/16 18:25:20 jer Exp $
+
+*opera-9.50_beta4 (16 Nov 2007)
+
+  16 Nov 2007; Jeroen Roovers <jer@gentoo.org> +opera-9.50_beta4.ebuild:
+  Version bump <http://my.opera.com/desktopteam/blog/2007/11/16/even-more-work>.
 
   09 Nov 2007; Jeroen Roovers <jer@gentoo.org> opera-9.50_beta1.ebuild,
   opera-9.50_beta2.ebuild, opera-9.50_beta3.ebuild:
diff --git a/www-client/opera/files/digest-opera-9.50_beta4 b/www-client/opera/files/digest-opera-9.50_beta4
new file mode 100644
index 000000000000..6285987b9bbd
--- /dev/null
+++ b/www-client/opera/files/digest-opera-9.50_beta4
@@ -0,0 +1,18 @@
+MD5 c0c725f2bca853c7563f83803ddedb09 opera-9.50-20071115.10-static-qt.i386-1669.tar.bz2 7547111
+RMD160 f1e17a0b21d16d5592bc467592b69aba4636c7ff opera-9.50-20071115.10-static-qt.i386-1669.tar.bz2 7547111
+SHA256 5886e78cc59b6a93b539288f405c43841a12e63c8205659a39bc74766a0dce66 opera-9.50-20071115.10-static-qt.i386-1669.tar.bz2 7547111
+MD5 0e817bb65e12df41d4958ba793167421 opera-9.50-20071115.2-shared-qt.x86_64-1669.tar.bz2 6199348
+RMD160 ae02d18d44f72ca3d28ebba207d67f0639b66195 opera-9.50-20071115.2-shared-qt.x86_64-1669.tar.bz2 6199348
+SHA256 250c116e65c42a2221dea28d6b15a98ec0e3b7c8620ab01c794f7d3d6717b393 opera-9.50-20071115.2-shared-qt.x86_64-1669.tar.bz2 6199348
+MD5 b67ec6df5a48b7a0910869267fd31715 opera-9.50-20071115.4-shared-qt.i386.freebsd-1669.tar.bz2 5734072
+RMD160 26d79b40bb92c9b29405ead1931c6783c8b8779d opera-9.50-20071115.4-shared-qt.i386.freebsd-1669.tar.bz2 5734072
+SHA256 b8ed018dc98573dc03736114031fa00d4bfe5d5587014de568cc4ef79729686d opera-9.50-20071115.4-shared-qt.i386.freebsd-1669.tar.bz2 5734072
+MD5 9a8b1cc2f0373af10068cbf1096d3ea1 opera-9.50-20071115.5-static-qt.i386.freebsd-1669.tar.bz2 7641863
+RMD160 281b8ea3c7e1ed963a057b3867bbc62b64f971e2 opera-9.50-20071115.5-static-qt.i386.freebsd-1669.tar.bz2 7641863
+SHA256 24682f418559544bc3124334fab35de08106ebf01774126499fd9fc71b2fd3ce opera-9.50-20071115.5-static-qt.i386.freebsd-1669.tar.bz2 7641863
+MD5 bb63d1b16322f0d18d6f7326bd6ffbdd opera-9.50-20071115.6-shared-qt.i386-1669.tar.bz2 5641091
+RMD160 2ee02f934b80a2ba9d51251c1ff1eec0679a43ba opera-9.50-20071115.6-shared-qt.i386-1669.tar.bz2 5641091
+SHA256 c36b7ffe327b641112213b69484779b1fc7ec559835c71d41b3f6be84842e57f opera-9.50-20071115.6-shared-qt.i386-1669.tar.bz2 5641091
+MD5 0b779962d83c8f2e9671c270f32ffd7b opera-9.50-20071115.6-shared-qt.ppc-1669.tar.bz2 5700214
+RMD160 c1f8074a1df6e052d7f2590bb3dc0867c30bd26f opera-9.50-20071115.6-shared-qt.ppc-1669.tar.bz2 5700214
+SHA256 9973845c58d5d4e196146c881984747fb84d55e80635810272f328c9bba0ab4d opera-9.50-20071115.6-shared-qt.ppc-1669.tar.bz2 5700214
diff --git a/www-client/opera/opera-9.50_beta4.ebuild b/www-client/opera/opera-9.50_beta4.ebuild
new file mode 100644
index 000000000000..7e1cb78e0d25
--- /dev/null
+++ b/www-client/opera/opera-9.50_beta4.ebuild
@@ -0,0 +1,184 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/opera/opera-9.50_beta4.ebuild,v 1.1 2007/11/16 18:25:20 jer Exp $
+
+GCONF_DEBUG="no"
+
+inherit eutils gnome2
+
+DESCRIPTION="Opera web browser"
+HOMEPAGE="http://www.opera.com/"
+
+SLOT="0"
+LICENSE="OPERA-9.0"
+KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
+
+IUSE="qt-static spell gnome elibc_FreeBSD"
+RESTRICT="strip mirror"
+
+O_LNG=""
+O_SUFF="1669"
+O_VER="9.50-20071115"
+
+O_URI="http://snapshot.opera.com/unix/snapshot-${O_SUFF}/"
+
+SRC_URI="
+	amd64? ( ${O_URI}x86_64-linux/${PN}-${O_VER}.2-shared-qt.x86_64${O_LNG}-${O_SUFF}.tar.bz2 )
+	ppc? ( ${O_URI}ppc-linux/${PN}-${O_VER}.6-shared-qt.ppc${O_LNG}-${O_SUFF}.tar.bz2 )
+	x86? ( qt-static? ( ${O_URI}intel-linux/${PN}-${O_VER}.10-static-qt.i386${O_LNG}-${O_SUFF}.tar.bz2 )
+		   !qt-static? ( ${O_URI}intel-linux/${PN}-${O_VER}.6-shared-qt.i386${O_LNG}-${O_SUFF}.tar.bz2 ) )
+	x86-fbsd? (	qt-static? ( ${O_URI}intel-freebsd/${PN}-${O_VER}.5-static-qt.i386.freebsd${O_LNG}-${O_SUFF}.tar.bz2 )
+				!qt-static? ( ${O_URI}intel-freebsd/${PN}-${O_VER}.4-shared-qt.i386.freebsd${O_LNG}-${O_SUFF}.tar.bz2 ) )
+	"
+
+DEPEND=">=sys-apps/sed-4"
+
+RDEPEND="media-libs/libexif
+	media-libs/jpeg
+	>=media-libs/fontconfig-2.1.94-r1
+	x11-libs/libXrandr
+	x11-libs/libXp
+	x11-libs/libXmu
+	x11-libs/libXi
+	x11-libs/libXft
+	x11-libs/libXext
+	x11-libs/libXcursor
+	x11-libs/libX11
+	x11-libs/libSM
+	x11-libs/libICE
+	!qt-static? ( =x11-libs/qt-3* )
+	amd64? ( =x11-libs/qt-3* )
+	ppc? ( =x11-libs/qt-3* )
+	spell? ( app-text/aspell )
+	x86-fbsd? ( =virtual/libstdc++-3* )"
+
+S="${WORKDIR}/${A/.tar.bz2/}"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}/${PN}-9.00-install.patch"
+
+	# bug #181300:
+	use elibc_FreeBSD || epatch "${FILESDIR}/${PN}-9.50-pluginpath.patch"
+	use elibc_FreeBSD && epatch "${FILESDIR}/${PN}-9.50-pluginpath-fbsd.patch"
+
+	sed -i -e "s:config_dir=\"/etc\":config_dir=\"${D}/etc/\":g" \
+		-e "s:/usr/share/applnk:${D}/usr/share/applnk:g" \
+		-e "s:/usr/share/pixmaps:${D}/usr/share/pixmaps:g" \
+		-e "s:/usr/share/icons:${D}/usr/share/icons:g" \
+		-e "s:/etc/X11:${D}/etc/X11:g" \
+		-e "s:/usr/share/gnome:${D}/usr/share/gnome:g" \
+		-e "s:/opt/gnome/share:${D}/opt/gnome/share:g" \
+		-e 's:#\(OPERA_FORCE_JAVA_ENABLED=\):\1:' \
+		-e 's:#\(export LD_PRELOAD OPERA_FORCE_JAVA_ENABLED\):\1:' \
+		-e 's:read str_answer:return 0:' \
+		-e "s:/opt/kde:${D}/usr/kde:" \
+		-e "s:\(str_localdirplugin=\).*$:\1/opt/opera/lib/opera/plugins:" \
+		install.sh || die "sed failed"
+
+}
+
+src_compile() {
+	# This workaround is sadly needed because gnome2.eclass doesn't check
+	# whether a configure script or Makefile exists.
+	true
+}
+
+src_install() {
+	# Prepare installation directories for Opera's installer script.
+	dodir /etc
+
+	# Opera's native installer.
+	./install.sh --prefix="${D}"/opt/opera || die "install.sh failed"
+
+	einfo "It is safe to ignore warnings about failed checksums"
+	einfo "and about files that would be ignored ..."
+	einfo "Completing the installation where install.sh abandoned us ..."
+
+	# java workaround
+	sed -i -e 's:LD_PRELOAD="${OPERA_JAVA_DIR}/libawt.so":LD_PRELOAD="$LD_PRELOAD"\:"${OPERA_JAVA_DIR}/libawt.so":' "${D}"/opt/opera/bin/opera
+
+	dosed /opt/opera/bin/opera
+	dosed /opt/opera/share/opera/java/opera.policy
+
+	# Install the icons
+	insinto /usr/share/pixmaps
+	doins usr/share/pixmaps/opera.xpm
+
+	local res
+	for res in 16x16 22x22 32x32 48x48 ; do
+		insinto /usr/share/icons/hicolor/${res}/apps
+		doins usr/share/icons/hicolor/${res}/apps/opera.png
+	done
+
+	# Install the menu entry
+	insinto /usr/share/applications
+	doins "${FILESDIR}"/opera.desktop
+
+	# Install a symlink /usr/bin/opera
+	dodir /usr/bin
+	dosym /opt/opera/bin/opera /usr/bin/opera
+
+	# fix plugin path
+	echo "Plugin Path=/opt/opera/lib/opera/plugins" >> "${D}"/etc/opera6rc
+
+	# enable spellcheck
+	if use spell; then
+		if use qt-static; then
+			DIR=$O_VER.1
+		else
+			use sparc && DIR=$O_VER.2 || DIR=$O_VER.5
+		fi
+		echo "Spell Check Engine=/opt/opera/lib/opera/${DIR}/spellcheck.so" >> "${D}"/opt/opera/share/opera/ini/spellcheck.ini
+	fi
+
+	dodir /etc/revdep-rebuild
+	echo 'SEARCH_DIRS_MASK="/opt/opera/lib/opera/plugins"' > "${D}"/etc/revdep-rebuild/90opera
+
+	# Change libz.so.3 to libz.so.1 for gentoo/freebsd
+	if use elibc_FreeBSD; then
+		scanelf -qR -N libz.so.3 -F "#N" "${D}"/opt/${PN}/ | \
+		while read i; do
+			if [[ $(strings "$i" | fgrep -c libz.so.3) -ne 1 ]];
+			then
+				export SANITY_CHECK_LIBZ_FAILED=1
+				break
+			fi
+			sed -i -e 's/libz\.so\.3/libz.so.1/g' "$i"
+		done
+		[[ "$SANITY_CHECK_LIBZ_FAILED" = "1" ]] && die "failed to change libz.so.3 to libz.so.1"
+	fi
+
+	# symlink to libflash-player.so:
+	dosym /opt/netscape/plugins/libflashplayer.so \
+		/opt/opera/lib/opera/plugins/libflashplayer.so
+
+	# Add the Opera man dir to MANPATH:
+	insinto /etc/env.d
+	echo 'MANPATH="/opt/opera/share/man"' >> "${D}"/etc/env.d/90opera
+}
+
+pkg_postinst() {
+	use gnome && gnome2_pkg_postinst
+
+	elog "For localized language files take a look at:"
+	elog " http://www.opera.com/download/languagefiles/index.dml"
+	elog
+	elog "To use the spellchecker (USE=spell) for non-English simply do"
+	elog "$ emerge app-dicts/aspell-[your language]."
+
+	if use elibc_FreeBSD; then
+		elog
+		elog "To improve shared memory usage please set:"
+		elog "$ sysctl kern.ipc.shm_allow_removed=1"
+	fi
+
+	elog "The Opera betas have several issues with plugins, notably"
+	elog "net-www/netscape-flash. See also https://bugs.gentoo.org/198162"
+}
+
+pkg_postrm() {
+	use gnome && gnome2_pkg_postrm
+}