Version bump.

(Portage version: 2.2.0_alpha100/cvs/Linux x86_64)

2 files changed, 67 insertions, 1 deletions

diff --git a/sys-apps/moreutils/ChangeLog b/sys-apps/moreutils/ChangeLog
index 3771be253f2c..405a04ec05d4 100644
--- a/sys-apps/moreutils/ChangeLog
+++ b/sys-apps/moreutils/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/moreutils
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/moreutils/ChangeLog,v 1.41 2012/04/07 17:58:50 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/moreutils/ChangeLog,v 1.42 2012/04/15 21:23:44 radhermit Exp $
+
+*moreutils-0.46 (15 Apr 2012)
+
+  15 Apr 2012; Tim Harder <radhermit@gentoo.org> +moreutils-0.46.ebuild:
+  Version bump.
 
   07 Apr 2012; Samuli Suominen <ssuominen@gentoo.org> -moreutils-0.45.ebuild:
   old
diff --git a/sys-apps/moreutils/moreutils-0.46.ebuild b/sys-apps/moreutils/moreutils-0.46.ebuild
new file mode 100644
index 000000000000..cfac5d09c92c
--- /dev/null
+++ b/sys-apps/moreutils/moreutils-0.46.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/moreutils/moreutils-0.46.ebuild,v 1.1 2012/04/15 21:23:44 radhermit Exp $
+
+EAPI=4
+inherit eutils toolchain-funcs prefix
+
+DESCRIPTION="a growing collection of the unix tools that nobody thought to write thirty years ago"
+HOMEPAGE="http://kitenet.net/~joey/code/moreutils/"
+SRC_URI="mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86 ~x86-linux"
+IUSE="+doc +perl"
+
+RDEPEND="
+	perl? (
+		dev-lang/perl
+		dev-perl/IPC-Run
+		dev-perl/Time-Duration
+		dev-perl/TimeDate
+	)"
+DEPEND="
+	doc? (
+		dev-lang/perl
+		>=app-text/docbook2X-0.8.8-r2
+		app-text/docbook-xml-dtd:4.4
+	)"
+
+S=${WORKDIR}/${PN}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-0.45-dtd-path.patch
+	eprefixify *.docbook
+
+	# Don't build manpages
+	if ! use doc ; then
+		sed -i -e '/^all:/s/$(MANS)//' -e '/man1/d' Makefile || die
+	fi
+
+	# Don't install perl scripts
+	if ! use perl ; then
+		sed -i -e '/PERLSCRIPTS/d' Makefile || die
+	fi
+}
+
+src_compile() {
+	tc-export CC
+	emake CFLAGS="${CFLAGS}" DOCBOOK2XMAN=docbook2man.pl PREFIX="${EPREFIX}/usr"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" INSTALL_BIN=install install
+
+	# sys-process is more advanced than parallel from moreutils, rename it
+	if use doc; then
+		mv -vf "${ED}"usr/share/man/man1/{,${PN}_}parallel.1 || die
+	fi
+	mv -vf "${ED}"usr/bin/{,${PN}_}parallel || die
+}