Version bump.

(Portage version: 2.1.8.3/cvs/Linux x86_64)

2 files changed, 107 insertions, 1 deletions

diff --git a/net-voip/linphone/ChangeLog b/net-voip/linphone/ChangeLog
index c911dd085601..9d6865c35e26 100644
--- a/net-voip/linphone/ChangeLog
+++ b/net-voip/linphone/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-voip/linphone
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-voip/linphone/ChangeLog,v 1.46 2010/05/20 10:08:59 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-voip/linphone/ChangeLog,v 1.47 2010/05/20 13:05:12 pva Exp $
+
+*linphone-3.3.0 (20 May 2010)
+
+  20 May 2010; Peter Volkov <pva@gentoo.org> +linphone-3.3.0.ebuild:
+  Version bump.
 
   20 May 2010; Peter Volkov <pva@gentoo.org> linphone-3.2.1-r2.ebuild:
   amd64 stable, bug 317235.
diff --git a/net-voip/linphone/linphone-3.3.0.ebuild b/net-voip/linphone/linphone-3.3.0.ebuild
new file mode 100644
index 000000000000..0b1c5b86118c
--- /dev/null
+++ b/net-voip/linphone/linphone-3.3.0.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-voip/linphone/linphone-3.3.0.ebuild,v 1.1 2010/05/20 13:05:12 pva Exp $
+
+EAPI="3"
+
+inherit eutils autotools multilib versionator
+
+DESCRIPTION="Video softphone based on the SIP protocol"
+HOMEPAGE="http://www.linphone.org/"
+SRC_URI="http://download.savannah.nongnu.org/releases-noredirect/${PN}/$(get_version_component_range 1-2).x/sources/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~ppc-macos ~x86-macos"
+IUSE="doc gtk ipv6 ncurses nls video"
+
+RDEPEND=">=media-libs/mediastreamer-2.4.0[video?]
+	>=net-libs/libeXosip-3.0.2
+	>=net-libs/libosip-3.0.0
+	>=net-libs/ortp-0.16.2
+	gtk? ( dev-libs/glib:2
+		>=gnome-base/libglade-2.4.0:2.0
+		>=x11-libs/gtk+-2.4.0:2 )
+	ncurses? ( sys-libs/readline
+		sys-libs/ncurses )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	doc? ( app-text/sgmltools-lite )
+	nls? ( dev-util/intltool
+		sys-devel/gettext )"
+
+IUSE_LINGUAS=" fr it de ja es pl cs nl sv pt_BR hu ru zh_CN"
+IUSE="${IUSE} ${IUSE_LINGUAS// / linguas_}"
+
+# TODO:
+# update ortp ?
+# update mediastreamer ?
+
+# TODO:
+# run-time test for ipv6 : does it need mediastreamer[ipv6] ?
+
+pkg_setup() {
+	if ! use gtk && ! use ncurses ; then
+		ewarn "gtk and ncurses are disabled."
+		ewarn "At least one of these use flags are needed to get a front-end."
+		ewarn "Only liblinphone is going to be installed."
+	fi
+
+	strip-linguas ${IUSE_LINGUAS}
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-3.2.99.1-external-mediastreamer.patch
+	epatch "${FILESDIR}"/${PN}-3.2.1-nls.patch
+
+	# remove speex check, avoid bug when mediastreamer[-speex]
+	sed -i -e '/SPEEX/d' configure.in || die "patching configure.in failed"
+
+	# fix path to use lib64
+	sed -i -e "s:lib\(/liblinphone\):$(get_libdir)\1:" configure.in \
+		|| die "patching configure.in failed"
+
+	# removing bundled libs dir prevent them to be reconf
+	rm -rf mediastreamer2 oRTP || die "should not die"
+	# and references in Makefile.am
+	sed -i -e "s:oRTP::;s:mediastreamer2::" Makefile.am \
+		|| die "patching Makefile.am failed"
+
+	# make sure to use host libtool version
+	rm -f m4/libtool.m4 m4/lt*.m4 #282268
+	eautoreconf
+}
+
+src_configure() {
+	# strict: we don't want -Werror
+	# external-ortp,external-mediastreamer: prefer external libs
+	# truespeech: seems not used, TODO: ask in ml
+	# rsvp: breaking the build (not maintained anymore) --disable = --enable
+	# alsa, artsc and portaudio are used for bundled mediastreamer
+	econf \
+		--libdir="${EPREFIX}"/usr/$(get_libdir) \
+		--disable-strict \
+		--enable-external-ortp \
+		--enable-external-mediastreamer \
+		--disable-truespeech \
+		--disable-dependency-tracking \
+		$(use_enable doc manual) \
+		$(use_enable gtk gtk_ui) \
+		$(use_enable ipv6) \
+		$(use_enable ncurses console_ui) \
+		$(use_enable nls) \
+		$(use_enable video)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dosym linphone-3 /usr/bin/linphone || die
+	dodoc AUTHORS BUGS ChangeLog NEWS README README.arm TODO || die
+	#cp "${ED}/usr/share/pixmaps/"{linphone/linphone2.png,linphone2.png} || die
+}