Version bump.

(Portage version: 2.2.0_alpha110/cvs/Linux x86_64)

2 files changed, 67 insertions, 1 deletions

diff --git a/sys-fs/avfs/ChangeLog b/sys-fs/avfs/ChangeLog
index 910ca7c81df2..00faf09d7f8c 100644
--- a/sys-fs/avfs/ChangeLog
+++ b/sys-fs/avfs/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-fs/avfs
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/avfs/ChangeLog,v 1.39 2012/03/20 13:25:12 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/avfs/ChangeLog,v 1.40 2012/06/13 07:58:44 radhermit Exp $
+
+*avfs-1.0.1 (13 Jun 2012)
+
+  13 Jun 2012; Tim Harder <radhermit@gentoo.org> +avfs-1.0.1.ebuild:
+  Version bump.
 
   20 Mar 2012; Agostino Sarubbo <ago@gentoo.org> avfs-1.0.0.ebuild:
   Stable for amd64, wrt bug #400503
diff --git a/sys-fs/avfs/avfs-1.0.1.ebuild b/sys-fs/avfs/avfs-1.0.1.ebuild
new file mode 100644
index 000000000000..7f9c36ff4fef
--- /dev/null
+++ b/sys-fs/avfs/avfs-1.0.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/avfs/avfs-1.0.1.ebuild,v 1.1 2012/06/13 07:58:44 radhermit Exp $
+
+EAPI=4
+inherit eutils
+
+DESCRIPTION="AVFS is a virtual filesystem that allows browsing of compressed files."
+HOMEPAGE="http://sourceforge.net/projects/avf"
+SRC_URI="mirror://sourceforge/avf/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~x86"
+IUSE="static-libs +lzma"
+
+RDEPEND=">=sys-fs/fuse-2.4
+	sys-libs/zlib
+	app-arch/bzip2
+	lzma? ( app-arch/xz-utils )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_configure() {
+	econf \
+		--enable-fuse \
+		--enable-library \
+		--enable-shared \
+		--with-system-zlib \
+		--with-system-bzlib \
+		$(use_enable static-libs static) \
+		$(use_with lzma xz)
+}
+
+src_install() {
+	default
+
+	# remove cruft
+	rm "${D}"/usr/bin/{davpass,ftppass} || die
+
+	# install docs
+	dodoc doc/{api-overview,background,FORMAT,INSTALL.*,README.avfs-fuse}
+	dosym /usr/lib/avfs/extfs/README /usr/share/doc/${PF}/README.extfs
+
+	docinto scripts
+	dodoc scripts/{avfscoda*,*pass}
+
+	prune_libtool_files
+}
+
+pkg_postinst() {
+	einfo "This version of AVFS includes FUSE support. It is user-based."
+	einfo "To execute:"
+	einfo "1) as user, mkdir ~/.avfs"
+	einfo "2) make sure fuse is either compiled into the kernel OR"
+	einfo "   modprobe fuse or add to startup."
+	einfo "3) run mountavfs"
+	einfo "To unload daemon, type umountavfs"
+	einfo
+	einfo "READ the documentation! Enjoy :)"
+}