Version bump. Use prune_libtool_files from eutils.eclass.

(Portage version: 2.2.0_alpha124/cvs/Linux x86_64)

3 files changed, 99 insertions, 15 deletions

diff --git a/sys-apps/kmod/ChangeLog b/sys-apps/kmod/ChangeLog
index 5715bdbce699..0120f4e37296 100644
--- a/sys-apps/kmod/ChangeLog
+++ b/sys-apps/kmod/ChangeLog
@@ -1,5 +1,11 @@
 # ChangeLog for sys-apps/kmod
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/ChangeLog,v 1.48 2012/07/23 14:20:12 williamh Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/ChangeLog,v 1.49 2012/09/08 17:35:44 ssuominen Exp $
+
+*kmod-10 (08 Sep 2012)
+
+  08 Sep 2012; Samuli Suominen <ssuominen@gentoo.org> +kmod-10.ebuild,
+  kmod-9999.ebuild:
+  Version bump. Use prune_libtool_files from eutils.eclass.
 
   23 Jul 2012; William Hubbs <williamh@gentoo.org> -kmod-7.ebuild,
   -kmod-8.ebuild, -kmod-9.ebuild:
diff --git a/sys-apps/kmod/kmod-10.ebuild b/sys-apps/kmod/kmod-10.ebuild
new file mode 100644
index 000000000000..afd9e97a364e
--- /dev/null
+++ b/sys-apps/kmod/kmod-10.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/kmod-10.ebuild,v 1.1 2012/09/08 17:35:44 ssuominen Exp $
+
+EAPI=4
+
+EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/kernel/${PN}/${PN}.git"
+
+[[ ${PV} == 9999 ]] && vcs=git-2
+inherit ${vcs} autotools eutils toolchain-funcs libtool
+unset vcs
+
+if [[ ${PV} != 9999 ]] ; then
+	SRC_URI="mirror://kernel/linux/utils/kernel/kmod/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+fi
+
+DESCRIPTION="library and tools for managing linux kernel modules"
+HOMEPAGE="http://git.kernel.org/?p=utils/kernel/kmod/kmod.git"
+
+LICENSE="LGPL-2"
+SLOT="0"
+IUSE="debug doc lzma static-libs +tools zlib"
+
+# Upstream does not support running the test suite with custom configure flags.
+# I was also told that the test suite is intended for kmod developers.
+# So we have to restrict it.
+# See bug #408915.
+RESTRICT="test"
+
+RDEPEND="!sys-apps/module-init-tools
+	!sys-apps/modutils
+	lzma? ( app-arch/xz-utils )
+	zlib? ( >=sys-libs/zlib-1.2.6 )" #427130
+DEPEND="${RDEPEND}
+	doc? ( dev-util/gtk-doc )
+	lzma? ( virtual/pkgconfig )
+	zlib? ( virtual/pkgconfig )"
+
+src_prepare()
+{
+	if [ ! -e configure ]; then
+		if use doc; then
+			gtkdocize --copy --docdir libkmod/docs || die
+		else
+			touch libkmod/docs/gtk-doc.make
+		fi
+		eautoreconf
+	else
+		elibtoolize
+	fi
+}
+
+src_configure()
+{
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable tools) \
+		$(use_enable debug) \
+		$(use_enable doc gtk-doc) \
+		$(use_with lzma xz) \
+		$(use_with zlib)
+}
+
+src_install()
+{
+	default
+	prune_libtool_files
+
+	if use tools; then
+		local cmd
+		for cmd in depmod insmod lsmod modinfo modprobe rmmod; do
+			dosym kmod /usr/bin/${cmd}
+		done
+		# Compability symlink(s):
+		# These are both hardcoded in the Linux kernel source tree wrt #426698
+		dosym /usr/bin/kmod /sbin/depmod
+		dosym /usr/bin/kmod /sbin/modprobe
+	fi
+}
diff --git a/sys-apps/kmod/kmod-9999.ebuild b/sys-apps/kmod/kmod-9999.ebuild
index a184c7bf4ce7..ed1442d5613b 100644
--- a/sys-apps/kmod/kmod-9999.ebuild
+++ b/sys-apps/kmod/kmod-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/kmod-9999.ebuild,v 1.31 2012/07/20 16:36:42 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/kmod-9999.ebuild,v 1.32 2012/09/08 17:35:44 ssuominen Exp $
 
 EAPI=4
 
@@ -22,6 +22,12 @@ LICENSE="LGPL-2"
 SLOT="0"
 IUSE="debug doc lzma static-libs +tools zlib"
 
+# Upstream does not support running the test suite with custom configure flags.
+# I was also told that the test suite is intended for kmod developers.
+# So we have to restrict it.
+# See bug #408915.
+RESTRICT="test"
+
 RDEPEND="!sys-apps/module-init-tools
 	!sys-apps/modutils
 	lzma? ( app-arch/xz-utils )
@@ -31,12 +37,6 @@ DEPEND="${RDEPEND}
 	lzma? ( virtual/pkgconfig )
 	zlib? ( virtual/pkgconfig )"
 
-# Upstream does not support running the test suite with custom configure flags.
-# I was also told that the test suite is intended for kmod developers.
-# So we have to restrict it.
-# See bug #408915.
-RESTRICT="test"
-
 src_prepare()
 {
 	if [ ! -e configure ]; then
@@ -65,18 +65,16 @@ src_configure()
 src_install()
 {
 	default
-
-	find "${D}" -name libkmod.la -exec rm -f {} +
+	prune_libtool_files
 
 	if use tools; then
 		local cmd
-		for cmd in insmod lsmod modinfo rmmod; do
+		for cmd in depmod insmod lsmod modinfo modprobe rmmod; do
 			dosym kmod /usr/bin/${cmd}
 		done
-		# according to upstream, modprobe can be called directly by the kernel,
-		# so it cannot be moved to /usr/bin at this time.
-		dosym /usr/bin/kmod /sbin/modprobe
-		# another hardcoded path in the Linux source tree, bug #426698
+		# Compability symlink(s):
+		# These are both hardcoded in the Linux kernel source tree wrt #426698
 		dosym /usr/bin/kmod /sbin/depmod
+		dosym /usr/bin/kmod /sbin/modprobe
 	fi
 }