Version bump, fix #451182

(Portage version: 2.1.11.41/cvs/Linux x86_64, signed Manifest commit with key B658FA13)

1 files changed, 68 insertions, 0 deletions

diff --git a/sys-cluster/corosync/corosync-2.3.0.ebuild b/sys-cluster/corosync/corosync-2.3.0.ebuild
new file mode 100644
index 000000000000..efc2683c04f9
--- /dev/null
+++ b/sys-cluster/corosync/corosync-2.3.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/corosync/corosync-2.3.0.ebuild,v 1.1 2013/01/18 10:22:53 ultrabug Exp $
+
+EAPI=4
+
+inherit autotools base
+
+MY_TREE="b7db472"
+
+DESCRIPTION="OSI Certified implementation of a complete cluster engine"
+HOMEPAGE="http://www.corosync.org/"
+SRC_URI="https://github.com/corosync/corosync/tarball/v${PV} -> ${P}.tar.gz"
+
+LICENSE="BSD-2 public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc infiniband static-libs"
+
+# TODO: support those new configure flags
+# --enable-watchdog : Watchdog support
+# --enable-augeas : Install the augeas lens for corosync.conf
+# --enable-snmp : SNMP protocol support
+# --enable-xmlconf : XML configuration support
+# --enable-systemd : Install systemd service files
+RDEPEND="!sys-cluster/heartbeat
+	infiniband? (
+		sys-infiniband/libibverbs
+		sys-infiniband/librdmacm
+	)
+	dev-libs/nss
+	sys-cluster/libqb"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( sys-apps/groff )"
+
+PATCHES=( "${FILESDIR}/${PN}-2.0.0-docs.patch" )
+
+DOCS=( README.recovery SECURITY TODO AUTHORS )
+
+S="${WORKDIR}/${PN}-${PN}-${MY_TREE}"
+
+src_prepare() {
+	base_src_prepare
+	eautoreconf
+}
+
+src_configure() {
+	# appends lib to localstatedir automatically
+	# FIXME: install just shared libs --disable-static does not work
+	econf \
+		--localstatedir=/var \
+		--docdir=/usr/share/doc/${PF} \
+		$(use_enable doc) \
+		$(use_enable infiniband rdma)
+}
+
+src_install() {
+	default
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	rm "${D}"/etc/init.d/corosync-notifyd || die
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/${PN}.logrotate ${PN}
+
+	keepdir /var/lib/corosync
+	use static-libs || rm -rf "${D}"/usr/$(get_libdir)/*.a || die
+}