Version bump to 1.1.7, and add the new beta. The new beta simplifies the init scripts as well.

(Portage version: 2.2.0_alpha120/cvs/Linux x86_64)

5 files changed, 117 insertions, 4 deletions

diff --git a/sys-libs/freeipmi/ChangeLog b/sys-libs/freeipmi/ChangeLog
index 4ef207c66079..06727d290b6f 100644
--- a/sys-libs/freeipmi/ChangeLog
+++ b/sys-libs/freeipmi/ChangeLog
@@ -1,6 +1,15 @@
 # ChangeLog for sys-libs/freeipmi
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/ChangeLog,v 1.51 2012/07/29 02:46:27 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/ChangeLog,v 1.52 2012/07/31 01:41:36 flameeyes Exp $
+
+*freeipmi-1.1.7 (31 Jul 2012)
+*freeipmi-1.2.0_beta0 (31 Jul 2012)
+
+  31 Jul 2012; Diego E. Pettenò <flameeyes@gentoo.org>
+  +files/bmc-watchdog.initd.4, +files/ipmidetectd.confd, +freeipmi-1.1.7.ebuild,
+  +freeipmi-1.2.0_beta0.ebuild, -freeipmi-1.1.6-r1.ebuild:
+  Version bump to 1.1.7, and add the new beta. The new beta simplifies the init
+  scripts as well.
 
 *freeipmi-1.1.6-r1 (29 Jul 2012)
 
diff --git a/sys-libs/freeipmi/files/bmc-watchdog.initd.4 b/sys-libs/freeipmi/files/bmc-watchdog.initd.4
new file mode 100644
index 000000000000..713f23484064
--- /dev/null
+++ b/sys-libs/freeipmi/files/bmc-watchdog.initd.4
@@ -0,0 +1,19 @@
+#!/sbin/runscript
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/files/bmc-watchdog.initd.4,v 1.1 2012/07/31 01:41:36 flameeyes Exp $
+
+extra_commands="condrestart"
+description_condrestart="Restart the service only if started already"
+
+command="/usr/sbin/${SVCNAME}"
+command_args="${OPTIONS}"
+pidfile=/var/run/$SVCNAME.pid
+
+depend() {
+    need logger
+}
+
+condrestart() {
+	service_started && restart
+}
diff --git a/sys-libs/freeipmi/files/ipmidetectd.confd b/sys-libs/freeipmi/files/ipmidetectd.confd
new file mode 100644
index 000000000000..74245f14c0c5
--- /dev/null
+++ b/sys-libs/freeipmi/files/ipmidetectd.confd
@@ -0,0 +1,5 @@
+# This configuration file controls the behaviour of the ipmid daemon
+# from FreeIPMI.
+# See `man 8 ipmitdetectd` for further information.
+
+# OPTIONS="-c /etc/freeipmi/ipmidetectd.conf"
diff --git a/sys-libs/freeipmi/freeipmi-1.1.6-r1.ebuild b/sys-libs/freeipmi/freeipmi-1.1.7.ebuild
index abf66f6c45df..e1902c83b4e0 100644
--- a/sys-libs/freeipmi/freeipmi-1.1.6-r1.ebuild
+++ b/sys-libs/freeipmi/freeipmi-1.1.7.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/freeipmi-1.1.6-r1.ebuild,v 1.1 2012/07/29 02:46:27 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/freeipmi-1.1.7.ebuild,v 1.1 2012/07/31 01:41:36 flameeyes Exp $
 
 EAPI=4
 
@@ -22,8 +22,9 @@ RDEPEND="${RDEPEND}
 	sys-apps/openrc"
 
 src_prepare() {
-	epatch "${FILESDIR}"/${PN}-1.1.1-strictaliasing.patch
-	epatch "${FILESDIR}"/${P}-thresholds.patch
+	epatch \
+		"${FILESDIR}"/${PN}-1.1.1-strictaliasing.patch \
+		"${FILESDIR}"/${PN}-1.1.6-thresholds.patch
 
 	AT_M4DIR="config" eautoreconf
 }
diff --git a/sys-libs/freeipmi/freeipmi-1.2.0_beta0.ebuild b/sys-libs/freeipmi/freeipmi-1.2.0_beta0.ebuild
new file mode 100644
index 000000000000..cdfc88106566
--- /dev/null
+++ b/sys-libs/freeipmi/freeipmi-1.2.0_beta0.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/freeipmi-1.2.0_beta0.ebuild,v 1.1 2012/07/31 01:41:36 flameeyes Exp $
+
+EAPI=4
+
+inherit autotools eutils
+
+DESCRIPTION="Provides Remote-Console and System Management Software as per IPMI v1.5/2.0"
+HOMEPAGE="http://www.gnu.org/software/freeipmi/"
+
+MY_P="${P/_/.}"
+S="${WORKDIR}"/${MY_P}
+[[ ${MY_P} == *.beta* ]] && ALPHA="-alpha"
+SRC_URI="mirror://gnu${ALPHA}/${PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug"
+
+RDEPEND="dev-libs/libgcrypt"
+DEPEND="${RDEPEND}
+		virtual/os-headers"
+RDEPEND="${RDEPEND}
+	sys-apps/openrc"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${PN}-1.1.1-strictaliasing.patch
+
+	AT_M4DIR="config" eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable debug) \
+		--disable-dependency-tracking \
+		--enable-fast-install \
+		--disable-static \
+		--disable-init-scripts \
+		--localstatedir=/var
+}
+
+# There are no tests
+src_test() { :; }
+
+src_install() {
+	emake DESTDIR="${D}" docdir="/usr/share/doc/${PF}" install
+	find "${D}" -name '*.la' -delete
+
+	# freeipmi by defaults install _all_ commands to /usr/sbin, but
+	# quite a few can be run remotely as standard user, so move them
+	# in /usr/bin afterwards.
+	dodir /usr/bin
+	for file in ipmi{detect,ping,power,console}; do
+		mv "${D}"/usr/{s,}bin/${file} || die
+
+		# The default install symlinks these commands to add a dash
+		# after the ipmi prefix; we repeat those after move for
+		# consistency.
+		rm "${D}"/usr/sbin/${file/ipmi/ipmi-}
+		dosym ${file} /usr/bin/${file/ipmi/ipmi-}
+	done
+
+	dodoc AUTHORS ChangeLog* DISCLAIMER* NEWS README* TODO doc/*.txt
+
+	keepdir \
+		/var/cache/ipmimonitoringsdrcache \
+		/var/lib/freeipmi \
+		/var/log/ipmiconsole
+
+	# starting from version 1.2.0 the two daemons are similar enough
+	newinitd "${FILESDIR}"/bmc-watchdog.initd.4 ipmidetectd
+	newconfd "${FILESDIR}"/ipmidetectd.confd ipmidetectd
+
+	newinitd "${FILESDIR}"/bmc-watchdog.initd.4 bmc-watchdog
+	newconfd "${FILESDIR}"/bmc-watchdog.confd bmc-watchdog
+}