Version bump. Fix up missing dependency on sqlite per bug #302100.

(Portage version: 2.2_rc63/cvs/Linux x86_64)

3 files changed, 163 insertions, 11 deletions

diff --git a/sci-misc/boinc/ChangeLog b/sci-misc/boinc/ChangeLog
index cbae43028e85..b10313217c40 100644
--- a/sci-misc/boinc/ChangeLog
+++ b/sci-misc/boinc/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sci-misc/boinc
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-misc/boinc/ChangeLog,v 1.84 2009/12/09 19:03:44 scarabeus Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-misc/boinc/ChangeLog,v 1.85 2010/03/05 14:56:17 scarabeus Exp $
+
+*boinc-6.10.36 (05 Mar 2010)
+
+  05 Mar 2010; Tomáš Chvátal <scarabeus@gentoo.org> boinc-6.10.18.ebuild,
+  +boinc-6.10.36.ebuild:
+  Version bump. Fix up missing dependency on sqlite per bug #302100.
 
   09 Dec 2009; Tomáš Chvátal <scarabeus@gentoo.org>
   -files/6.6.40-as-needed.patch, -files/6.6.40-cuda.patch,
diff --git a/sci-misc/boinc/boinc-6.10.18.ebuild b/sci-misc/boinc/boinc-6.10.18.ebuild
index 951ee514e8f8..ec788587eebc 100644
--- a/sci-misc/boinc/boinc-6.10.18.ebuild
+++ b/sci-misc/boinc/boinc-6.10.18.ebuild
@@ -1,10 +1,10 @@
-# Copyright 1999-2009 Gentoo Foundation
+# Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sci-misc/boinc/boinc-6.10.18.ebuild,v 1.3 2009/12/03 20:04:11 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-misc/boinc/boinc-6.10.18.ebuild,v 1.4 2010/03/05 14:56:17 scarabeus Exp $
 
 EAPI="2"
 
-inherit flag-o-matic depend.apache eutils wxwidgets autotools
+inherit flag-o-matic depend.apache eutils wxwidgets autotools base
 
 DESCRIPTION="The Berkeley Open Infrastructure for Network Computing"
 HOMEPAGE="http://boinc.ssl.berkeley.edu/"
@@ -27,15 +27,20 @@ RDEPEND="
 		>=dev-util/nvidia-cuda-toolkit-2.1
 		>=x11-drivers/nvidia-drivers-180.22
 	)
-"
-DEPEND="${RDEPEND}
-	sys-devel/gettext
 	X? (
+		dev-db/sqlite:3
 		media-libs/freeglut
 		media-libs/jpeg
 		x11-libs/wxGTK:2.8[X,opengl]
 	)
 "
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+"
+
+PATCHES=(
+	"${FILESDIR}"/6.4.5-glibc210.patch
+)
 
 src_prepare() {
 	# use system ssl certificates
@@ -45,8 +50,7 @@ src_prepare() {
 	# prevent bad changes in compile flags, bug 286701
 	sed -i -e "s:BOINC_SET_COMPILE_FLAGS::" configure.ac || die "sed failed"
 
-	epatch \
-		"${FILESDIR}"/6.4.5-glibc210.patch
+	base_src_prepare
 
 	eautoreconf
 }
@@ -82,7 +86,7 @@ src_configure() {
 }
 
 src_install() {
-	emake DESTDIR="${D}" install || die "make install failed"
+	base_src_install
 
 	dodir /var/lib/${PN}/
 	keepdir /var/lib/${PN}/
diff --git a/sci-misc/boinc/boinc-6.10.36.ebuild b/sci-misc/boinc/boinc-6.10.36.ebuild
new file mode 100644
index 000000000000..169d2a23f982
--- /dev/null
+++ b/sci-misc/boinc/boinc-6.10.36.ebuild
@@ -0,0 +1,142 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-misc/boinc/boinc-6.10.36.ebuild,v 1.1 2010/03/05 14:56:17 scarabeus Exp $
+
+EAPI="2"
+
+inherit flag-o-matic depend.apache eutils wxwidgets autotools base
+
+DESCRIPTION="The Berkeley Open Infrastructure for Network Computing"
+HOMEPAGE="http://boinc.ssl.berkeley.edu/"
+SRC_URI="http://dev.gentooexperimental.org/~scarabeus/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="X +client cuda"
+
+RDEPEND="
+	!sci-misc/boinc-bin
+	!app-admin/quickswitch
+	>=app-misc/ca-certificates-20080809
+	dev-libs/openssl
+	net-misc/curl
+	sys-apps/util-linux
+	sys-libs/zlib
+	cuda? (
+		>=dev-util/nvidia-cuda-toolkit-2.1
+		>=x11-drivers/nvidia-drivers-180.22
+	)
+	X? (
+		dev-db/sqlite:3
+		media-libs/freeglut
+		media-libs/jpeg
+		x11-libs/wxGTK:2.8[X,opengl]
+	)
+"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+"
+
+PATCHES=(
+	"${FILESDIR}"/6.4.5-glibc210.patch
+)
+
+src_prepare() {
+	# use system ssl certificates
+	mkdir "${S}"/curl
+	cp /etc/ssl/certs/ca-certificates.crt "${S}"/curl/ca-bundle.crt
+
+	# prevent bad changes in compile flags, bug 286701
+	sed -i -e "s:BOINC_SET_COMPILE_FLAGS::" configure.ac || die "sed failed"
+
+	base_src_prepare
+
+	eautoreconf
+}
+
+src_configure() {
+	local wxconf=""
+	local conf=""
+
+	# define preferable CFLAGS (recommended by upstream)
+	append-flags -O3 -funroll-loops -fforce-addr -ffast-math
+
+	# look for wxGTK
+	if use X; then
+		WX_GTK_VER="2.8"
+		need-wxwidgets unicode
+		wxconf+=" --with-wx-config=${WX_CONFIG}"
+	else
+		wxconf+=" --without-wxdir"
+	fi
+
+	conf+=" --disable-server"
+	use X || conf+=" --disable-manager"
+	use client || conf+=" --disable-client"
+
+	# configure
+	econf \
+		--disable-dependency-tracking \
+		--enable-unicode \
+		--with-ssl \
+		$(use_with X x) \
+		${wxconf} \
+		${conf}
+}
+
+src_install() {
+	base_src_install
+
+	dodir /var/lib/${PN}/
+	keepdir /var/lib/${PN}/
+
+	if use X; then
+		newicon "${S}"/packages/generic/sea/${PN}mgr.48x48.png ${PN}.png || die
+		make_desktop_entry boincmgr "${PN}" "${PN}" "Math;Science" /var/lib/${PN}
+	fi
+
+	# cleanup cruft
+	rm -rf "${D}"/etc/
+
+	newinitd "${FILESDIR}"/${PN}.init ${PN}
+	newconfd "${FILESDIR}"/${PN}.conf ${PN}
+}
+
+pkg_preinst() {
+	enewgroup ${PN}
+	# note this works only for first install so we have to
+	# elog user about the need of being in video group
+	if use cuda; then
+		enewuser ${PN} -1 -1 /var/lib/${PN} "${PN},video"
+	else
+		enewuser ${PN} -1 -1 /var/lib/${PN} "${PN}"
+	fi
+}
+
+pkg_postinst() {
+	echo
+	elog "You are using the source compiled version of ${PN}."
+	use X && elog "The graphical manager can be found at /usr/bin/${PN}mgr"
+	elog
+	elog "You need to attach to a project to do anything useful with ${PN}."
+	elog "You can do this by running /etc/init.d/${PN} attach"
+	elog "The howto for configuration is located at:"
+	elog "http://boinc.berkeley.edu/wiki/Anonymous_platform"
+	elog
+	# Add warning about the new password for the client, bug 121896.
+	if use X; then
+		elog "If you need to use the graphical manager the password is in:"
+		elog "/var/lib/${PN}/gui_rpc_auth.cfg"
+		elog "Where /var/lib/ is default RUNTIMEDIR, that can be changed in:"
+		elog "/etc/conf.d/${PN}"
+		elog "You should change this password to something more memorable (can be even blank)."
+		elog "Remember to launch init script before using manager. Or changing the password."
+		elog
+	fi
+	if use cuda; then
+		elog "To be able to use CUDA you should add boinc user to video group."
+		elog "To do so run as root:"
+		elog "gpasswd -a boinc video"
+	fi
+}