[sys-cluster/ceph] Version bump

(Portage version: 2.2.0_alpha151/cvs/Linux x86_64, signed Manifest commit with key F82F92E6)

3 files changed, 215 insertions, 2 deletions

diff --git a/sys-cluster/ceph/ChangeLog b/sys-cluster/ceph/ChangeLog
index 464c92d14f22..796aebad9635 100644
--- a/sys-cluster/ceph/ChangeLog
+++ b/sys-cluster/ceph/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for sys-cluster/ceph
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/ceph/ChangeLog,v 1.27 2012/12/17 13:07:51 alexxy Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/ceph/ChangeLog,v 1.28 2013/01/14 09:02:08 alexxy Exp $
+
+*ceph-9999 (14 Jan 2013)
+*ceph-0.56.1 (14 Jan 2013)
+
+  14 Jan 2013; Alexey Shvetsov <alexxy@gentoo.org> +ceph-0.56.1.ebuild,
+  +ceph-9999.ebuild:
+  [sys-cluster/ceph] Version bump
 
 *ceph-0.55.1 (17 Dec 2012)
 
diff --git a/sys-cluster/ceph/ceph-0.56.1.ebuild b/sys-cluster/ceph/ceph-0.56.1.ebuild
new file mode 100644
index 000000000000..13622fc1295c
--- /dev/null
+++ b/sys-cluster/ceph/ceph-0.56.1.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/ceph/ceph-0.56.1.ebuild,v 1.1 2013/01/14 09:02:08 alexxy Exp $
+
+EAPI=5
+
+if [[ $PV = *9999* ]]; then
+	scm_eclass=git-2
+	EGIT_REPO_URI="
+		git://github.com/ceph/ceph.git
+		https://github.com/ceph/ceph.git"
+	SRC_URI=""
+	KEYWORDS=""
+else
+	SRC_URI="http://ceph.com/download/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+inherit autotools eutils multilib ${scm_eclass}
+
+DESCRIPTION="Ceph distributed filesystem"
+HOMEPAGE="http://ceph.com/"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="debug fuse gtk libatomic radosgw static-libs tcmalloc"
+
+CDEPEND="
+	dev-libs/boost
+	dev-libs/fcgi
+	dev-libs/libaio
+	dev-libs/libedit
+	dev-libs/crypto++
+	sys-apps/keyutils
+	fuse? ( sys-fs/fuse )
+	libatomic? ( dev-libs/libatomic_ops )
+	gtk? (
+		x11-libs/gtk+:2
+		dev-cpp/gtkmm:2.4
+		gnome-base/librsvg
+	)
+	radosgw? (
+		dev-libs/fcgi
+		dev-libs/expat
+		net-misc/curl
+	)
+	tcmalloc? ( dev-util/google-perftools )
+	"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig"
+RDEPEND="${CDEPEND}
+	sys-fs/btrfs-progs"
+
+STRIP_MASK="/usr/lib*/rados-classes/*"
+
+src_prepare() {
+	sed -e 's:invoke-rc\.d.*:/etc/init.d/ceph reload >/dev/null:' \
+		-i src/logrotate.conf || die
+	sed -i "/^docdir =/d" src/Makefile.am || die #fix doc path
+	# disable testsnaps
+	sed -e '/testsnaps/d' -i src/Makefile.am || die
+	sed -e "/bin=/ s:lib:$(get_libdir):" "${FILESDIR}"/${PN}.initd \
+		> "${T}"/${PN}.initd || die
+	sed -i -e '/AM_INIT_AUTOMAKE/s:-Werror ::' src/leveldb/configure.ac || die #423755
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--without-hadoop \
+		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
+		--includedir=/usr/include \
+		$(use_with debug) \
+		$(use_with fuse) \
+		$(use_with libatomic libatomic-ops) \
+		$(use_with radosgw) \
+		$(use_with gtk gtk2) \
+		$(use_enable static-libs static) \
+		$(use_with tcmalloc)
+}
+
+src_install() {
+	default
+
+	prune_libtool_files --all
+
+	rmdir "${ED}/usr/sbin"
+
+	exeinto /usr/$(get_libdir)/ceph
+	newexe src/init-ceph ceph_init.sh
+
+	insinto /etc/logrotate.d/
+	newins src/logrotate.conf ${PN}
+
+	chmod 644 "${ED}"/usr/share/doc/${PF}/sample.*
+
+	keepdir /var/lib/${PN}
+	keepdir /var/lib/${PN}/tmp
+	keepdir /var/log/${PN}/stat
+
+	newinitd "${T}/${PN}.initd" ${PN}
+	newconfd "${FILESDIR}/${PN}.confd" ${PN}
+}
diff --git a/sys-cluster/ceph/ceph-9999.ebuild b/sys-cluster/ceph/ceph-9999.ebuild
new file mode 100644
index 000000000000..abbc24f2dce6
--- /dev/null
+++ b/sys-cluster/ceph/ceph-9999.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/ceph/ceph-9999.ebuild,v 1.1 2013/01/14 09:02:08 alexxy Exp $
+
+EAPI=5
+
+if [[ $PV = *9999* ]]; then
+	scm_eclass=git-2
+	EGIT_REPO_URI="
+		git://github.com/ceph/ceph.git
+		https://github.com/ceph/ceph.git"
+	SRC_URI=""
+	KEYWORDS=""
+else
+	SRC_URI="http://ceph.com/download/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+inherit autotools eutils multilib ${scm_eclass}
+
+DESCRIPTION="Ceph distributed filesystem"
+HOMEPAGE="http://ceph.com/"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="debug fuse gtk libatomic radosgw static-libs tcmalloc"
+
+CDEPEND="
+	dev-libs/boost
+	dev-libs/fcgi
+	dev-libs/libaio
+	dev-libs/libedit
+	dev-libs/crypto++
+	sys-apps/keyutils
+	fuse? ( sys-fs/fuse )
+	libatomic? ( dev-libs/libatomic_ops )
+	gtk? (
+		x11-libs/gtk+:2
+		dev-cpp/gtkmm:2.4
+		gnome-base/librsvg
+	)
+	radosgw? (
+		dev-libs/fcgi
+		dev-libs/expat
+		net-misc/curl
+	)
+	tcmalloc? ( dev-util/google-perftools )
+	"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig"
+RDEPEND="${CDEPEND}
+	sys-fs/btrfs-progs"
+
+STRIP_MASK="/usr/lib*/rados-classes/*"
+
+src_prepare() {
+	sed -e 's:invoke-rc\.d.*:/etc/init.d/ceph reload >/dev/null:' \
+		-i src/logrotate.conf || die
+	sed -i "/^docdir =/d" src/Makefile.am || die #fix doc path
+	# disable testsnaps
+	sed -e '/testsnaps/d' -i src/Makefile.am || die
+	sed -e "/bin=/ s:lib:$(get_libdir):" "${FILESDIR}"/${PN}.initd \
+		> "${T}"/${PN}.initd || die
+	sed -i -e '/AM_INIT_AUTOMAKE/s:-Werror ::' src/leveldb/configure.ac || die #423755
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--without-hadoop \
+		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
+		--includedir=/usr/include \
+		$(use_with debug) \
+		$(use_with fuse) \
+		$(use_with libatomic libatomic-ops) \
+		$(use_with radosgw) \
+		$(use_with gtk gtk2) \
+		$(use_enable static-libs static) \
+		$(use_with tcmalloc)
+}
+
+src_install() {
+	default
+
+	prune_libtool_files --all
+
+	rmdir "${ED}/usr/sbin"
+
+	exeinto /usr/$(get_libdir)/ceph
+	newexe src/init-ceph ceph_init.sh
+
+	insinto /etc/logrotate.d/
+	newins src/logrotate.conf ${PN}
+
+	chmod 644 "${ED}"/usr/share/doc/${PF}/sample.*
+
+	keepdir /var/lib/${PN}
+	keepdir /var/lib/${PN}/tmp
+	keepdir /var/log/${PN}/stat
+
+	newinitd "${T}/${PN}.initd" ${PN}
+	newconfd "${FILESDIR}/${PN}.confd" ${PN}
+}