Version bump and fix some deps to make sure people don't use uncompatible combination

(Portage version: 2.2_rc96/cvs/Linux x86_64)

4 files changed, 91 insertions, 3 deletions

diff --git a/sys-power/upower/ChangeLog b/sys-power/upower/ChangeLog
index 94e61bcfb58a..51570f3905c4 100644
--- a/sys-power/upower/ChangeLog
+++ b/sys-power/upower/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-power/upower
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-power/upower/ChangeLog,v 1.22 2010/10/13 21:37:06 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-power/upower/ChangeLog,v 1.23 2010/10/17 08:16:04 ssuominen Exp $
+
+*upower-0.9.6 (17 Oct 2010)
+
+  17 Oct 2010; Samuli Suominen <ssuominen@gentoo.org> +upower-0.9.6.ebuild:
+  Version bump.
 
   13 Oct 2010; Markus Meier <maekke@gentoo.org> upower-0.9.5.ebuild:
   arm stable, bug #338988
diff --git a/sys-power/upower/upower-0.9.4.ebuild b/sys-power/upower/upower-0.9.4.ebuild
index 7d2808ce6f61..40e98585c11a 100644
--- a/sys-power/upower/upower-0.9.4.ebuild
+++ b/sys-power/upower/upower-0.9.4.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-power/upower/upower-0.9.4.ebuild,v 1.7 2010/09/09 03:19:33 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-power/upower/upower-0.9.4.ebuild,v 1.8 2010/10/17 08:16:04 ssuominen Exp $
 
 EAPI=3
 inherit eutils linux-info
@@ -18,6 +18,7 @@ COMMON_DEPEND=">=dev-libs/glib-2.21.5:2
 	>=sys-apps/dbus-1
 	>=dev-libs/dbus-glib-0.76
 	>=sys-auth/polkit-0.91
+	<sys-auth/polkit-0.97
 	introspection? ( dev-libs/gobject-introspection )
 	kernel_linux? ( >=sys-fs/udev-151[extras]
 		virtual/libusb:0 )
diff --git a/sys-power/upower/upower-0.9.5.ebuild b/sys-power/upower/upower-0.9.5.ebuild
index c89b7e1d2ce3..b01b0177ad7b 100644
--- a/sys-power/upower/upower-0.9.5.ebuild
+++ b/sys-power/upower/upower-0.9.5.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-power/upower/upower-0.9.5.ebuild,v 1.11 2010/10/13 21:37:06 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-power/upower/upower-0.9.5.ebuild,v 1.12 2010/10/17 08:16:04 ssuominen Exp $
 
 EAPI=3
 inherit linux-info
@@ -18,6 +18,7 @@ COMMON_DEPEND=">=dev-libs/dbus-glib-0.76
 	>=dev-libs/glib-2.21.5:2
 	>=sys-apps/dbus-1
 	>=sys-auth/polkit-0.91
+	<sys-auth/polkit-0.97
 	introspection? ( dev-libs/gobject-introspection )
 	kernel_linux? ( >=sys-fs/udev-151[extras]
 		virtual/libusb:1
diff --git a/sys-power/upower/upower-0.9.6.ebuild b/sys-power/upower/upower-0.9.6.ebuild
new file mode 100644
index 000000000000..75c13ebb51ba
--- /dev/null
+++ b/sys-power/upower/upower-0.9.6.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-power/upower/upower-0.9.6.ebuild,v 1.1 2010/10/17 08:16:04 ssuominen Exp $
+
+EAPI=3
+inherit linux-info
+
+DESCRIPTION="D-Bus abstraction for enumerating power devices and querying history and statistics"
+HOMEPAGE="http://upower.freedesktop.org/"
+SRC_URI="http://upower.freedesktop.org/releases/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="debug doc introspection ipod kernel_FreeBSD kernel_linux"
+
+COMMON_DEPEND=">=dev-libs/dbus-glib-0.76
+	>=dev-libs/glib-2.21.5:2
+	>=sys-apps/dbus-1
+	>=sys-auth/polkit-0.97
+	introspection? ( dev-libs/gobject-introspection )
+	kernel_linux? ( >=sys-fs/udev-151[extras]
+		virtual/libusb:1
+		ipod? ( >=app-pda/libimobiledevice-0.9.7 ) )
+	!sys-apps/devicekit-power"
+RDEPEND="${COMMON_DEPEND}
+	kernel_linux? ( >=sys-power/pm-utils-1.4.1 )"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/libxslt
+	app-text/docbook-xsl-stylesheets
+	>=dev-util/intltool-0.40.0
+	dev-util/pkgconfig
+	doc? ( dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.1.2 )"
+
+RESTRICT="test" # error getting system bus
+
+pkg_setup() {
+	if use kernel_linux; then
+		if use amd64 || use x86; then
+			CONFIG_CHECK="~ACPI_SYSFS_POWER"
+			linux-info_pkg_setup
+		fi
+	fi
+}
+
+src_prepare() {
+	sed -i -e '/DISABLE_DEPRECATED/d' configure || die
+}
+
+src_configure() {
+	local backend
+
+	if use kernel_linux; then
+		backend=linux
+	elif use kernel_FreeBSD; then
+		backend=freebsd
+	else
+		backend=dummy
+	fi
+
+	econf \
+		--localstatedir="${EPREFIX}/var" \
+		$(use_enable introspection) \
+		--disable-dependency-tracking \
+		--disable-static \
+		$(use_enable debug verbose-mode) \
+		--enable-man-pages \
+		$(use_enable doc gtk-doc) \
+		--disable-tests \
+		--with-html-dir="${EPREFIX}/usr/share/doc/${PF}/html" \
+		--with-backend=${backend} \
+		$(use_with ipod idevice)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	dodoc AUTHORS HACKING NEWS README
+
+	find "${ED}" -name '*.la' -exec rm -f '{}' +
+}