Make use of the new hwids ebuild.

(Portage version: 2.2.0_alpha96/cvs/Linux x86_64)

2 files changed, 73 insertions, 1 deletions

diff --git a/sys-apps/usbutils/ChangeLog b/sys-apps/usbutils/ChangeLog
index 885bb74bc58c..762ba57246d9 100644
--- a/sys-apps/usbutils/ChangeLog
+++ b/sys-apps/usbutils/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/usbutils
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/usbutils/ChangeLog,v 1.134 2012/01/31 16:17:50 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/usbutils/ChangeLog,v 1.135 2012/04/01 01:48:07 flameeyes Exp $
+
+*usbutils-005-r1 (01 Apr 2012)
+
+  01 Apr 2012; Diego E. Pettenò <flameeyes@gentoo.org> +usbutils-005-r1.ebuild:
+  Make use of the new hwids ebuild.
 
   31 Jan 2012; Mike Frysinger <vapier@gentoo.org> usbutils-005.ebuild:
   Trim usb.ids.gz file since the package currently lacks the plumbing to
diff --git a/sys-apps/usbutils/usbutils-005-r1.ebuild b/sys-apps/usbutils/usbutils-005-r1.ebuild
new file mode 100644
index 000000000000..2b7ab57d541e
--- /dev/null
+++ b/sys-apps/usbutils/usbutils-005-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/usbutils/usbutils-005-r1.ebuild,v 1.1 2012/04/01 01:48:07 flameeyes Exp $
+
+EAPI="4"
+
+PYTHON_DEPEND="python? 2:2.6"
+
+inherit autotools eutils python
+
+DESCRIPTION="USB enumeration utilities"
+HOMEPAGE="http://linux-usb.sourceforge.net/"
+SRC_URI="mirror://debian/pool/main/u/${PN}/${PN}_${PV}.orig.tar.gz"
+#SRC_URI="mirror://kernel/linux/utils/usb/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="python zlib"
+
+RDEPEND="virtual/libusb:1
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+RDEPEND="${RDEPEND}
+	sys-apps/hwids"
+
+pkg_setup() {
+	if use python; then
+		python_set_active_version 2
+		python_pkg_setup
+	fi
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-missing-includes.patch
+
+	eautoreconf
+
+	if use python; then
+		python_convert_shebangs 2 lsusb.py
+		sed -i -e '/^usbids/s:/usr/share:/usr/share/misc:' lsusb.py || die
+	fi
+}
+
+src_configure() {
+	econf \
+		--datarootdir=/usr/share \
+		--datadir=/usr/share/misc \
+		$(use_enable zlib)
+}
+
+src_install() {
+	default
+	newdoc usbhid-dump/NEWS NEWS.usbhid-dump
+
+	rm "${ED}"/usr/share/misc/usb.ids* "${ED}"/usr/sbin/update-usbids.sh || die
+
+	use python || rm -f "${ED}"/usr/bin/lsusb.py
+
+	newbin "${FILESDIR}"/usbmodules.sh usbmodules
+}
+
+pkg_postinst() {
+	elog "The 'network-cron' USE flag is gone; if you want a more up-to-date"
+	elog "usb.ids file, you should use sys-apps/hwids-99999999 (live ebuild)."
+}