Bump Debian patchset for new Dell server support, also add optional static build for infra use.

(Portage version: 2.2.10/cvs/Linux x86_64, unsigned Manifest commit)

2 files changed, 89 insertions, 1 deletions

diff --git a/sys-apps/ipmitool/ChangeLog b/sys-apps/ipmitool/ChangeLog
index 110408d21af2..fbda261a78ed 100644
--- a/sys-apps/ipmitool/ChangeLog
+++ b/sys-apps/ipmitool/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/ipmitool
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/ipmitool/ChangeLog,v 1.26 2014/08/10 20:24:25 slyfox Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/ipmitool/ChangeLog,v 1.27 2014/10/11 21:21:18 robbat2 Exp $
+
+*ipmitool-1.8.14-r1 (11 Oct 2014)
+
+  11 Oct 2014; Robin H. Johnson <robbat2@gentoo.org> +ipmitool-1.8.14-r1.ebuild:
+  Bump Debian patchset for new Dell server support, also add optional static
+  build for infra use.
 
   10 Aug 2014; Sergei Trofimovich <slyfox@gentoo.org> ipmitool-1.8.11-r1.ebuild,
   ipmitool-1.8.11.ebuild, ipmitool-1.8.14.ebuild:
diff --git a/sys-apps/ipmitool/ipmitool-1.8.14-r1.ebuild b/sys-apps/ipmitool/ipmitool-1.8.14-r1.ebuild
new file mode 100644
index 000000000000..10a5da14095b
--- /dev/null
+++ b/sys-apps/ipmitool/ipmitool-1.8.14-r1.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/ipmitool/ipmitool-1.8.14-r1.ebuild,v 1.1 2014/10/11 21:21:18 robbat2 Exp $
+
+EAPI=4
+inherit eutils
+
+DESCRIPTION="Utility for controlling IPMI enabled devices."
+HOMEPAGE="http://ipmitool.sf.net/"
+DEBIAN_PR="4.debian"
+DEBIAN_P="${P/-/_}"
+DEBIAN_PF="${DEBIAN_P}-${DEBIAN_PR}"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
+	https://launchpad.net/ubuntu/+archive/primary/+files/${DEBIAN_PF}.tar.xz"
+#IUSE="freeipmi openipmi status"
+IUSE="openipmi static"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ia64 ~ppc ~x86"
+LICENSE="BSD"
+
+RDEPEND="dev-libs/openssl"
+DEPEND="${RDEPEND}
+		openipmi? ( sys-libs/openipmi )
+		virtual/os-headers"
+		#freeipmi? ( sys-libs/freeipmi )
+# ipmitool CAN build against || ( sys-libs/openipmi sys-libs/freeipmi )
+# but it doesn't actually need either.
+
+src_prepare() {
+	[ -d "${S}"/debian ] && mv "${S}"/debian{,.package}
+	ln -s "${WORKDIR}"/debian "${S}"
+	for p in $(cat debian/patches/series) ; do
+		epatch debian/patches/$p
+	done
+}
+
+src_configure() {
+	# - LIPMI and BMC are the Solaris libs
+	# - OpenIPMI is unconditionally enabled in the configure as there is compat
+	# code that is used if the library itself is not available
+	# FreeIPMI does build now, but is disabled until the other arches keyword it
+	#	`use_enable freeipmi intf-free` \
+	# --enable-ipmievd is now unconditional
+	econf \
+		$(use_enable static) \
+		--enable-ipmishell \
+		--enable-intf-lan \
+		--enable-intf-lanplus \
+		--enable-intf-open \
+		--enable-intf-serial \
+		--disable-intf-bmc \
+		--disable-intf-dummy \
+		--disable-intf-free \
+		--disable-intf-imb \
+		--disable-intf-lipmi \
+		--disable-internal-md5 \
+		--with-kerneldir=/usr --bindir=/usr/sbin \
+		|| die "econf failed"
+	# Fix linux/ipmi.h to compile properly. This is a hack since it doesn't
+	# include the below file to define some things.
+	echo "#include <asm/byteorder.h>" >>config.h
+}
+
+src_compile() {
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PACKAGE="${PF}" install || die "emake install failed"
+
+	into /usr
+	dosbin contrib/bmclanconf
+	rm -f "${D}"/usr/share/doc/${PF}/COPYING
+	docinto contrib
+	cd "${S}"/contrib
+	dodoc collect_data.sh create_rrds.sh create_webpage_compact.sh create_webpage.sh README
+
+	newinitd "${FILESDIR}"/${PN}-1.8.9-ipmievd.initd ipmievd
+	newconfd "${FILESDIR}"/${PN}-1.8.9-ipmievd.confd ipmievd
+	# TODO: init script for contrib/bmc-snmp-proxy
+	# TODO: contrib/exchange-bmc-os-info
+}