Version bump, wrt bug #475966. Some cleanups, utilize l10n eclass for proper locale support

(Portage version: 2.2.0_alpha191/cvs/Linux x86_64, signed Manifest commit with key 0x1F357D42)

2 files changed, 72 insertions, 1 deletions

diff --git a/sys-apps/bleachbit/ChangeLog b/sys-apps/bleachbit/ChangeLog
index fc569a797fd6..04bba345a1f4 100644
--- a/sys-apps/bleachbit/ChangeLog
+++ b/sys-apps/bleachbit/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/bleachbit
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/bleachbit/ChangeLog,v 1.12 2013/05/14 09:41:14 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/bleachbit/ChangeLog,v 1.13 2013/08/03 09:45:17 pinkbyte Exp $
+
+*bleachbit-0.9.6 (03 Aug 2013)
+
+  03 Aug 2013; Sergey Popov <pinkbyte@gentoo.org> +bleachbit-0.9.6.ebuild:
+  Version bump, wrt bug #475966. Some cleanups, utilize l10n eclass for proper
+  locale support
 
   14 May 2013; Agostino Sarubbo <ago@gentoo.org> bleachbit-0.9.5.ebuild:
   Stable for x86, wrt bug #469354
diff --git a/sys-apps/bleachbit/bleachbit-0.9.6.ebuild b/sys-apps/bleachbit/bleachbit-0.9.6.ebuild
new file mode 100644
index 000000000000..ff4b2d57ee6e
--- /dev/null
+++ b/sys-apps/bleachbit/bleachbit-0.9.6.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/bleachbit/bleachbit-0.9.6.ebuild,v 1.1 2013/08/03 09:45:17 pinkbyte Exp $
+
+EAPI=5
+
+PLOCALES="ar ast be bg bn bs ca cs da de el en_AU en_GB eo es et eu fa fi fo fr gl he hi hr hu hy ia id it ja ko ku ky lt ms
+my nb nds nl pl pt_BR pt ro ru se si sk sl sr sv ta te th tr ug uk uz vi zh_CN zh_TW"
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1 eutils l10n
+
+DESCRIPTION="Clean junk to free disk space and to maintain privacy"
+HOMEPAGE="http://bleachbit.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls"
+
+RDEPEND="dev-python/pygtk:2[$PYTHON_USEDEP]"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )"
+
+DOCS=( README )
+
+python_prepare_all() {
+	rem_locale() {
+		rm "po/${1}.po" || die "removing of ${1}.po failed"
+	}
+
+	l10n_find_plocales_changes po "" ".po"
+	l10n_for_each_disabled_locale_do rem_locale
+
+	addpredict /root/.gnome2 #401981
+
+	# warning: key "Encoding" in group "Desktop Entry" is deprecated
+	sed -i -e '/Encoding/d' ${PN}.desktop || die
+
+	# choose correct Python implementation, bug #465254
+	sed -i -e 's/python/$(PYTHON)/g' po/Makefile || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use nls && emake -C po
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	use nls && emake -C po DESTDIR="${D}" install
+
+	# http://bugs.gentoo.org/388999
+	insinto /usr/share/${PN}/cleaners
+	doins cleaners/*.xml
+
+	newbin ${PN}.py ${PN}
+	python_replicate_script "${D}/usr/bin/${PN}"
+
+	doicon ${PN}.png
+	domenu ${PN}.desktop
+}