Bump to 1.6.4 and EAPI 4, thanks so slepnoga. Bug 394699

(Portage version: 2.1.10.40/cvs/Linux x86_64)

3 files changed, 143 insertions, 1 deletions

diff --git a/sys-auth/sssd/ChangeLog b/sys-auth/sssd/ChangeLog
index 4bd190803dfd..38e79ce0f590 100644
--- a/sys-auth/sssd/ChangeLog
+++ b/sys-auth/sssd/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sys-auth/sssd
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-auth/sssd/ChangeLog,v 1.10 2011/10/28 17:13:52 maksbotan Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/sssd/ChangeLog,v 1.11 2011/12/19 13:39:08 maksbotan Exp $
+
+*sssd-1.6.4 (19 Dec 2011)
+
+  19 Dec 2011; Maxim Koltsov <maksbotan@gentoo.org> +sssd-1.6.4.ebuild,
+  metadata.xml:
+  Bump to 1.6.4 and EAPI 4, thanks so slepnoga. Bug 394699
 
 *sssd-1.6.2 (28 Oct 2011)
 
diff --git a/sys-auth/sssd/metadata.xml b/sys-auth/sssd/metadata.xml
index e7a94104aa03..15c3f4d681d8 100644
--- a/sys-auth/sssd/metadata.xml
+++ b/sys-auth/sssd/metadata.xml
@@ -3,12 +3,17 @@
 <pkgmetadata>
 <maintainer>
 	<email>spamslepnoga@inbox.ru</email>
+	<name>Andreis Vinogradovs</name>
 </maintainer>
 <maintainer>
 	<email>maksbotan@gentoo.org</email>
+	<name>Maxim Koltsov</name>
 </maintainer>
 <use>
 	<flag name="locator">Install sssd's Kerberos plugin</flag>
 	<flag name="logrotate">Install logrotate.d file</flag>
+	<flag name="glib">Use <pkg>dev-libs/glib</pkg> as UTF-8 string library</flag>
+	<flag name="libunistring">Use <pkg>dev-libs/libunistring</pkg> as UTF-8 string library</flag>
+	<flag name='netlink'>Add support for netlink protocol via <pkg>dev-libs/libnl</pkg></flag>
 </use>
 </pkgmetadata>
diff --git a/sys-auth/sssd/sssd-1.6.4.ebuild b/sys-auth/sssd/sssd-1.6.4.ebuild
new file mode 100644
index 000000000000..2e5968ca532c
--- /dev/null
+++ b/sys-auth/sssd/sssd-1.6.4.ebuild
@@ -0,0 +1,131 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/sssd/sssd-1.6.4.ebuild,v 1.1 2011/12/19 13:39:08 maksbotan Exp $
+
+EAPI=4
+
+PYTHON_DEPEND="python? 2:2.6"
+
+inherit python multilib pam linux-info autotools-utils
+
+DESCRIPTION="System Security Services Daemon provides access to identity and authentication"
+HOMEPAGE="http://fedorahosted.org/sssd/"
+SRC_URI="http://fedorahosted.org/released/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="glib doc +locator logrotate netlink nls python +libunistring selinux test"
+
+REQUIRED_USE="^^ ( glib libunistring )"
+
+COMMON_DEP="
+	virtual/pam
+	dev-libs/popt
+	!glib? ( >=dev-libs/libunistring-0.9.3 )
+	glib? ( dev-libs/glib:2 )
+	>=dev-libs/ding-libs-0.1.2
+	>=sys-libs/talloc-2.0
+	sys-libs/tdb
+	sys-libs/tevent
+	sys-libs/ldb
+	>=net-nds/openldap-2.4.19
+	dev-libs/libpcre
+	>=app-crypt/mit-krb5-1.9.1
+	sys-apps/keyutils
+	>=net-dns/c-ares-1.7.4
+	>=dev-libs/nss-3.12.9
+	selinux? ( >=sys-libs/libselinux-2.0.94 >=sys-libs/libsemanage-2.0.45 )
+	net-dns/bind-tools
+	dev-libs/cyrus-sasl
+	sys-apps/dbus
+	nls? ( >=sys-devel/gettext-0.17 )
+	virtual/libintl
+	netlink? ( dev-libs/libnl )
+	"
+
+RDEPEND="${COMMON_DEP}"
+DEPEND="${COMMON_DEP}
+	test? ( dev-libs/check )
+	>=dev-libs/libxslt-1.1.26
+	app-text/docbook-xml-dtd:4.4
+	doc? ( app-doc/doxygen )"
+
+CONFIG_CHECK="~KEYS"
+#AUTOTOOLS_IN_SOURCE_BUILD=1
+
+pkg_setup(){
+	if use python; then
+		python_set_active_version 2
+		python_pkg_setup
+		python_need_rebuild
+	fi
+	linux-info_pkg_setup
+}
+
+src_prepare() {
+	cp -f  "${FILESDIR}"/sssd "${S}/"src/sysv/gentoo/sssd
+}
+
+src_configure(){
+	myconf=""
+	if use glib; then
+		myconf="glib2"
+	else
+		myconf="libunistring"
+	fi
+
+	local myeconfargs=(
+		--localstatedir="${EPREFIX}"/var
+		--enable-nsslibdir="${EPREFIX}"/$(get_libdir)
+		--with-plugin-path="${EPREFIX}"/usr/$(get_libdir)/sssd
+		--enable-pammoddir="${EPREFIX}"/$(getpam_mod_dir)
+		--with-ldb-lib-dir="${EPREFIX}"/usr/$(get_libdir)/ldb/modules/ldb
+		--without-nscd
+		--with-unicode-lib=${myconf}
+		$(use_with selinux)
+		$(use_with selinux semanage)
+		$(use_with python python-bindings)
+		$(use_enable locator krb5-locator-plugin)
+		$(use_enable nls )
+		$(use_with netlink libnl) )
+
+	autotools-utils_src_configure
+}
+
+src_install(){
+	autotools-utils_src_install
+	remove_libtool_files all
+
+	insinto /etc/sssd
+	insopts -m600
+	doins "${S}"/src/examples/sssd.conf
+
+	if use logrotate; then
+		insinto /etc/logrotate.d
+		insopts -m644
+		newins "${S}"/src/examples/logrotate sssd
+	fi
+
+	if use python; then
+		python_clean_installation_image
+		python_convert_shebangs 2 "${ED}$(python_get_sitedir)/"*.py
+	fi
+	newconfd "${FILESDIR}"/sssd.conf sssd
+}
+
+src_test() {
+	autotools-utils_src_test
+}
+
+pkg_postinst(){
+	elog "You must set up sssd.conf (default installed into /etc/sssd)"
+	elog "and (optionally) configuration in /etc/pam.d in order to use SSSD"
+	elog "features. Please see howto in	http://fedorahosted.org/sssd/wiki/HOWTO_Configure_1_0_2"
+
+	use python && python_mod_optimize SSSDConfig.py ipachangeconf.py
+}
+
+pkg_postrm() {
+	use python && python_mod_cleanup SSSDConfig.py ipachangeconf.py
+}