version bump and sync live ebuild.

(Portage version: 2.2.0_alpha142/cvs/Linux i686, signed Manifest commit with key 0x30C46538)

3 files changed, 96 insertions, 3 deletions

diff --git a/sys-apps/kmod/ChangeLog b/sys-apps/kmod/ChangeLog
index 57347f04ee90..bde6f35b34f1 100644
--- a/sys-apps/kmod/ChangeLog
+++ b/sys-apps/kmod/ChangeLog
@@ -1,5 +1,11 @@
 # ChangeLog for sys-apps/kmod
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/ChangeLog,v 1.53 2012/10/20 09:30:13 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/ChangeLog,v 1.54 2012/11/08 06:41:10 williamh Exp $
+
+*kmod-11 (08 Nov 2012)
+
+  08 Nov 2012; William Hubbs <williamh@gentoo.org> +kmod-11.ebuild,
+  kmod-9999.ebuild:
+  version bump and sync live ebuild
 
 *kmod-10-r2 (20 Oct 2012)
 
diff --git a/sys-apps/kmod/kmod-11.ebuild b/sys-apps/kmod/kmod-11.ebuild
new file mode 100644
index 000000000000..1d12e66c9d34
--- /dev/null
+++ b/sys-apps/kmod/kmod-11.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/kmod-11.ebuild,v 1.1 2012/11/08 06:41:10 williamh Exp $
+
+EAPI=4
+
+inherit autotools eutils toolchain-funcs libtool
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/kernel/${PN}/${PN}.git"
+	inherit git-2
+else
+	SRC_URI="mirror://kernel/linux/utils/kernel/kmod/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+fi
+
+DESCRIPTION="library and tools for managing linux kernel modules"
+HOMEPAGE="http://git.kernel.org/?p=utils/kernel/kmod/kmod.git"
+
+LICENSE="LGPL-2"
+SLOT="0"
+IUSE="debug doc lzma static-libs +tools zlib"
+
+# Upstream does not support running the test suite with custom configure flags.
+# I was also told that the test suite is intended for kmod developers.
+# So we have to restrict it.
+# See bug #408915.
+RESTRICT="test"
+
+RDEPEND="!sys-apps/module-init-tools
+	!sys-apps/modutils
+	lzma? ( app-arch/xz-utils )
+	zlib? ( >=sys-libs/zlib-1.2.6 )" #427130
+DEPEND="${RDEPEND}
+	doc? ( dev-util/gtk-doc )
+	lzma? ( virtual/pkgconfig )
+	zlib? ( virtual/pkgconfig )"
+
+src_prepare()
+{
+	if [ ! -e configure ]; then
+		if use doc; then
+			gtkdocize --copy --docdir libkmod/docs || die
+		else
+			touch libkmod/docs/gtk-doc.make
+		fi
+		eautoreconf
+	else
+		elibtoolize
+	fi
+}
+
+src_configure()
+{
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable tools) \
+		$(use_enable debug) \
+		$(use_enable doc gtk-doc) \
+		$(use_with lzma xz) \
+		$(use_with zlib)
+}
+
+src_install()
+{
+	default
+	prune_libtool_files
+
+	if use tools; then
+		local cmd
+		for cmd in depmod insmod lsmod modinfo modprobe rmmod; do
+			dosym kmod /usr/bin/${cmd}
+		done
+		# Compability symlink(s):
+		# These are both hardcoded in the Linux kernel source tree wrt #426698
+		dosym /usr/bin/kmod /sbin/depmod
+		dosym /usr/bin/kmod /sbin/modprobe
+	fi
+
+	cat <<-EOF > "${T}"/usb-load-ehci-first.conf
+	softdep uhci_hcd pre: ehci_hcd
+	softdep ohci_hcd pre: ehci_hcd
+	EOF
+
+	insinto /usr/lib/modprobe.d
+	doins "${T}"/usb-load-ehci-first.conf #260139
+}
diff --git a/sys-apps/kmod/kmod-9999.ebuild b/sys-apps/kmod/kmod-9999.ebuild
index 352d7fb293a3..bbbc746a1385 100644
--- a/sys-apps/kmod/kmod-9999.ebuild
+++ b/sys-apps/kmod/kmod-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/kmod-9999.ebuild,v 1.35 2012/10/20 09:30:13 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/kmod-9999.ebuild,v 1.36 2012/11/08 06:41:10 williamh Exp $
 
 EAPI=4
 
@@ -82,6 +82,6 @@ src_install()
 	softdep ohci_hcd pre: ehci_hcd
 	EOF
 
-	insinto /etc/modprobe.d
+	insinto /usr/lib/modprobe.d
 	doins "${T}"/usb-load-ehci-first.conf #260139
 }