sys-kernel/aufs-sources: Bump to latest genpatches and linux release

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

2 files changed, 78 insertions, 1 deletions

diff --git a/sys-kernel/aufs-sources/ChangeLog b/sys-kernel/aufs-sources/ChangeLog
index a71c53aa78e2..f770b880f838 100644
--- a/sys-kernel/aufs-sources/ChangeLog
+++ b/sys-kernel/aufs-sources/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-kernel/aufs-sources
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-kernel/aufs-sources/ChangeLog,v 1.97 2014/02/17 11:22:02 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/aufs-sources/ChangeLog,v 1.98 2014/02/21 12:46:41 jlec Exp $
+
+*aufs-sources-3.13.4 (21 Feb 2014)
+
+  21 Feb 2014; Justin Lecher <jlec@gentoo.org> +aufs-sources-3.13.4.ebuild:
+  Bump to latest genpatches and linux release
 
 *aufs-sources-3.10.30 (17 Feb 2014)
 
diff --git a/sys-kernel/aufs-sources/aufs-sources-3.13.4.ebuild b/sys-kernel/aufs-sources/aufs-sources-3.13.4.ebuild
new file mode 100644
index 000000000000..a891ad9daa33
--- /dev/null
+++ b/sys-kernel/aufs-sources/aufs-sources-3.13.4.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/aufs-sources/aufs-sources-3.13.4.ebuild,v 1.1 2014/02/21 12:46:41 jlec Exp $
+
+EAPI=5
+
+ETYPE="sources"
+K_WANT_GENPATCHES="base extras experimental"
+K_GENPATCHES_VER="7"
+K_DEBLOB_AVAILABLE="1"
+UNIPATCH_STRICTORDER=1
+inherit kernel-2 eutils
+detect_version
+detect_arch
+
+AUFS_VERSION=3.13_p20140127
+AUFS_TARBALL="aufs-sources-${AUFS_VERSION}.tar.xz"
+# git archive -v --remote=git://git.code.sf.net/p/aufs/aufs3-standalone aufs${AUFS_VERSION/_p*} > aufs-sources-${AUFS_VERSION}.tar
+AUFS_URI="http://dev.gentoo.org/~jlec/distfiles/${AUFS_TARBALL}"
+
+KEYWORDS="~amd64 ~x86"
+HOMEPAGE="http://dev.gentoo.org/~mpagano/genpatches http://aufs.sourceforge.net/"
+IUSE="deblob experimental module vanilla"
+
+DESCRIPTION="Full sources including the Gentoo patchset for the ${KV_MAJOR}.${KV_MINOR} kernel tree and aufs3 support"
+SRC_URI="
+	${KERNEL_URI}
+	${ARCH_URI}
+	${AUFS_URI}
+	!vanilla? ( ${GENPATCHES_URI} )
+	"
+
+PDEPEND=">=sys-fs/aufs-util-3.9"
+
+src_unpack() {
+	if use vanilla; then
+		unset UNIPATCH_LIST_GENPATCHES UNIPATCH_LIST_DEFAULT
+		ewarn "You are using USE=vanilla"
+		ewarn "This will drop all support from the gentoo kernel security team"
+	fi
+
+	UNIPATCH_LIST="
+		"${WORKDIR}"/aufs3-kbuild.patch
+		"${WORKDIR}"/aufs3-base.patch
+		"${WORKDIR}"/aufs3-mmap.patch"
+
+	use module && UNIPATCH_LIST+=" "${WORKDIR}"/aufs3-standalone.patch"
+
+	unpack ${AUFS_TARBALL}
+
+	kernel-2_src_unpack
+}
+
+src_prepare() {
+	if ! use module; then
+		sed -e 's:tristate:bool:g' -i "${WORKDIR}"/fs/aufs/Kconfig || die
+	fi
+	cp -f "${WORKDIR}"/include/uapi/linux/aufs_type.h include/uapi/linux/aufs_type.h || die
+	cp -rf "${WORKDIR}"/{Documentation,fs} . || die
+}
+
+pkg_postinst() {
+	kernel-2_pkg_postinst
+	einfo "For more info on this patchset, and how to report problems, see:"
+	einfo "${HOMEPAGE}"
+	has_version sys-fs/aufs-util && \
+		einfo "In order to use aufs FS you need to install sys-fs/aufs-util"
+}
+
+pkg_postrm() {
+	kernel-2_pkg_postrm
+}