Version bump, bug 509022 by Fabian Henze.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

2 files changed, 63 insertions, 1 deletions

diff --git a/sys-fs/btrfs-progs/ChangeLog b/sys-fs/btrfs-progs/ChangeLog
index 3175775a0c25..a44187544fc9 100644
--- a/sys-fs/btrfs-progs/ChangeLog
+++ b/sys-fs/btrfs-progs/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-fs/btrfs-progs
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/btrfs-progs/ChangeLog,v 1.77 2014/04/14 20:26:56 slyfox Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/btrfs-progs/ChangeLog,v 1.78 2014/04/29 01:50:12 floppym Exp $
+
+*btrfs-progs-3.14.1 (29 Apr 2014)
+
+  29 Apr 2014; Mike Gilbert <floppym@gentoo.org> +btrfs-progs-3.14.1.ebuild:
+  Version bump, bug 509022 by Fabian Henze.
 
 *btrfs-progs-3.14_pre20140414 (14 Apr 2014)
 
diff --git a/sys-fs/btrfs-progs/btrfs-progs-3.14.1.ebuild b/sys-fs/btrfs-progs/btrfs-progs-3.14.1.ebuild
new file mode 100644
index 000000000000..4696da1356a4
--- /dev/null
+++ b/sys-fs/btrfs-progs/btrfs-progs-3.14.1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/btrfs-progs/btrfs-progs-3.14.1.ebuild,v 1.1 2014/04/29 01:50:12 floppym Exp $
+
+EAPI=5
+
+inherit eutils multilib toolchain-funcs
+
+libbtrfs_soname=0
+
+if [[ ${PV} != 9999 ]]; then
+	MY_PV=v${PV}
+	KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+	SRC_URI="https://www.kernel.org/pub/linux/kernel/people/mason/${PN}/${PN}-${MY_PV}.tar.xz"
+	S="${WORKDIR}"/${PN}-${MY_PV}
+else
+	inherit git-2
+	EGIT_REPO_URI="git://git.kernel.org/pub/scm/linux/kernel/git/mason/btrfs-progs.git
+		https://git.kernel.org/pub/scm/linux/kernel/git/mason/btrfs-progs.git"
+fi
+
+DESCRIPTION="Btrfs filesystem utilities"
+HOMEPAGE="https://btrfs.wiki.kernel.org"
+
+LICENSE="GPL-2"
+SLOT="0/${libbtrfs_soname}"
+IUSE=""
+
+DEPEND="
+	dev-libs/lzo
+	sys-libs/zlib
+	sys-apps/acl
+	sys-fs/e2fsprogs
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	epatch_user
+}
+
+src_compile() {
+	emake \
+		AR="$(tc-getAR)" \
+		CC="$(tc-getCC)" \
+		CFLAGS="${CFLAGS}" \
+		LDFLAGS="${LDFLAGS}" \
+		BUILD_VERBOSE=1
+}
+
+src_install() {
+	emake install \
+		DESTDIR="${D}" \
+		prefix=/usr \
+		bindir=/sbin \
+		libdir=/usr/$(get_libdir) \
+		mandir=/usr/share/man
+}