Version bump.

(Portage version: 2.1.2_pre2-r9)

3 files changed, 67 insertions, 1 deletions

diff --git a/net-proxy/3proxy/3proxy-0.5.3.ebuild b/net-proxy/3proxy/3proxy-0.5.3.ebuild
new file mode 100644
index 000000000000..72d7e11e2d43
--- /dev/null
+++ b/net-proxy/3proxy/3proxy-0.5.3.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/3proxy/3proxy-0.5.3.ebuild,v 1.1 2006/10/14 19:05:32 vapier Exp $
+
+inherit toolchain-funcs
+
+DESCRIPTION="really tiny cross-platform proxy servers set"
+HOMEPAGE="http://www.security.nnov.ru/soft/3proxy/"
+SRC_URI="mirror://gentoo/${P}.tgz"
+#http://www.security.nnov.ru/soft/3proxy/${PV}/3proxy.tgz
+
+LICENSE="3proxy"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+DEPEND=""
+
+S=${WORKDIR}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	sed -i \
+		-e "/^CFLAGS/s:-g -O2:${CFLAGS}:" \
+		-e "/^LDFLAGS/s:-O2:${LDFLAGS}:" \
+		Makefile.unix || die "sed Makefile"
+	sed -i 's:/usr/local::' src/stringtable.c || die "sed stringtable"
+	find . -type f -print0 | xargs -0 chmod a-x
+}
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		LN="$(tc-getCC)" \
+		-f Makefile.unix \
+		|| die
+}
+
+src_install() {
+	local x
+
+	cd "${S}"/src
+	dobin 3proxy || die "dobin 3proxy failed"
+	for x in proxy socks pop3p tcppm udppm mycrypt dighosts ; do
+		newbin ${x} ${PN}-${x} || die "newbin ${x} failed"
+		[[ -f ${S}/man/${x}.8 ]] \
+			&& newman "${S}"/man/${x}.8 ${PN}-${x}.8
+	done
+
+	dodoc $(find "${S}"/cfg -type f)
+	doman "${S}"/man/3proxy*.[38]
+
+	cd "${S}"
+	dodoc Changelog Readme Release.notes
+	dodoc $(find "${S}"/doc -name '*.txt')
+	dohtml $(find "${S}"/doc -name '*.html')
+}
diff --git a/net-proxy/3proxy/ChangeLog b/net-proxy/3proxy/ChangeLog
index 529dab6b9f91..877e3355cba6 100644
--- a/net-proxy/3proxy/ChangeLog
+++ b/net-proxy/3proxy/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-proxy/3proxy
 # Copyright 1999-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-proxy/3proxy/ChangeLog,v 1.8 2006/05/25 14:10:37 hansmi Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/3proxy/ChangeLog,v 1.9 2006/10/14 19:05:32 vapier Exp $
+
+*3proxy-0.5.3 (14 Oct 2006)
+
+  14 Oct 2006; Mike Frysinger <vapier@gentoo.org> +3proxy-0.5.3.ebuild:
+  Version bump.
 
   25 May 2006; Michael Hanselmann <hansmi@gentoo.org> 3proxy-0.5.2.ebuild:
   Stable on ppc.
diff --git a/net-proxy/3proxy/files/digest-3proxy-0.5.3 b/net-proxy/3proxy/files/digest-3proxy-0.5.3
new file mode 100644
index 000000000000..4c35bfeb4ab6
--- /dev/null
+++ b/net-proxy/3proxy/files/digest-3proxy-0.5.3
@@ -0,0 +1,3 @@
+MD5 d29da05d383c7b96409ebb7b0aa5bfb5 3proxy-0.5.3.tgz 190075
+RMD160 083d4ddaf2b5e8b893c20912e95458381bfa06e3 3proxy-0.5.3.tgz 190075
+SHA256 1e93dd0ba9344aa765be416b2bd7afee90aba7fab0c8c2ebe4b13555b9226705 3proxy-0.5.3.tgz 190075