Version bump

(Portage version: 2.1.9.25/cvs/Linux x86_64)

2 files changed, 90 insertions, 1 deletions

diff --git a/sci-visualization/gwyddion/ChangeLog b/sci-visualization/gwyddion/ChangeLog
index 9bdd1438aef1..d60f37cb766f 100644
--- a/sci-visualization/gwyddion/ChangeLog
+++ b/sci-visualization/gwyddion/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sci-visualization/gwyddion
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-visualization/gwyddion/ChangeLog,v 1.23 2010/08/07 13:50:21 graaff Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-visualization/gwyddion/ChangeLog,v 1.24 2010/12/02 05:08:34 bicatali Exp $
+
+*gwyddion-2.21 (02 Dec 2010)
+
+  02 Dec 2010; Sébastien Fabbro <bicatali@gentoo.org> +gwyddion-2.21.ebuild:
+  Version bump
 
   07 Aug 2010; Hans de Graaff <graaff@gentoo.org> gwyddion-2.10.ebuild:
   Change virtual/ruby to dev-lang/ruby, bug 265054.
diff --git a/sci-visualization/gwyddion/gwyddion-2.21.ebuild b/sci-visualization/gwyddion/gwyddion-2.21.ebuild
new file mode 100644
index 000000000000..7c75b1a4fc7c
--- /dev/null
+++ b/sci-visualization/gwyddion/gwyddion-2.21.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-visualization/gwyddion/gwyddion-2.21.ebuild,v 1.1 2010/12/02 05:08:34 bicatali Exp $
+
+EAPI=2
+
+PYTHON_DEPEND="python? 2"
+
+inherit fdo-mime gnome2-utils python autotools
+
+DESCRIPTION="A software framework for SPM data analysis"
+HOMEPAGE="http://gwyddion.net/"
+SRC_URI="http://gwyddion.net/download/${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc fftw gnome kde nls opengl perl python ruby sourceview xml X"
+
+RDEPEND=">=x11-libs/gtk+-2.8
+	x11-libs/cairo
+	x11-libs/pango
+	x11-libs/libXmu
+	fftw? ( >=sci-libs/fftw-3 )
+	gnome? ( gnome-base/gconf )
+	kde? ( >=kde-base/kdelibs-4 )
+	opengl? ( virtual/opengl x11-libs/gtkglext )
+	perl? ( dev-lang/perl )
+	python? ( dev-python/pygtk )
+	ruby? ( dev-ruby/narray )
+	sourceview? ( >=x11-libs/gtksourceview-2 )
+	xml? ( dev-libs/libxml2 )"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	doc? ( dev-util/gtk-doc )"
+
+pkg_setup() {
+	use python && python_set_active_version 2
+}
+
+src_prepare() {
+	sed -i -e '/x_includes/d' -e '/x_libraries/d' configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-desktop-file-update \
+		--disable-rpath \
+		--enable-library-bloat \
+		--enable-plugin-proxy \
+		$(use_enable doc gtk-doc) \
+		$(use_enable nls) \
+		$(use_enable python pygwy) \
+		$(use_with perl) \
+		$(use_with python) \
+		$(use_with ruby) \
+		$(use_with fftw fftw3) \
+		$(use_with opengl gl) \
+		$(use_with sourceview gtksourceview) \
+		$(use_with xml spml) \
+		$(use_with X x) \
+		$(use_with kde kde4-thumbnailer)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc AUTHORS ChangeLog NEWS README THANKS TODO
+	use python && dodoc modules/pygwy/README.pygwy
+}
+
+pkg_postinst() {
+	use gnome && gnome2_gconf_install
+	fdo-mime_desktop_database_update
+}
+
+pkg_prerm() {
+	use gnome && gnome2_gconf_uninstall
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+}