Proper Linux 3.13 support, Linux 3.14 support, numerous races/deadlocks fixed, many compatibility fixes

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xBEE84C64)

3 files changed, 139 insertions, 3 deletions

diff --git a/sys-fs/zfs-kmod/ChangeLog b/sys-fs/zfs-kmod/ChangeLog
index 6d5600234a7c..4dc78a4ff1b1 100644
--- a/sys-fs/zfs-kmod/ChangeLog
+++ b/sys-fs/zfs-kmod/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for sys-fs/zfs-kmod
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/zfs-kmod/ChangeLog,v 1.41 2014/01/27 04:47:49 ryao Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/zfs-kmod/ChangeLog,v 1.42 2014/04/10 03:13:36 ryao Exp $
+
+*zfs-kmod-0.6.2-r4 (10 Apr 2014)
+
+  10 Apr 2014; Richard Yao <ryao@gentoo.org> +zfs-kmod-0.6.2-r4.ebuild,
+  zfs-kmod-0.6.2-r3.ebuild:
+  Proper Linux 3.13 support, Linux 3.14 support, numerous races/deadlocks fixed,
+  many compatibility fixes
 
   27 Jan 2014; Richard Yao <ryao@gentoo.org> zfs-kmod-0.6.2-r3.ebuild:
   Linux 3.13 support: This requires no changes to the ZFS C code, so we just
diff --git a/sys-fs/zfs-kmod/zfs-kmod-0.6.2-r3.ebuild b/sys-fs/zfs-kmod/zfs-kmod-0.6.2-r3.ebuild
index 9e4a08ed5de1..348ec90f1e15 100644
--- a/sys-fs/zfs-kmod/zfs-kmod-0.6.2-r3.ebuild
+++ b/sys-fs/zfs-kmod/zfs-kmod-0.6.2-r3.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/zfs-kmod/zfs-kmod-0.6.2-r3.ebuild,v 1.2 2014/01/27 04:47:49 ryao Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/zfs-kmod/zfs-kmod-0.6.2-r3.ebuild,v 1.3 2014/04/10 03:13:36 ryao Exp $
 
 EAPI="4"
 
@@ -60,7 +60,7 @@ pkg_setup() {
 	kernel_is ge 2 6 26 || die "Linux 2.6.26 or newer required"
 
 	[ ${PV} != "9999" ] && \
-		{ kernel_is le 3 13 || die "Linux 3.13 is the latest supported version."; }
+		{ kernel_is le 3 12 || die "Linux 3.12 is the latest supported version."; }
 
 	check_extra_config
 }
diff --git a/sys-fs/zfs-kmod/zfs-kmod-0.6.2-r4.ebuild b/sys-fs/zfs-kmod/zfs-kmod-0.6.2-r4.ebuild
new file mode 100644
index 000000000000..94e9cfce9018
--- /dev/null
+++ b/sys-fs/zfs-kmod/zfs-kmod-0.6.2-r4.ebuild
@@ -0,0 +1,129 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/zfs-kmod/zfs-kmod-0.6.2-r4.ebuild,v 1.1 2014/04/10 03:13:36 ryao Exp $
+
+EAPI="4"
+
+AT_M4DIR="config"
+AUTOTOOLS_AUTORECONF="1"
+AUTOTOOLS_IN_SOURCE_BUILD="1"
+
+inherit bash-completion-r1 flag-o-matic linux-info linux-mod toolchain-funcs autotools-utils
+
+if [ ${PV} == "9999" ] ; then
+	inherit git-2
+	MY_PV=9999
+	EGIT_REPO_URI="git://github.com/zfsonlinux/zfs.git"
+else
+	inherit eutils versionator
+	MY_PV=$(replace_version_separator 3 '-')
+	SRC_URI="https://github.com/zfsonlinux/zfs/archive/zfs-${MY_PV}.tar.gz
+		http://dev.gentoo.org/~ryao/dist/${PN}-${MY_PV}-p3.tar.xz"
+	S="${WORKDIR}/zfs-zfs-${MY_PV}"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="Linux ZFS kernel module for sys-fs/zfs"
+HOMEPAGE="http://zfsonlinux.org/"
+
+LICENSE="CDDL debug? ( GPL-2+ )"
+SLOT="0"
+IUSE="custom-cflags debug +rootfs"
+RESTRICT="test"
+
+DEPEND="
+	=sys-kernel/spl-${PV}*
+	dev-lang/perl
+	virtual/awk
+"
+
+RDEPEND="${DEPEND}
+	!sys-fs/zfs-fuse
+"
+
+pkg_setup() {
+	linux-info_pkg_setup
+	CONFIG_CHECK="!DEBUG_LOCK_ALLOC
+		BLK_DEV_LOOP
+		EFI_PARTITION
+		IOSCHED_NOOP
+		MODULES
+		!PAX_KERNEXEC_PLUGIN_METHOD_OR
+		ZLIB_DEFLATE
+		ZLIB_INFLATE
+	"
+
+	use rootfs && \
+		CONFIG_CHECK="${CONFIG_CHECK} BLK_DEV_INITRD
+			DEVTMPFS"
+
+	kernel_is ge 2 6 26 || die "Linux 2.6.26 or newer required"
+
+	[ ${PV} != "9999" ] && \
+		{ kernel_is le 3 14 || die "Linux 3.14 is the latest supported version."; }
+
+	check_extra_config
+}
+
+src_prepare() {
+	# Remove GPLv2-licensed ZPIOS unless we are debugging
+	use debug || sed -e 's/^subdir-m += zpios$//' -i "${S}/module/Makefile.in"
+
+	if [ ${PV} != "9999" ]
+	then
+		# Apply patch set
+		EPATCH_SUFFIX="patch" \
+		EPATCH_FORCE="yes" \
+		epatch "${WORKDIR}/${PN}-${MY_PV}-patches"
+	fi
+
+	autotools-utils_src_prepare
+}
+
+src_configure() {
+	use custom-cflags || strip-flags
+	filter-ldflags -Wl,*
+
+	set_arch_to_kernel
+	local myeconfargs=(
+		--bindir="${EPREFIX}/bin"
+		--sbindir="${EPREFIX}/sbin"
+		--with-config=kernel
+		--with-linux="${KV_DIR}"
+		--with-linux-obj="${KV_OUT_DIR}"
+		$(use_enable debug)
+	)
+	autotools-utils_src_configure
+}
+
+src_install() {
+	autotools-utils_src_install
+	dodoc AUTHORS COPYRIGHT DISCLAIMER README.markdown
+}
+
+pkg_postinst() {
+	linux-mod_pkg_postinst
+
+	# Remove old modules
+	if [ -d "${EROOT}lib/modules/${KV_FULL}/addon/zfs" ]
+	then
+		ewarn "${PN} now installs modules in ${EROOT}lib/modules/${KV_FULL}/extra/zfs"
+		ewarn "Old modules were detected in ${EROOT}lib/modules/${KV_FULL}/addon/zfs"
+		ewarn "Automatically removing old modules to avoid problems."
+		rm -r "${EROOT}lib/modules/${KV_FULL}/addon/zfs" || die "Cannot remove modules"
+		rmdir --ignore-fail-on-non-empty "${EROOT}lib/modules/${KV_FULL}/addon"
+	fi
+
+	if use x86 || use arm
+	then
+		ewarn "32-bit kernels will likely require increasing vmalloc to"
+		ewarn "at least 256M and decreasing zfs_arc_max to some value less than that."
+	fi
+
+	ewarn "This version of ZFSOnLinux includes support for features flags."
+	ewarn "If you upgrade your pools to make use of feature flags, you will lose"
+	ewarn "the ability to import them using older versions of ZFSOnLinux."
+	ewarn "Any new pools will be created with feature flag support and will"
+	ewarn "not be compatible with older versions of ZFSOnLinux. To create a new"
+	ewarn "pool that is backward compatible, use zpool create -o version=28 ..."
+}