Version bump. Forcing in source building, hopefully fixing bug #419899

(Portage version: 2.1.10.63/cvs/Linux x86_64)

2 files changed, 89 insertions, 1 deletions

diff --git a/sci-visualization/gwyddion/ChangeLog b/sci-visualization/gwyddion/ChangeLog
index 23a011b9ebe3..8ddc4a2c7b1f 100644
--- a/sci-visualization/gwyddion/ChangeLog
+++ b/sci-visualization/gwyddion/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sci-visualization/gwyddion
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-visualization/gwyddion/ChangeLog,v 1.36 2012/05/04 08:07:00 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-visualization/gwyddion/ChangeLog,v 1.37 2012/06/06 18:51:55 bicatali Exp $
+
+*gwyddion-2.28 (06 Jun 2012)
+
+  06 Jun 2012; Sébastien Fabbro <bicatali@gentoo.org> +gwyddion-2.28.ebuild:
+  Version bump. Forcing in source building, hopefully fixing bug #419899
 
   04 May 2012; Jeff Horelick <jdhore@gentoo.org> gwyddion-2.25.ebuild,
   gwyddion-2.27.ebuild:
diff --git a/sci-visualization/gwyddion/gwyddion-2.28.ebuild b/sci-visualization/gwyddion/gwyddion-2.28.ebuild
new file mode 100644
index 000000000000..9c7dce54b151
--- /dev/null
+++ b/sci-visualization/gwyddion/gwyddion-2.28.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-visualization/gwyddion/gwyddion-2.28.ebuild,v 1.1 2012/06/06 18:51:55 bicatali Exp $
+
+EAPI=4
+
+PYTHON_DEPEND="python? 2"
+AUTOTOOLS_IN_SOURCE_BUILD=1
+
+inherit eutils fdo-mime gnome2-utils python autotools-utils
+
+DESCRIPTION="Framework for Scanning Mode Microscopy data analysis"
+HOMEPAGE="http://gwyddion.net/"
+SRC_URI="http://gwyddion.net/download/${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc fftw gnome kde nls opengl perl python ruby sourceview xml X"
+
+RDEPEND="media-libs/libpng
+	x11-libs/cairo
+	x11-libs/gtk+:2
+	x11-libs/libXmu
+	x11-libs/pango
+	fftw? ( >=sci-libs/fftw-3 )
+	gnome? ( gnome-base/gconf:2 )
+	kde? ( >=kde-base/kdelibs-4 )
+	opengl? ( virtual/opengl x11-libs/gtkglext )
+	perl? ( dev-lang/perl )
+	python? ( dev-python/pygtk:2 )
+	ruby? ( dev-ruby/narray )
+	sourceview? ( x11-libs/gtksourceview:2.0 )
+	xml? ( dev-libs/libxml2:2 )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( dev-util/gtk-doc )"
+
+pkg_setup() {
+	use python && python_set_active_version 2
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.25-libpng15.patch
+}
+
+src_configure() {
+	local myeconfargs+=(
+		--disable-rpath
+		$(use_enable doc gtk-doc)
+		$(use_enable nls)
+		$(use_enable python pygwy)
+		$(use_with perl)
+		$(use_with python)
+		$(use_with ruby)
+		$(use_with fftw fftw3)
+		$(use_with opengl gl) \
+		$(use_with sourceview gtksourceview)
+		$(use_with xml spml)
+		$(use_with X x)
+		$(use_with kde kde4-thumbnailer)
+	)
+	autotools-utils_src_configure
+}
+
+src_install() {
+	autotools-utils_src_install
+	use python && dodoc modules/pygwy/README.pygwy
+}
+
+pkg_postinst() {
+	use gnome && gnome2_gconf_install
+	fdo-mime_desktop_database_update
+}
+
+pkg_prerm() {
+	use gnome && gnome2_gconf_uninstall
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+}