Explicitly set rpcuser to root (bug #499776).

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 58 insertions, 1 deletions

diff --git a/net-nds/rpcbind/ChangeLog b/net-nds/rpcbind/ChangeLog
index 2dd58f1fb92a..8fd074b10515 100644
--- a/net-nds/rpcbind/ChangeLog
+++ b/net-nds/rpcbind/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-nds/rpcbind
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-nds/rpcbind/ChangeLog,v 1.35 2014/01/30 05:10:36 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-nds/rpcbind/ChangeLog,v 1.36 2014/01/30 21:04:39 radhermit Exp $
+
+*rpcbind-0.2.1-r1 (30 Jan 2014)
+
+  30 Jan 2014; Tim Harder <radhermit@gentoo.org> +rpcbind-0.2.1-r1.ebuild:
+  Explicitly set rpcuser to root (bug #499776).
 
 *rpcbind-0.2.1 (30 Jan 2014)
 
diff --git a/net-nds/rpcbind/rpcbind-0.2.1-r1.ebuild b/net-nds/rpcbind/rpcbind-0.2.1-r1.ebuild
new file mode 100644
index 000000000000..b28c467617c8
--- /dev/null
+++ b/net-nds/rpcbind/rpcbind-0.2.1-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-nds/rpcbind/rpcbind-0.2.1-r1.ebuild,v 1.1 2014/01/30 21:04:39 radhermit Exp $
+
+EAPI="4"
+
+inherit eutils systemd
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="git://git.infradead.org/~steved/rpcbind.git"
+	inherit autotools git-r3
+else
+	SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+fi
+
+DESCRIPTION="portmap replacement which supports RPC over various protocols"
+HOMEPAGE="http://sourceforge.net/projects/rpcbind/"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="debug selinux tcpd warmstarts"
+
+RDEPEND=">=net-libs/libtirpc-0.2.3
+	selinux? ( sec-policy/selinux-rpcbind )
+	tcpd? ( sys-apps/tcp-wrappers )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	[[ ${PV} == "9999" ]] && eautoreconf
+	epatch_user
+}
+
+src_configure() {
+	econf \
+		--bindir="${EPREFIX}"/sbin \
+		--with-statedir="${EPREFIX}"/run/${PN} \
+		--with-rpcuser=root \
+		$(use_enable tcpd libwrap) \
+		$(use_enable debug) \
+		$(use_enable warmstarts)
+}
+
+src_install() {
+	default
+
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+
+	systemd_dounit "${FILESDIR}"/${PN}.service
+}