Version Bump

(Portage version: 2.2_rc72/cvs/Linux x86_64)

2 files changed, 62 insertions, 1 deletions

diff --git a/sci-libs/liborigin/ChangeLog b/sci-libs/liborigin/ChangeLog
index d46463f78a3a..cef1227b0b7e 100644
--- a/sci-libs/liborigin/ChangeLog
+++ b/sci-libs/liborigin/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sci-libs/liborigin
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/liborigin/ChangeLog,v 1.21 2010/07/12 20:11:10 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/liborigin/ChangeLog,v 1.22 2010/09/03 05:50:47 jlec Exp $
+
+*liborigin-20100903 (03 Sep 2010)
+
+  03 Sep 2010; Justin Lecher <jlec@gentoo.org> +liborigin-20100903.ebuild:
+  Version Bump
 
   12 Jul 2010; Markos Chandras <hwoarang@gentoo.org>
   liborigin-20100420.ebuild:
diff --git a/sci-libs/liborigin/liborigin-20100903.ebuild b/sci-libs/liborigin/liborigin-20100903.ebuild
new file mode 100644
index 000000000000..83e16a241ef6
--- /dev/null
+++ b/sci-libs/liborigin/liborigin-20100903.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/liborigin/liborigin-20100903.ebuild,v 1.1 2010/09/03 05:50:47 jlec Exp $
+
+EAPI="3"
+
+inherit eutils qt4
+
+DESCRIPTION="Library for reading OriginLab OPJ project files"
+HOMEPAGE="http://soft.proindependent.com/liborigin2/"
+SRC_URI="mirror://gentoo/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="2"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+RDEPEND="dev-libs/boost"
+DEPEND="${RDEPEND}
+	x11-libs/qt-gui:4
+	dev-cpp/tree
+	doc? ( app-doc/doxygen )"
+
+src_prepare() {
+	epatch "${FILESDIR}/liborigin-20100420-build-parsers.patch"
+	cat >> liborigin.pro <<-EOF
+		INCLUDEPATH += "${EPREFIX}/usr/include/tree"
+		headers.files = \$\$HEADERS
+		headers.path = "${EPREFIX}/usr/include/liborigin2"
+		target.path = "${EPREFIX}/usr/$(get_libdir)"
+		INSTALLS = target headers
+	EOF
+	# use system one
+	rm -f tree.hh || die
+}
+
+src_configure() {
+	eqmake4
+}
+
+src_compile() {
+	emake || die "emake failed"
+	if use doc; then
+		cd doc
+		doxygen Doxyfile || die "doc generation failed"
+	fi
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install || die "emake install failed"
+	dodoc readme FORMAT || die
+	if use doc; then
+		insinto /usr/share/doc/${PF}
+		doins -r doc/html || die "doc install failed"
+	fi
+}